[R] Redimensionner une interface GUI ainsi que l'image

[franco]

Bonjour à tous et à toutes.

Je cherche avant tout à afficher un gif animé dans une interface, : j'y arrive.
Mais je ne souhaite pas de barre de titre : j'y arrive aussi.

Le seul hic : je voudrais quand même que l'interface soit redimensionnable, et que l'image se redimensionne avec.

j'arrive à rendre redimensionnable l'interface, mais pas l'image affichée (le "control").

J'utilise l'UDF GifAnimation pour afficher les gifs animés.


Mais le script ci-dessus a été réduit, pour ne montrer que l'essentiel.
J'affiche donc une image .jpg.

► Afficher le textecode

Code : Tout sélectionner

#include <File.au3>
#include <GDIPlus.au3>
#include <GIFAnimation.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

$FichierImage = "roquette.jpg"
_GDIPlus_Startup()
$tImg = _GDIPlus_ImageLoadFromFile($FichierImage)
$Hauteur = _GDIPlus_ImageGetHeight($tImg)
$Largeur = _GDIPlus_ImageGetWidth($tImg)
_GDIPlus_ImageDispose($tImg)
_GDIPlus_Shutdown()

If $Largeur > $Hauteur And $Largeur > 640 Then
	$Largeur = 640
	$Hauteur = 480
ElseIf $Largeur < $Hauteur And $Hauteur > 640 Then
	$Largeur = 480
	$Hauteur = 640
EndIf


_PicGui($FichierImage, $Hauteur, $Largeur, 50, 50)


Func _PicGui($FichierImage, $Hauteur, $Largeur, $posX, $posY)
	Const $SC_DRAGMOVE2 = 0xF012

	Local $sDrive, $sDir, $sFileName, $sExtension
	_PathSplit(@ScriptFullPath, $sDrive, $sDir, $sFileName, $sExtension)

	Global $PicGui = GUICreate($sFileName & $sExtension, $Largeur, $Hauteur, 010, 50, BitOR($WS_POPUP, $WS_THICKFRAME), $WS_EX_LAYERED)

	GUICtrlCreatePic($FichierImage, 0, 0, $Largeur, $Hauteur)
	GUICtrlSetResizing(-1, BitOr($GUI_DOCKTOP, $GUI_DOCKLEFT, $GUI_DOCKSIZE))
;~ 	GUICtrlSetResizing(-1, $GUI_DOCKALL)
	GUISetBkColor(0xABCDEF, $PicGui)
	_WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

	GUISetState(@SW_SHOW)

	While 1
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_PRIMARYDOWN
				_SendMessage($PicGui, $WM_SYSCOMMAND, $SC_DRAGMOVE2, 0)
			Case $GUI_EVENT_CLOSE
				GUIDelete($PicGui)
				ExitLoop

		EndSwitch
	WEnd

EndFunc   ;==>_PicGui

Avez-vous une idée / une piste pour que je puisse redimensionner la GUI ET l'image simultanément ?


Merci
Et bonne journée / soirée.

[mikell]

GUICtrlSetResizing($pic, $GUI_DOCKBORDERS)

[walkson]

Bonsoir,
Si l'udf GifAnimation est celui de Tracexx, il y a une gui redimensionnable dans Example6_ImageViewer.au3 (image comprise)
Ça peut donner des idées...

[franco]

Bonjour.

Merci à vous deux.
Et effectivement, c'est bien l'udf de trancexx.


Je reviens plus tard.

++

[franco]

Bonjour.

Bon, déjà merci (encore) pour vos réponses.

Voici le nouveau code

► Afficher le textenouveau code

Code : Tout sélectionner

#include <File.au3>
#include <GDIPlus.au3>
#include <GIFAnimation.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

Global $DisplayImage

Const $SC_DRAGMOVE1 = 0xF012


#Region ### START Koda GUI section ### Form=
Global $ViewPic = GUICreate("Form1", 50, 50, 192, 124, $WS_POPUP, $WS_EX_ACCEPTFILES)
GUICtrlCreateGraphic(0, 0, 50, 50)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlSetBkColor(-1, 0x0A000)
GUICtrlSetColor(-1, 0)

$pos = WinGetPos($ViewPic)
$posX = $pos[0] + $pos[2] + 10
$posY = $pos[1]

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_PRIMARYDOWN
			_SendMessage($ViewPic, $WM_SYSCOMMAND, $SC_DRAGMOVE1, 0)

		Case $GUI_EVENT_CLOSE
			Exit

		Case $GUI_EVENT_DROPPED
			$FichierImage = @GUI_DragFile
			_GDIPlus_Startup()
			$tImg = _GDIPlus_ImageLoadFromFile($FichierImage)
			$Hauteur = _GDIPlus_ImageGetHeight($tImg)
			$Largeur = _GDIPlus_ImageGetWidth($tImg)
			_GDIPlus_ImageDispose($tImg)
			_GDIPlus_Shutdown()

			If $Largeur > $Hauteur And $Largeur > 640 Then
				$Largeur = 640
				$Hauteur = 480
			ElseIf $Largeur < $Hauteur And $Hauteur > 640 Then
				$Largeur = 480
				$Hauteur = 640
			EndIf

			_PicGui($FichierImage, $Hauteur, $Largeur, $posX, $posY)


	EndSwitch
WEnd



Func _PicGui($FichierImage, $Hauteur, $Largeur, $posX, $posY)
	Const $SC_DRAGMOVE2 = 0xF012

	Local $sDrive, $sDir, $sFileName, $sExtension
	_PathSplit(@ScriptFullPath, $sDrive, $sDir, $sFileName, $sExtension)


	Global $PicGui = GUICreate($sFileName & $sExtension, $Largeur, $Hauteur, 010, 50, BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), $WS_EX_LAYERED)

	$DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $Largeur, $Hauteur)
	GUICtrlSetResizing($DisplayImage, $GUI_DOCKBORDERS)
	GUISetBkColor(0xABCDEF, $PicGui)
	_WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

	GUISetState(@SW_SHOW)

	While 1
		$nMsg = GUIGetMsg()
		Switch $nMsg
			Case $GUI_EVENT_PRIMARYDOWN
				_SendMessage($PicGui, $WM_SYSCOMMAND, $SC_DRAGMOVE2, 0)
			Case $GUI_EVENT_CLOSE
				GUIDelete($PicGui)
				ExitLoop

		EndSwitch
	WEnd

EndFunc   ;==>_PicGui

Il reste un problème, et pas des moindres.

J'affiche un gif animé et je le redimensionne :
- Pendant le redimensionnement, cela fonctionne.
- Une fois le redimensionnement fini, je relâche donc le clic de la souris : et là, PROBLEME...

En effet, j'ai "deux images".
- Le gif animé d'origine (avec les dimensions d'origine)
- Et l'image fixe qui a été redimensionnée.

• Le gif utilisé : http://i.imgur.com/TZpYTCd.gifv
• Capture d'écran sans redimension : http://i.imgur.com/D3B9Uhx.png
• Capture d'écran avec redimension : http://i.imgur.com/Dt1YT0c.png

D'où vient le souci ?
Et est-ce corrigible ?

EDIT : Ca fonctionne avec les images non animées.
EDIT2 : peut-être qu'il faut calculer les nouvelles dimensions et refaire un nouveau " _GUICtrlCreateGIF($FichierImage, "", 0, 0, $Largeur, $Hauteur) "

Si l'EDIT2 est confirmé... Et bien... Je ne sais pas faire ni où commencer.

Merci de m'aider
++

[franco]

Re.

Je pense avoir une solution... que je n'ai pas encore mis en place...

En fait, suffit de détecter les nouvelles dimensions de l'interface après le redimensionnement (surtout les deux tailles largeur et hauteur).
Puis de supprimer le gif animé.
Et de le recréer avec les nouvelles dimensions.


je vais tester.
je pense juste qu'il y aura un souci : comment faire pour dire "immédiatement après le redimensionnement, je veux que les nouvelles dimensions du gif s'appliquent'".

En gros, une condition : Si la taille varie, le gif varie aussi.


A creuser...
Je vais potasser. ^^


++

[franco]

Bonsoir.

J'ai avancé. ^^ Voire quasiment fini, me reste un problème qui n'est pas gênant.


Etant donné que je voulais faire une action après avoir redimensionné, j'ai donc recherché sur google avec des mots en français : rien trouvé.
Donc j'ai écrit ma recherche en anglais : et là, j'ai trouvé.

=> https://www.google.fr/search?q=autoit+a ... ter+resize
=> https://www.autoitscript.com/forum/topi ... ent-946083

la réponse : Case $GUI_EVENT_RESIZED


J'ai donc pondu ce code :

► Afficher le textenouveau code

Code: [Tout sélectionner] [Déplier/Replier]

#include <File.au3>
#include <GDIPlus.au3>
#include <GIFAnimation.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>
#include <Misc.au3>
Global $DisplayImage, $pos, $Larg, $Haut

Const $SC_DRAGMOVE1 = 0xF012


#Region ### START Koda GUI section ### Form=
Global $ViewPic = GUICreate("Form1", 50, 50, 192, 124, $WS_POPUP, $WS_EX_ACCEPTFILES)
GUICtrlCreateGraphic(0, 0, 50, 50)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlSetBkColor(-1, 0x0A000)
GUICtrlSetColor(-1, 0)

$pos = WinGetPos($ViewPic)
$Larg = $pos[2]
$Haut = $pos[3]

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###




While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_PRIMARYDOWN
         _SendMessage($ViewPic, $WM_SYSCOMMAND, $SC_DRAGMOVE1, 0)

      Case $GUI_EVENT_CLOSE
         Exit

      Case $GUI_EVENT_DROPPED
         $FichierImage = @GUI_DragFile
         _GDIPlus_Startup()
         $tImg = _GDIPlus_ImageLoadFromFile($FichierImage)
         $Hauteur = _GDIPlus_ImageGetHeight($tImg)
         $Largeur = _GDIPlus_ImageGetWidth($tImg)
         _GDIPlus_ImageDispose($tImg)
         _GDIPlus_Shutdown()

         If $Largeur > $Hauteur And $Largeur > 640 Then
            $Largeur = 640
            $Hauteur = 480
         ElseIf $Largeur < $Hauteur And $Hauteur > 640 Then
            $Largeur = 480
            $Hauteur = 640
         EndIf

         _PicGui($FichierImage, $Hauteur, $Largeur)


   EndSwitch
WEnd



Func _PicGui($FichierImage, $Hauteur, $Largeur)
   Const $SC_DRAGMOVE2 = 0xF012

   Local $sDrive, $sDir, $sFileName, $sExtension
   _PathSplit(@ScriptFullPath, $sDrive, $sDir, $sFileName, $sExtension)



   Global $PicGui = GUICreate($sFileName & $sExtension, $Largeur, $Hauteur, 010, 50, BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), $WS_EX_LAYERED)

   Global $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $Largeur, $Hauteur)
   GUICtrlSetResizing($DisplayImage, $GUI_DOCKBORDERS)

   GUISetBkColor(0xABCDEF, $PicGui)
   _WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

   GUISetState(@SW_SHOW)

   While 1


      $nMsg = GUIGetMsg()
      Switch $nMsg
         Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($PicGui, $WM_SYSCOMMAND, $SC_DRAGMOVE2, 0)
         Case $GUI_EVENT_CLOSE
            GUIDelete($PicGui)
            ExitLoop

         Case $GUI_EVENT_RESIZED
            $newpos = WinGetPos($PicGui)
            $NewLargeur = $newpos[2]
            $NewHauteur = $newpos[3]
            If $Larg <> $NewLargeur Or $Haut <> $NewHauteur Then
               _GIF_DeleteGIF($DisplayImage)
               $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $NewLargeur, $NewHauteur)
            EndIf


      EndSwitch



   WEnd

EndFunc   ;==>_PicGui

GeSHi © Extension Codebox Plus

Je fais donc ce que je voulais.

Le seul souci : la touche échap.


En effet, elle permet de fermer la fenêtre.
Après le redimensionnement, echap n'est plus active.

Après, je peux faire un hotkeyset... Mais j'aimerais savoir pourquoi echap ne me permet plus la fermeture de cette fenêtre.


@+ et bonne soirée à tous.

[TommyDDR]

@franco : Avez-vous essayé la solution de mikell ?

[franco]

Bonjour.

La ligne de Mikell est dans mon script, donc oui.

Tout fonctionne, sauf que la touche échap ne ferme pas la fenêtre.

Cependant, je compte ajouter un menu contextuel.
Donc je peux inclure la fermeture de cette fenêtre dans ce menu.

Néanmoins j'aimerais savoir pourquoi la touche Echap, même si je clique sur l'image, ne ferme pas la fenêtre.
J'ai du fauté quelque part.



++

[mikell]

Peut-être (hypothèse...) parce qu'il y a 2 gui et 2 boucles while, et que la gui principale est inactive pendant que la 2ème est présente
Pourquoi pas un hotkeySet ESC ? le résultat est le même, les incertitudes en moins

[TommyDDR]

J'ai parcouru rapidement votre code, je me pose la question sur l'utilité d'avoir 2 fenêtres. Quelque chose m'échapperait-il ?

[franco]

Salut.

J'ai parcouru rapidement votre code, je me pose la question sur l'utilité d'avoir 2 fenêtres. Quelque chose m'échapperait-il ?

La première fait juste 50*50 et me permet de glisser/déposer l'image que je souhaite afficher avec les dimensions voulues.

@+

[Numeric]

Bonjour.

La ligne de Mikell est dans mon script, donc oui.

Tout fonctionne, sauf que la touche échap ne ferme pas la fenêtre.

Cependant, je compte ajouter un menu contextuel.
Donc je peux inclure la fermeture de cette fenêtre dans ce menu.

Néanmoins j'aimerais savoir pourquoi la touche Echap, même si je clique sur l'image, ne ferme pas la fenêtre.
J'ai du fauté quelque part.



++

as tu donc pensé à un HotKeySet? en attendant?

[franco]

Salut.

Oui, et cela a déjà été proposé par Mikell et moi-même.


Mais j'ai résolu le souci. D'une façon qui me parait pas... propre... Mais bon, ça fonctionne.

Code: [Tout sélectionner] [Déplier/Replier]

Case $GUI_EVENT_RESIZED
            GUISetState(@SW_HIDE)
            $newpos = WinGetPos($PicGui)
            $NewLargeur = $newpos[2]
            $NewHauteur = $newpos[3]
            If $Larg <> $NewLargeur Or $Haut <> $NewHauteur Then


               _GIF_DeleteGIF($DisplayImage)

               $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $NewLargeur, $NewHauteur)
               GUISetBkColor(0xABCDEF, $PicGui)
               _WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

;~                $Actions = GUICtrlCreateContextMenu($DisplayImage)
;~                $CopierImage = GUICtrlCreateMenuItem("Copier l'image affichée", $Actions)
;~                $EnrSous = GUICtrlCreateMenuItem("Enregistrer l'image affichée", $Actions)
;~                GUICtrlCreateMenuItem("", $Actions)
;~                $Quitter = GUICtrlCreateMenuItem("Quitter", $Actions)

            EndIf
            GUISetState(@SW_SHOW)

GeSHi © Extension Codebox Plus

J'ai juste rajouté :
GUISetState(@SW_HIDE) au début
GUISetState(@SW_SHOW à la fin

Car vraissemblablement, une fois l'interface redimensionnée... La fenêtre elle-même n'est plus "active".

Donc pour moi : c'est résolu.


Merci à vous tous de m'avoir aidé.

► Afficher le textecode complet

Code: [Tout sélectionner] [Déplier/Replier]

#include <File.au3>
#include <GDIPlus.au3>
#include <GIFAnimation.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>
#include <Misc.au3>

Global $DisplayImage, $pos, $Larg, $Haut
Const $SC_DRAGMOVE1 = 0xF012

Global $ViewPic = GUICreate("Form1", 50, 50, 192, 124, $WS_POPUP, $WS_EX_ACCEPTFILES)

GUICtrlCreateGraphic(0, 0, 50, 50)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlSetBkColor(-1, 0x0A000)
GUICtrlSetColor(-1, 0)

$pos = WinGetPos($ViewPic)
$Larg = $pos[2]
$Haut = $pos[3]

GUISetState(@SW_SHOW)


While 1

   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_PRIMARYDOWN
         _SendMessage($ViewPic, $WM_SYSCOMMAND, $SC_DRAGMOVE1, 0)

      Case $GUI_EVENT_CLOSE
         Exit

      Case $GUI_EVENT_DROPPED
         $FichierImage = @GUI_DragFile
         _GDIPlus_Startup()
         $tImg = _GDIPlus_ImageLoadFromFile($FichierImage)
         $Hauteur = _GDIPlus_ImageGetHeight($tImg)
         $Largeur = _GDIPlus_ImageGetWidth($tImg)
         _GDIPlus_ImageDispose($tImg)
         _GDIPlus_Shutdown()

         If $Largeur > $Hauteur And $Largeur > 640 Then
            $Largeur = 640
            $Hauteur = 480
         ElseIf $Largeur > $Hauteur And $Largeur < 640 Then
            $Largeur = $Largeur
            $Hauteur = $Hauteur
         ElseIf $Largeur < $Hauteur And $Hauteur > 640 Then
            $Largeur = 480
            $Hauteur = 640
         ElseIf $Largeur < $Hauteur And $Hauteur < 640 Then
            $Largeur = $Largeur
            $Hauteur = $Hauteur
         EndIf



         _PicGui($FichierImage, $Hauteur, $Largeur)


   EndSwitch
WEnd



Func _PicGui($FichierImage, $Hauteur, $Largeur)

   Const $SC_DRAGMOVE2 = 0xF012
   Local $sDrive, $sDir, $sFileName, $sExtension

   _PathSplit($FichierImage, $sDrive, $sDir, $sFileName, $sExtension)

   Global $PicGui = GUICreate($sFileName & $sExtension, $Largeur, $Hauteur, 010, 50, $WS_POPUP+$WS_THICKFRAME, $WS_EX_LAYERED)

   Global $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $Largeur, $Hauteur)
   GUISetBkColor(0xABCDEF, $PicGui)
   _WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

   $Actions = GUICtrlCreateContextMenu($DisplayImage)
   $CopierImage = GUICtrlCreateMenuItem("Copier l'image affichée", $Actions)
   $EnrSous = GUICtrlCreateMenuItem("Enregistrer l'image affichée", $Actions)
   GUICtrlCreateMenuItem("", $Actions)
   $Quitter = GUICtrlCreateMenuItem("Quitter", $Actions)

   GUISetState(@SW_SHOW)

   While 1

      $nMsg = GUIGetMsg()
      Switch $nMsg

         Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($PicGui, $WM_SYSCOMMAND, $SC_DRAGMOVE2, 0)
         Case $GUI_EVENT_CLOSE, $Quitter
            GUIDelete($PicGui)
            ExitLoop

         Case $GUI_EVENT_RESIZED
            GUISetState(@SW_HIDE)
            $newpos = WinGetPos($PicGui)
            $NewLargeur = $newpos[2]
            $NewHauteur = $newpos[3]
            If $Larg <> $NewLargeur Or $Haut <> $NewHauteur Then


               _GIF_DeleteGIF($DisplayImage)

               $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $NewLargeur, $NewHauteur)
               GUISetBkColor(0xABCDEF, $PicGui)
               _WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

;~                $Actions = GUICtrlCreateContextMenu($DisplayImage)
;~                $CopierImage = GUICtrlCreateMenuItem("Copier l'image affichée", $Actions)
;~                $EnrSous = GUICtrlCreateMenuItem("Enregistrer l'image affichée", $Actions)
;~                GUICtrlCreateMenuItem("", $Actions)
;~                $Quitter = GUICtrlCreateMenuItem("Quitter", $Actions)

            EndIf
            GUISetState(@SW_SHOW)

      EndSwitch

   WEnd

EndFunc   ;==>_PicGui

Func _DisplayImage()
   Global $DisplayImage = _GUICtrlCreateGIF($FichierImage, "", 0, 0, $Largeur, $Hauteur)
   GUICtrlSetResizing($DisplayImage, $GUI_DOCKBORDERS)
   GUISetBkColor(0xABCDEF, $PicGui)
   _WinAPI_SetLayeredWindowAttributes($PicGui, 0xABCDEF, 250)

   $Actions = GUICtrlCreateContextMenu($DisplayImage)
   $CopierImage = GUICtrlCreateMenuItem("Copier l'image affichée", $Actions)
   $EnrSous = GUICtrlCreateMenuItem("Enregistrer l'image affichée", $Actions)
   GUICtrlCreateMenuItem("", $Actions)
   $Quitter = GUICtrlCreateMenuItem("Quitter", $Actions)
EndFunc   ;==>_DisplayImage

GeSHi © Extension Codebox Plus

++