[..] Deuxième Boucle while bloquant les évènements

[stevanovich]

Je ne comprend vraiment pas votre problématique.
Lors de l'affichage de la fenêtre de login, vous n'avez rien de spécial à faire, donc pourquoi compliquer les choses ?

Ok, donc je dois être compliqué ...

Dans ma façon de voir les choses, qui, visiblement, n'est pas la bonne, mon premier process est autonome, j'ai une boucle while/wend qui tourne pour effectuer quelques transferts TCP et autres bricoles.
Et .... à un moment donné, pour certaines tâches, j'ai besoin d'effectuer une authentification.
Donc, j'appui sur un de mes boutons (exemple : effectuer une requête sur un serveur php), et donc, j'ai besoin d'un login et d'un password, et là donc, on y vient, je souhaitais afficher ma seconde boite login/password, et qui, lorsque le résultat est correcte, envoie la requête.
Hors, dans le cas présent, tout le process du bouton requête s'execute sans avoir pu valider le login/password, et les autres process sont interrompus ... c'est vrai que je complique les choses .....

En ce qui concerne le 3 des messages précédents, je parlais du paramètre parent de la commande GUICreate.

Ok, Merci.

Cordialement.

[Tlem]

En reprenant le code de votre premier message, voici sans doute plus ou moins ce que vous attendez :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt("GUIOnEventMode", 1)
Global  $b_Sortie

Global $GUI_Form1 = GUICreate("Exemple while", 238, 158, 285, 167)
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
Global $h_Login = GUICtrlCreateButton("Login", 32, 16, 113, 33, 0)
GUICtrlSetOnEvent($h_Login,"Process_Login")
GUISetState(@SW_SHOW)

Global $GUI_Login = GUICreate("Login", 200, 58, 348, 353, -1, -1, $GUI_Form1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Process_Valid")
Global $h_Password = GUICtrlCreateInput("", 16, 8, 121, 21, BitOR($ES_PASSWORD,$ES_AUTOHSCROLL))
Global $h_Valid = GUICtrlCreateButton("OK", 144, 8, 33, 25, 0)
GUICtrlSetOnEvent($h_Valid,"Process_Valid")

While 1
    Sleep(50)
WEnd

Func Process_Login()
    ToolTip("Process_Login")
    MsgBox(8192,"Essai","Faut taper OK",10)
    ToolTip("")
    GUISetState(@SW_SHOW,$GUI_Login)
EndFunc

Func Process_Valid()
    GUISetState(@SW_HIDE,$GUI_Login)
    if GuiCtrlRead($h_Password) = "OK" Then
        $b_Sortie = True
        ToolTip("Process_Valid")
        MsgBox(8192,"Essai","ok login effectué",10)
        ToolTip("")
    Else
        $b_Sortie = False
        MsgBox(8192,"Essai","Pas de login",10)
    EndIf
EndFunc

Func Close()
    Exit
EndFunc

Vous parlez souvent de process, mais si je lit votre code, vous parlez du code exécuté par une fonction.
N'oubliez pas une chose; c'est que AutoIt n'est pas multitâche, donc une fonction ne peut être considérée comme un process, mais plutôt comme faisant partie du process principal/général.

Par contre vous pouvez utiliser la commande AdlibRegister qui vous permettra de partager les ressources entre différentes fonctions.
Cette fonction, c'est comme le Canada dry.
Ça ressemble à du multitâche, ca a la couleur du multitâche, mais ce n'est pas du multitâche ...
Par contre, ca aide bien.

[stevanovich]

En reprenant le code ....

Ok, je pense que je vais regarder du coté AdlibRegister qui semblerait être la fonction que je recherche ....
Je ferais un test en vous renverrais un résultat.
Merci.

[Alexward]

Bon bah essai sa alors

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
Global $b_Sortie

Global $Form1 = GUICreate("Exemple While", 211, 77, 192, 124)
GUISetBkColor(0x3399FF)
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
Global $h_Login = GUICtrlCreateButton("Login", 32, 24, 139, 25, $WS_GROUP)
GUICtrlSetFont(-1, 10, 800, 0, "Segoe UI")
GUICtrlSetOnEvent($h_Login,"Process_Login")
GUISetState(@SW_SHOW)

Global $GUI_Login = GUICreate("Login", 185, 67, 220, 134)
GUISetBkColor(0x3399FF)
Global $h_Password = GUICtrlCreateInput("", 8, 24, 129, 21)
Global $h_Valid = GUICtrlCreateButton("Ok", 144, 22, 33, 25, $WS_GROUP)
GUICtrlSetOnEvent($h_Valid,"Process_Valid")



While 1
 if $b_Sortie then ExitLoop
WEnd

Func Close()
 Exit
EndFunc

Func Process_Valid()
 ToolTip("Process_Valid")
 if GuiCtrlRead($h_Password) = "OK" Then
 $b_Sortie = True
MsgBox(0,"Essai","ok login effectué",10)
 Else
 MsgBox(0,"Manqué", "Mauvais Mot de Passe")
 EndIf
EndFunc

Func Process_Login()
 MsgBox(0,"Essai","Faut taper OK",10)
 ToolTip("Process_Login")
 GUISetState(@SW_SHOW,$GUI_Login)
 $b_Sortie = False
 EndFunc