[R] Lire un dossier

[TT22]

Y'a quoi comme bug ?

[Zippo]

Code : Tout sélectionner

C:\Users\********\Desktop\test.au3 (248) : ==> Variable used without being declared.:
$msgbox = ("Ce Zippo date de Janvier "&$annee)
$msgbox = ("Ce Zippo date de Janvier "&^ ERROR

Quand la variable msgbox se défini, la variable annee n'est pas déclaré.

Un déveulopeur expérimenté m'avais dis un jour ; moins il y a de lignes moins il y a d'emmerde ... sur le coup j'ai rigolé mais en réalité il n'a pas tord. Si tu as le temps, je te lance un défi. Ré-édit ton script qu'il soit + fonctionnelle et moins de lignes. Pour t'aider utilise les array. Un moyen très fort pour limiter la taille d'un script !

[mikell]

@Zippo

Si tu as le temps, je te lance un défi.

Sympa, mais pour faire un nouveau post sur un nouveau sujet


@TT22

Code : Tout sélectionner

If StringInStr(FileGetAttrib($file), "D") <> 0  ; [color=#FF0000]$file est un dossier[/color]
If StringInStr(FileGetAttrib($file), "D") = 0  ; [color=#FF0000]$file est un fichier[/color]
 

[legend]

Il n'est pas recommandé d'utiliser des arrays qui contient des données sans rapport entre eux. (enfin c'est la même truc que des variables, ça fait que compliquer puisqu'ils portent le même nom et que tu peut oublier certains numero de cases)
la traduction d'un array est tableau en français, et je vois pas son importance si chaque case contient des trucs hors sujet du tableau. (sans relation avec les autres cases)
donc ce sera : plus ton code est plus organisé et clair (perso je passe plusieurs lignes automatiquement et je met plein de commentaires en maj.)
pour le sujet du post :
c'était plutot mikell qui était sur la bonne voie. j'ai bien aimé l'appel de la fonction en boucle.
le code qu'il t'a donné marche a merveille (chez moi). peut être que t'a oublié de mettre un fichier list.txt dans le dossier de ton script.
merci de passer en R si c'est le cas et bonne journée.

[Zippo]

Voilà BBQ fini .. Très bon d'ailleurs x)

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Local $arrayDossier[999],$arrayFichier[999],$fileList = "list.ini"
Dim $iNb = 0,$Contenu

_recherche("*.*",$arrayDossier,$arrayFichier,"")
FileWrite(FileOpen($fileList,1),$Contenu)

Func _recherche($filename,$arrayDossier,$arrayFichier,$Dossier)
Local $iDossier = 0,$iFichier = 0,$o = 0,$oldDossier =""
$iNb += 1
$search = FileFindFirstFile($filename)

If $search = -1 Then
    MsgBox(0, "Erreur", "Il n'y a pas de fichier ni de dossier")
    Return 0
EndIf

While 1
    $file = FileFindNextFile($search)
    If @error Then ExitLoop
    If StringInStr(FileGetAttrib($file), "D") <> 0 Then
        $arrayDossier[$iDossier] = $file
        $iDossier += 1
        $oldDossier = $Dossier
        $Dossier = $file
        _recherche($file & "\" & "*.*",$arrayDossier,$arrayFichier,$Dossier)
    EndIf
    If StringInStr(FileGetAttrib($file), "D") = 0 Then
        $arrayFichier[$iFichier] = $file
        $iFichier += 1
    EndIf


WEnd

If $oldDossier <> "" And $Dossier <> "" Then
    $Contenu &= '[' & @ScriptDir & ']' & @CRLF
;~  $ContenuFin = '[' & @ScriptDir & ']#Fin' & @CRLF
Else
    $Contenu &= '[' & $Dossier & ']' & @CRLF
;~  $ContenuFin = '[' & $Dossier & ']#Fin' & @CRLF
EndIf


For $i = 0 To UBound($arrayFichier) -1
    If $arrayFichier[$i] = "" Then
    Else
    $Contenu &= $arrayFichier[$i] & @CRLF
    EndIf
Next
;~ $Contenu &= $ContenuFin
FileClose($search)
EndFunc

 

Voilà =)

[TT22]

Pour la solution de Zippo, il affiche un message d'erreur

[TT22]

En fait, je vais reformuler ma demande :
je prend le même exemple qu'au début :
Si premier dossier s'appelle "dossier1" et qu'il contient un autre dossier qui se nome "dossier2" qui lui même contient un fichier qui se nome "fichier1" dans lequel est écrit "test". Il faudrait que le fichier.ini ressemble à ça :
dir_number=2
file_number=1
dir1=\dossier1
dir2=\dossier1\dossier2
file1=\dossier1\dossier2\fichier1
file1_write=test

[Zippo]

Hum ... Je suis desoler, je ne vois pas trop comment presenter ton truc

[TT22]

Moi non plus, c'est pour ça que je demande

[TommyDDR]

Bon... après 1h30 de codage... voilà une fonction "ListerDossier" qui devrait vous satisfaire :

► Afficher le textecode

Code : Tout sélectionner

#include "Array.au3"
Local $Tab = ListerDossier("C:", True) ; $Recursif = True -> Cherche dans les sous dossiers.
; $Tab est un tableau contenant la liste des fichiers.

Func ListerDossier($CheminDossier, $Recursif = False)
    Local $Search = FileFindFirstFile($CheminDossier & "\*")
    Local $Error
    Local $Tableau[1]
    Do
        $Fichier = FileFindNextFile($Search)
        $Error = @error
        If(Not($Error)) Then
            If(StringInStr(FileGetAttrib($CheminDossier & "\" & $Fichier), "D")) Then
                If($Recursif) Then
                    Local $TableauSousDossier = ListerDossier($CheminDossier & "\" & $Fichier, True)
                    If(UBound($Tableau, 1) = 1 And $Tableau[0] = "") Then
                        $Tableau = $TableauSousDossier
                    Else
                        If(UBound($Tableau, 1) > 1 And $Tableau[UBound($Tableau, 1)-1] = "") Then
                            ReDim $Tableau[UBound($Tableau, 1)-1]
                        EndIf
                        $Tableau = AssemblerTableaux($Tableau, $TableauSousDossier)
                    EndIf
                EndIf
            Else
                $Tableau[UBound($Tableau, 1)-1] = $CheminDossier & "\" & $Fichier
                ReDim $Tableau[UBound($Tableau, 1)+1]
            EndIf
        EndIf
    Until($Error)
    Return $Tableau
EndFunc

Func AssemblerTableaux($Tab1, $Tab2)
    If(IsArray($Tab1) And IsArray($Tab2)) Then
        Local $IndiceBase = UBound($Tab1, 1)
        ReDim $Tab1[UBound($Tab1, 1)+UBound($Tab2, 1)]
        For $i = 0 To UBound($Tab2, 1)-1
            $Tab1[$IndiceBase+$i] = $Tab2[$i]
        Next
    EndIf
    Return $Tab1
EndFunc

Il est conseillé de changer le dossier (C: prend beaucoup de temps)

[TT22]

Oaui, mais je ne vois pas ou je récupère les données

[TommyDDR]

J'ai mis un commentaire "$Tab contient les données... etc"

Donc une boucle for dessus du genre :

Code : Tout sélectionner

For $i = 0 To Ubound($Tab, 1)-1
    ConsoleWrite($Tab[$i] & @CRLF)
Next

Et vous pouvez lister les dossiers / fichiers.

Je vous laisse l'adapter à vos besoins...

[TT22]

Ouai, ça marche bien, mais ça ne répertorie que les dossiers qui contiennent des fichiers et pas les dossiers vides

[TommyDDR]

Pas faux !

Utilisez votre matière grise pour qu'ils y apparaissent

Si vous ne trouvez toujours pas demain soir, je règlerai le problème.

[mikell]

D'après un post du forum US, recherche "recursive search"
Franchement si ça, ça va pas, alors rien n'ira...

► Afficher le texte

Code : Tout sélectionner

$path = @scriptdir  ; <== dossier de départ (à adapter, chemin complet) 

$FileList = _RecFileListToArray($path, "*", 0, 1, 0)

$list = @scriptdir & "\list.txt"
$txt = FileOpen($list, 1)

$doss = 1
For $i = 1 to $FileList[0]
    If StringInStr(FileGetAttrib($path & "\" & $FileList[$i]), "D") <> 0 Then 
        FileWriteLine ($txt, @CRLF & $FileList[$i] & " (dossier " & $doss & ")") 
        $doss += 1
    Else
        FileWriteLine ($txt, $FileList[$i]) 
    EndIf
Next

FileClose($txt)


;##################################################################

; #FUNCTION# ===========================================

; Name...........: _RecFileListToArray
; Description ...: Lists files and\or folders in a specified path (Similar to using Dir with the /B Switch)
; Syntax.........: _RecFileListToArray($sPath[, $sFilter = "*"[, $iFlag = 0[, $iRecur = 0[, $iFullPath = 0]]]])
; Parameters ....: $sPath   - Path to generate filelist for.
;                 $sFilter - Optional the filter to use, default is *. Search the Autoit3 helpfile for the word "WildCards" For details.
;                 $iFlag   - Optional: specifies whether to return files folders or both
;                 |$iFlag=0 (Default) Return both files and folders
;                 |$iFlag=1 Return files only
;                 |$iFlag=2 Return Folders only
;                 $iRecur  - Optional: specifies whether to search in subfolders
;                 |$iRecur=0 (Default) Do not search in subfolders
;                 |$iRecur=1 Search in subfolders
;                 $iFullPath  - Optional: specifies whether to include initial path in result string
;                 |$iFullPath=0 (Default) Do not include initial path
;                 |$iFullPath=1 Include initial path
; Return values .: @Error - 1 = Path not found or invalid
;                 |2 = Invalid $sFilter
;                 |3 = Invalid $iFlag
;                 |4 = Invalid $iRecur
;                 |5 = Invalid $iFullPath
;                 |6 = No File/Folder Found
; Author ........: SolidSnake <MetalGX91 at GMail dot com>
; Modified.......: 22 Jan 09 by Melba23 - added recursive search and full path options
; Remarks .......: The array returned is one-dimensional and is made up as follows:
;                               $array[0] = Number of Files\Folders returned
;                               $array[1] = 1st File\Folder
;                               $array[2] = 2nd File\Folder
;                               $array[3] = 3rd File\Folder
;                               $array[n] = nth File\Folder
; Related .......:
; Link ..........;
; Example .......; Yes
; ==============================================================================
;Special Thanks to Helge and Layer for help with the $iFlag update
; speed optimization by code65536
;===============================================================================
Func _RecFileListToArray($sPath, $sFilter = "*", $iFlag = 0, $iRecur = 0, $iFullPath = 0)
    Local $asFileList[1], $sFullPath
    If Not FileExists($sPath) Then Return SetError(1, 1, "")
    If StringRight($sPath, 1) <> "\" Then $sPath = $sPath & "\"
    If (StringInStr($sFilter, "\")) Or (StringInStr($sFilter, "/")) Or (StringInStr($sFilter, ":")) Or (StringInStr($sFilter, ">")) Or (StringInStr($sFilter, "<")) Or (StringInStr($sFilter, "|")) Or (StringStripWS($sFilter, 8) = "") Then Return SetError(2, 2, "")
    If Not ($iFlag = 0 Or $iFlag = 1 Or $iFlag = 2) Then Return SetError(3, 3, "")
    If Not ($iRecur = 0 Or $iRecur = 1) Then Return SetError(4, 4, "")
    If $iFullPath = 0 Then
        $sFullPath = $sPath
    ElseIf $iFullPath = 1 Then
        $sFullPath = ""
    Else
        Return SetError(5, 5, "")
    EndIf
    _FLTA_Search($sPath, $sFilter, $iFlag, $iRecur, $sFullPath, $asFileList)
    If $asFileList[0] = 0 Then Return SetError(6, 6, "")
    Return $asFileList
EndFunc  ;==>_FileListToArray

; #INTERNAL_USE_ONLY#===========================================================
; Name...........: _FLTA_Search
; Description ...: Searches folder for files and then recursively searches in subfolders
; Syntax.........: _FLTA_Search($sStartFolder, $sFilter, $iFlag, $iRecur, $sFullPath, ByRef $asFileList)
; Parameters ....: $sStartFolder - Value passed on from UBound($avArray)
;                 $sFilter - As set in _FileListToArray
;                 $iFlag - As set in _FileListToArray
;                 $iRecur - As set in _FileListToArray
;                 $sFullPath - $sPath as set in _FileListToArray
;                 $asFileList - Array containing found files/folders 
; Return values .: None
; Author ........: Melba23 based on code from _FileListToArray by SolidSnake <MetalGX91 at GMail dot com>
; Modified.......: 
; Remarks .......: This function is used internally by _FileListToArray.
; Related .......:
; Link ..........; 
; Example .......;
; ===============================================================================
Func _FLTA_Search($sStartFolder, $sFilter, $iFlag, $iRecur, $sFullPath, ByRef $asFileList)
    
    Local $hSearch, $sFile

    If StringRight($sStartFolder, 1) <> "\" Then $sStartFolder = $sStartFolder & "\"
; First look for filtered files/folders in folder
    $hSearch = FileFindFirstFile($sStartFolder & $sFilter)
    If $hSearch > 0 Then
        While 1
            $sFile = FileFindNextFile($hSearch)
            If @error Then ExitLoop
            Switch $iFlag
                Case 0; Both files and folders
                    If $iRecur And StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") <> 0 Then ContinueLoop
                Case 1; Files Only
                    If StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") <> 0 Then ContinueLoop
                Case 2; Folders only
                    If StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") = 0 Then ContinueLoop
            EndSwitch
            If $iFlag = 1 And StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") <> 0 Then ContinueLoop
            If $iFlag = 2 And StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") = 0 Then ContinueLoop
            _FLTA_Add($asFileList, $sFullPath, $sStartFolder, $sFile)
        WEnd
        FileClose($hSearch)
        ReDim $asFileList[$asFileList[0] + 1]
    EndIf
    
    If $iRecur = 1 Then
    ; Now look for subfolders
        $hSearch = FileFindFirstFile($sStartFolder & "*.*")
        If $hSearch > 0 Then
            While 1
                $sFile = FileFindNextFile($hSearch)
                If @error Then ExitLoop
                If StringInStr(FileGetAttrib($sStartFolder & $sFile), "D") And ($sFile <> "." Or $sFile <> "..") Then
                ; If folders needed, add subfolder to array
                    If $iFlag <> 1 Then _FLTA_Add($asFileList, $sFullPath, $sStartFolder, $sFile)
                ; Recursive search of this subfolder
                    _FLTA_Search($sStartFolder & $sFile, $sFilter, $iFlag, $iRecur, $sFullPath, $asFileList)
                EndIf
            WEnd
            FileClose($hSearch)
        EndIf
    EndIf
    
EndFunc

; #INTERNAL_USE_ONLY#========================================================

; Name...........: _FLTA_Add
; Description ...: Searches folder for files and then recursively searches in subfolders
; Syntax.........: _FLTA_Add(ByRef $asFileList, $sFullPath, $sStartFolder, $sFile)
; Parameters ....: $asFileList - Array containing found files/folders 
;                 $sFullPath - $sPath as set in _FileListToArray
;                 $sStartFolder - Value passed on from UBound($avArray)
;                 $sFile - Full path of file/folder to add to $asFileList
; Return values .: Function only changes $asFileList ByRef
; Author ........: Melba23 based on code from _FileListToArray by SolidSnake <MetalGX91 at GMail dot com>
; Modified.......: 
; Remarks .......: This function is used internally by _FileListToArray.
; Related .......:
; Link ..........; 
; Example .......;
; ============================================================================

Func _FLTA_Add(ByRef $asFileList, $sFullPath, $sStartFolder, $sFile)
    
    Local $sAddFolder
    
    $asFileList[0] += 1
    If UBound($asFileList) <= $asFileList[0] Then ReDim $asFileList[UBound($asFileList) * 2]
    If $sFullPath = "" Then
        $sAddFolder = $sStartFolder
    Else
        $sAddFolder = StringReplace($sStartFolder, $sFullPath, "")
    EndIf
    $asFileList[$asFileList[0]] = $sAddFolder & $sFile
    
EndFunc

[TT22]

Eh ben voilà, c'est parfait !
Je passe en résolut