[R] Convertir un fichier PDF en fichier .DOC avec _Word_DocSaveAs

[franco]

Salut à tous.

Je me suis mis dans l'idée de créer plusieurs scripts pour convertir tel document vers un autre format... Dans le cas où je dois envoyer un mail avec un fichier en pièce-jointe...

Combien de fois la personne me répond ceci :

désolé, je n'arrive pas à ouvrir le fichier, pouvez-vous l'enregistrer dans un autre format ?

Dans cet état d'esprit, je me créé donc un script qui me permet donc de "convertir" un fichier PDF au format .doc...

Le script en lui-même fonctionne, mais le résultat n'est pas vraiment "conforme"...


Disons qu'en plus de convertir, il met des pages blanches entre chaque page "pas blanche".

Résultat : un fichier de 23 pages (PDF) devient un fichier de 46 pages (.doc)...


Voici le code en question :

Code: [Tout sélectionner] [Déplier/Replier]

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

_pdftoword()

Func _pdftoword()
   $pdf = @ScriptDir & "\Bomb-Defusal-Manual_1.pdf"
   $doc = @ScriptDir & "\Bomb-Defusal-Manual_1.doc"

   While 1
      If ProcessExists("Winword.exe") Then
         If Not IsDeclared("iMsgBoxAnswer") Then Local $iMsgBoxAnswer
         $iMsgBoxAnswer = MsgBox(68, "Processus Word toujours actif !", "Attention : Microsoft Word est toujours actif..." & @CRLF & @CRLF & "Enregistrez vos travaux avant de continuer." & @CRLF & "En effet, pour pouvoir convertir ce PDF au format .doc, Microsoft Word sera fermé." & @CRLF & @CRLF & "Voulez-vous continuer ?" & @CRLF & "Si OUI : Microsoft Word sera fermé et la conversion se fera automatiquement." & @CRLF & "Si NON : A vous de fermer Microsoft Word et de réitérer l'opération.")
         Select
            Case $iMsgBoxAnswer = 6 ;Yes
               ProcessClose("winword.exe")
               ProcessClose("winword.exe")
            Case $iMsgBoxAnswer = 7 ;No
               ExitLoop
         EndSelect
      EndIf

      Local $oWord = _Word_Create(False, True)
      If @error Then ExitLoop

      ; Open the test document
      Local $oDoc = _Word_DocOpen($oWord, $pdf)
      If @error Then ExitLoop

      ; *****************************************************************************
      ; Save the document as _Word_Test2.doc
      ; *****************************************************************************
      ; Insert text at the beginning
      Local $oRange = _Word_DocRangeSet($oDoc, 0)
;~       $oRange.Text = "Bold text at the beginning. "
;~       $oRange.Bold = True
      ; Save document
      _Word_DocSaveAs($oDoc, $doc)
      If @error Then ExitLoop

      _Word_Quit($oWord)
      ShellExecute($doc)

      ExitLoop
   WEnd
EndFunc   ;==>_pdftoword

GeSHi © Extension Codebox Plus

J'ai travaillé sur ce fichier : http://www.bombmanual.com/manual/1/pdf/ ... nual_1.pdf ( Attention, c'est lié à un jeu steam ^^ pas taper => Jeu )

Je dois donc avoir ceci en première page du fichier converti (.doc) : http://i.imgur.com/57mpvFI.png
Mais j'ai ceci : http://i.imgur.com/TucwM2T.png


Bref, pouvez-vous m'aider à y voir plus clair.
Car là ( et non pas Clara lol) : je sèche...



Merci à tous.
Bonne fin de dimanche.

[franco]

Yo.

Bon, j'ai procédé autrement et j'ai résolu le souci... Le sujet même.

Autrement car... le souci de la première page mal "converti" est un souci interne à Word... Et pas AutoIt donc...

Pour le souci des pages en double, étant donné que rien n'a fonctionné, et que le souci cité précédemment n'avait rien à avoir avec le script, j'ai procédé d'une autre façon.

Voici ce que j'ai fait :
- J'ai utilisé l'outil en ligne de commande pdftopng (de XPDF) pour convertir chaque page du PDF au format PNG dans un dossier unique (qui ne contient donc que ces fichiers).
- J'ai ensuite listé ces fichiers images et est utilisé la fonction _Word_DocPictureAdd pour les ajouter au fichier .doc.

Trêve de blabla, voici le code :

► Afficher le texte

Code: [Tout sélectionner] [Déplier/Replier]

#include <File.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>

#include <WindowsConstants.au3>
#include <Word.au3>

Global $Dossiertmp, $ObjWord

If FileExists($Dossiertmp) Then DirRemove($Dossiertmp, 1)

$pdf_info = @TempDir & '\pdfinfo.exe'
$pdf_png = @TempDir & '\pdftopng.exe'
FileInstall('pdfinfo.exe', $pdf_info)
FileInstall('pdftopng.exe', $pdf_png)

Global $Form1 = GUICreate("Form1", 542.5, 31, 192, 124, $ws_popupwindow, $WS_EX_ACCEPTFILES)
GUISetFont(9, 400, 0, "comic sans ms")

$lbl = GUICtrlCreateLabel("Glissez/Déposez le fichier PDF afin de le convertir en un seul un fichier Texte", 5, 5.5, 450, -1)

GUICtrlCreateGraphic(460, 5, 20, 20)
GUICtrlSetColor(-1, 0x123123)
GUICtrlSetBkColor(-1, 0xA0A0A0)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

$Red = GUICtrlCreateButton("-", 490, 4.5, 23, 23)
$Quit = GUICtrlCreateButton("X", 515, 4.5, 23, 23)


GUISetState(@SW_SHOW)


While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE, $Quit
         _Word_Quit($ObjWord)
         FileDelete($pdf_info)
         FileDelete($pdf_png)
         DirRemove($Dossiertmp, 1)
         Exit
      Case $Red
         GUISetState(@SW_MINIMIZE)

      Case $GUI_EVENT_DROPPED
         Local $sDrive, $sDir, $sFileName, $sExtension

         $FichierPDF = @GUI_DragFile
         _PathSplit($FichierPDF, $sDrive, $sDir, $sFileName, $sExtension)
         $Dossier = @DesktopDir & '\pdf_vdoc'
         $FichierDoc = $Dossier & '\' & $sFileName & ".doc"

         While 1

            If StringRight($FichierPDF, 4) = '.pdf' Then

               $Progress = GUICtrlCreateProgress(460, 5, 20, 20, $PBS_MARQUEE)
               GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30)) ; on envoie la barre de progressiob

               $Dossiertmp = @TempDir & '\pdf_vdoc_png'
               DirRemove($Dossiertmp, 1)
               DirCreate($Dossiertmp)

               $command = $pdf_info & ' "' & $FichierPDF & '"|find "Pages"'
               Local $nPid = Run(@ComSpec & " /c " & $command, "", @SW_HIDE, 8), $pagett = ""
               ProcessWait($nPid)
               While 1
                  $pagett &= StdoutRead($nPid)
                  If @error Or (Not ProcessExists($nPid)) Then ExitLoop
               WEnd
               $var = StringSplit($pagett, @CRLF, 1)
               $pagett = StringStripWS(StringReplace($var[$var[0] - 1], 'pages:', ''), 8)

               $command = $pdf_png & ' -f 1 -l ' & $pagett & ' "' & $FichierPDF & '" "' & $Dossiertmp & '\png"'
               RunWait(@ComSpec & " /c " & $command, "", @SW_HIDE)

               $Dossier = @DesktopDir & '\pdf_vdoc'
               $FichierDoc = $Dossier & '\' & $sFileName & ".doc"
               DirCreate($Dossier)
               FileDelete($FichierDoc)

               $PngFile = _FileListToArray($Dossiertmp, '*.png', 1, True)
               If @error Then ExitLoop

               $FDOC = FileOpen($FichierDoc, 2)
               FileClose($FDOC)

               Local $oWord = _Word_Create(False, True)
               Local $oDocPart = _Word_DocOpen($oWord, $FichierDoc)

               For $a = $PngFile[0] To 1 Step -1
                  _Word_DocPictureAdd($oDocPart, $PngFile[$a])
               Next
               _Word_DocSaveAs($oDocPart, $FichierDoc)
               _Word_DocClose($oDocPart)
               _Word_Quit($oWord)

               GUICtrlDelete($Progress)
               
               DirRemove($Dossiertmp, 1)
               ShellExecute($FichierDoc)

            EndIf

            ExitLoop
         WEnd





   EndSwitch
WEnd

GeSHi © Extension Codebox Plus

Bref, il est surement optimisable, mais bon : il fait ce que j'avais en tête...

Le seul hic (mais là je chipote), c'est que l'image ajoutée ne prend pas toute la page du doc.



@+

[walkson]

A titre indicatif, il y a ça aussi
RunWait("LibreOfficePortable --headless --invisible --convert-to doc FF.pdf --outdir dossier ")
Le PDF est converti en Doc directement mais il y a des inconvénients:
le PDF doit avoir une page
Si le PDF possède trop d'images, le résultat n'est pas terrible
Word crie à la "corruption" et crée un nouveau document corrigé (Word 2007) (ça doit pouvoir se résoudre)
L'avantage est que le PDF converti peut être entièrement modifié (position, texte, chiffres, images etc...) et le format est (en principe) conservé.
C'est une bonne solution pour un PDF simple comme une facture, un tableau...

[franco]

Coucou.

D'accord avec toi Walkson : un pdf éditable, c'est mieux.

Comme faisait le premier script...

Si je trouve un moyen que la première page soit correctement convertie et un moyen de supprimer les pages blanches, ça serait le must

Pour la première page... Pourquoi ne pas la convertir comme je l'ai fait, et l'insérer.

Puis utiliser les fonctions _word...

Je pense que je vais tenter cela


Comme cela : seule la première page ne sera pas éditable...


Restera donc le fameux problème des pages blanches....


Je continue mon script. Et de cogiter lol.


Si j'y arrive, je reviendrai...


@++