[..] Ajout de Wins

[sirus]

Attention aux accents.

Tu parles de l'accent de "réseau"?

Si oui comment je dois l'écrire vu que même en l'écrivant "reseau" ça ne fonctionne pas?

Merci par avance

[Tlem]

C'est un problème déjà vu depuis longtemps. Il y a plusieurs sujets la dessus dont un UDF de conversion (ANSI <=> OEM) que j'ai écrit.

Sinon, lancez une console DOS et tapez :

Code : Tout sélectionner

ECHO Réseau>C:\Con.txt

Ouvrez le fichier C:\Con.txt et voyez ce qu'est devenu votre é.

► Afficher le texte

Attention, ce n'est pas une virgule comme vous l'écrirez avec Windows. Donc utilisez le copier/coller

[sirus]

Merci pour l'info.

J'ai donc fait ceci

Code : Tout sélectionner

RunWait(@ComSpec & " /c netsh interface ip add wins 'Connexion au r‚seau local' 128.1.79.2")
RunWait(@ComSpec & " /c netsh interface ip add wins 'Connexion au r‚seau local' 128.1.71.36")

Mais les wins ne s'ajoutent toujours pas.
J'ai trouvé une solution de contournement comme ceci

Code : Tout sélectionner

;Ajout des WINS sur Connexion au réseau local
run(@ComSpec)
WinWaitActive("C:\WINDOWS\system32\cmd.exe")
Send('netsh interface ip add wins "Connexion au réseau local" 128.1.71.36')
send("{ENTER}")
sleep(4000)
Send('netsh interface ip add wins "Connexion au réseau local" 128.1.79.2')
send("{ENTER}")
sleep(4000)
Send("exit")
send("{ENTER}")

Mais c'est pas top

[ani]

Salut,
en visionnant la ruche, et voyant hex(7) dans le premier post, il faut juste que tu change le REG_SZ en REG_MULTI_SZ

Au niveau du fichier reg du premier post, quand tu l'execute il écrit quoi dans la ruche ?
L'ip en clair ou en hexadecimal et quel est le type de cette valeur ?
Reponse : l'ip en clair

► Afficher le texte

DhcpNameServerList = '128.1.79.2 128.1.71.36'
NameServerList = '128.1.71.36 128.1.79.2'
Type = REG_MULTI_SZ

Tjrs avec ce fichier reg, quand tu tape dans la fenetre ms-dos cette commande = netsh interface ip show wins
il te retourne quoi l'ip en clair ou en hexa?
Reponse: l'ip en clair

► Afficher le texte

netsh interface ip>show wins
Configuration pour l'interface "Connexion au réseau local"
Serveurs WINS configurés statiquement : 128.1.71.36
128.1.79.2

Si tu visionne l'hexa soumis y a les deux IP qui se suivent,
NameServerlist = NameServerlist + DhcpNameServerlist
DhcpNameServerlist = DhcpNameServerlist + NameServerlist

Normalement c'est bon, mais je vais quand même tester


PS : TESTé

Donc pour regwrite indique comme ci-dessous

Code : Tout sélectionner

RegWrite("HKLM\SYSTEM\ControlSet001\Services\NetBT\Parameters\Interfaces\Tcpip_{751FD231-CB48-4990-9AF9-597E02DB5913}","NameServerList","REG_MULTI_SZ","128.1.71.36" & @LF & "128.1.79.2")
RegWrite("HKLM\SYSTEM\ControlSet001\Services\NetBT\Parameters\Interfaces\Tcpip_{751FD231-CB48-4990-9AF9-597E02DB5913}","DhcpNameServerList","REG_MULTI_SZ","128.1.79.2" & @LF & "128.1.71.36")

Pour netsh, tu devrait regarder l'exemple de l'aide avec la fonction StdinWrite()
mais je doute que c' add win, çà doit etre un mélange avec set win.

bonne continuation

[GhostLine]

Deux solutions, brutes de copier / coller de mes codes par contre (je suis un peu en speed) :

Sous XP :

Code : Tout sélectionner

Func step51($adresse_integration, $masque_integration, $passerelle_integration, $dns_prefere, $dns_auxiliaire, $Cx)
    SplashTextOn("Configuration IP", "Configuration IP en cours ...", 400, 50, -1, -1, 33, -1, 18)
    Sleep(1000)
    FileMove("c:\PICARD - automation 2.exe", @DesktopDir & "\PICARD - automation 2.exe")
    RunWait(@ComSpec & ' /c ' & 'netsh int ip reset c:\windows\temp\temp.txt', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set address local static ' & $adresse_integration & ' ' & $masque_integration & ' ' & $passerelle_integration & ' 1', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set dns ' & '"' & $Cx & '"' & ' static ' & $dns_prefere & ' primary', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip add dns ' & '"' & $Cx & '"' & ' ' & $dns_auxiliaire & ' index=2', "", @SW_HIDE)
    SplashTextOn("Configuration IP", "Configuration IP terminée.", 400, 50, -1, -1, 33, -1, 18)
    Sleep(1000)
    SplashOff()
    IniWrite($fichier_ini, "Avancement", "Etat", "1")
EndFunc   ;==>step51

Sous 7 :

Code : Tout sélectionner

Func step1($adresse_mag, $masque_mag, $passerelle_mag, $dns_prefere, $dns_auxiliaire, $Cx)
    SplashTextOn("Configuration IP", "Paramétrage réseau en cours ...", 400, 50, -1, -1, 33, -1, 18)
    Sleep(1000)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip reset c:\windows\temp\temp.txt', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set address ' & '"' & $Cx & '"' & ' static ' & $adresse_mag & ' ' & $masque_mag & ' ' & $passerelle_mag & ' 1', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip set dns ' & '"' & $Cx & '"' & ' static ' & $dns_prefere & ' primary', "", @SW_HIDE)
    RunWait(@ComSpec & ' /c ' & 'netsh interface ip add dns ' & '"' & $Cx & '"' & ' ' & $dns_auxiliaire & ' index=2', "", @SW_HIDE)
    SplashTextOn("Configuration IP", "Configuration IP terminée.", 400, 50, -1, -1, 33, -1, 18)
    Sleep(1000)
    SplashOff()
EndFunc   ;==>step1
 

Et la modification du nom de machine :

Code : Tout sélectionner

    SplashTextOn("Modif. nom", "Modif. nom PC en cours ...", 400, 50, -1, -1, 33, -1, 18)
    RegWrite($sCtrlKey & "\Control\Computername\ActiveComputername", "ComputerName", "REG_SZ", $sCmpName)
    RegWrite($sCtrlKey & "\Control\Computername\Computername", "ComputerName", "REG_SZ", $sCmpName)
    RegWrite($sCtrlKey & "\Services\Tcpip\Parameters", "Hostname", "REG_SZ", $sCmpName)
    RegWrite($sCtrlKey & "\Services\Tcpip\Parameters", "NV Hostname", "REG_SZ", $sCmpName)
    RegWrite($sLogonKey, "AltDefaultDomainName", "REG_SZ", $sCmpName)
    RegWrite($sLogonKey, "DefaultDomainName", "REG_SZ", $sCmpName)
    RegWrite("HKEY_USERS\.Default\Software\Microsoft\Windows Media\WMSDK\General", "Computername", "REG_SZ", $sCmpName)
    SplashTextOn("Modif. nom", "Modif. nom PC terminée.", 400, 50, -1, -1, 33, -1, 18)

[jguinch]

Salut.
Aillant eu pas mal de problèmes avec netsh (fonctionnement aléatoire, lenteur), je me suis penché sur le sujet.
Finalement, on peut faire ça sans passer par une commande externe, en utilisant WMI.

Un exemple :

► Afficher le texte_AddWins

Code : Tout sélectionner

_AddWins("Connexion au réseau local", "192.168.1.2", "")


Func _AddWins($sNetworkAdapter, $sWinsAddr1, $sWinsAddr2 = "")
    Local $sQueryNetAdapter, $sQueryNetAdapterConfig, $colNetAdapter, $colNetAdapterConfig
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    
    Local $objWMIService = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
    If $objWMIService = 0 Then Return -1

    $sQueryNetAdapter = "select * from Win32_NetworkAdapter Where NetConnectionID = '" & $sNetworkAdapter & "'"
    $colNetAdapter = $objWMIService.ExecQuery($sQueryNetAdapter, "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    
    If NOT IsObj($colNetAdapter) Then Return -1
    
    For $objNetAdapter In $colNetAdapter
        $netIndex = $objNetAdapter.Index
        $sQueryNetAdapterConfig = "select * from Win32_NetworkAdapterConfiguration Where Index = '" & $netIndex & "'"
        
        $colNetAdapterConfig = $objWMIService.ExecQuery($sQueryNetAdapterConfig, "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
        If NOT IsObj($colNetAdapterConfig) Then Return -1
        
        For $objNetAdapter In $colNetAdapterConfig
            $objNetAdapter.SetWINSServer($sWinsAddr1, $sWinsAddr2)
        Next
    Next
EndFunc