[R] Creation de GUI (Surveillance Ping)

[DimVar]

Bonjour,


Si qqun peut me préparer une GUI, contenant :
une zone de saisie d'IP,
une zone dans laquelle s'ajoute la ou les adresses IP, elle même contenant un "voyant" status (texte ou image/icon),
une zone de gestion des actions pour la zone précédente (supprimer de la zone et mettre en pause)

D'avance merci.

Cdlt, Dimvar.

[TommyDDR]

Je n'avais rien dit pour l'ancien sujet mais : Je vous conseille de mettre un titre plus explicite, beaucoup de gens n'ouvrent les sujets que si le titre les y invitent.

[jguinch]

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiIPAddress.au3>
#include <ListViewConstants.au3>
#include <GuiImageList.au3>

Opt("GUIOnEventMode", 1)

Local $sTitle = "IP Status"
Local $iW = 170, $iH = 300
Global $iTimeOut = 2000

Global $iRunning = 0

Global $hGui = GUICreate($sTitle, $iW, $iH)
Global $hIPAddress = _GUICtrlIpAddress_Create ( $hGui, 10, 10, 125, 20)

Global $ID_Add = GUICtrlCreateButton( ChrW (0xBB), 140, 10, 20, 20)

Global $ID_Listview = GUICtrlCreateListView("Adresse IP", 10, 40, 150, 200, BitOR($LVS_NOCOLUMNHEADER, $LVS_SORTASCENDING) )
_GUICtrlListView_SetColumnWidth ( $ID_Listview, 0, 145 )

Global $ID_Go = GUICtrlCreateButton("GO", 35, 260, 100, 25)
GUICtrlSetState($ID_Go, $GUI_DISABLE)

Global $ID_Remove = GUICtrlCreateButton( ChrW (0xAB), 140, 240, 20, 20)
GUICtrlSetState($ID_Remove, $GUI_DISABLE)

GUICtrlSetTip($ID_Add, "Ajouter l'adresse IP à  la liste")
GUICtrlSetTip($ID_Remove, "Supprimer l'adresse IP sélectionnée de la liste")


Global $hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, 0x999999, 16, 16)) ; en attente
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, 0x00ff33, 16, 16)) ; ping
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, 0xff0000, 16, 16)) ; ping pas
_GUICtrlListView_SetImageList($ID_Listview, $hImage, 1)


GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlSetOnEvent($ID_Add, "_AddIP")
GUICtrlSetOnEvent($ID_Remove, "_RemoveIP")
GUICtrlSetOnEvent($ID_Go, "_Go")

GUISetState()

While 1
    Sleep(0xFFFF)
WEnd

Func _Go()
    Local $sIP, $iPing

    GUICtrlSetData($ID_Go, "En cours...")
    ControlDisable($hGui, "", $hIPAddress)
    GUICtrlSetState($ID_Add, $GUI_DISABLE)
    GUICtrlSetState($ID_Remove, $GUI_DISABLE)
    GUICtrlSetState($ID_Go, $GUI_DISABLE)

    For $i = 0 To _GUICtrlListView_GetItemCount ( $ID_Listview ) - 1
        $sIP = _GUICtrlListView_GetItemText($ID_Listview, $i)
        _GUICtrlListView_SetItemText($ID_Listview, $i, $sIP & " <" )
        
        _GUICtrlListView_SetItemImage ( $ID_Listview, $i,     ( Ping($sIP, $iTimeOut) ? 1 : 2)       )
        
        _GUICtrlListView_SetItemText($ID_Listview, $i, $sIP )
    Next
    
    GUICtrlSetData($ID_Go, "Go")
    ControlEnable($hGui, "", $hIPAddress)
    GUICtrlSetState($ID_Remove, $GUI_ENABLE)
    GUICtrlSetState($ID_Add, $GUI_ENABLE)
    GUICtrlSetState($ID_Go, $GUI_ENABLE)
EndFunc

Func _AddIP()
    Local $sIP = _GUICtrlIpAddress_Get($hIPAddress)
    For $i = 0 To _GUICtrlListView_GetItemCount ( $ID_Listview ) - 1
        If $sIP = _GUICtrlListView_GetItemText($ID_Listview, $i) Then Return
    Next

    _GUICtrlIpAddress_ClearAddress ( $hIPAddress )
    _GUICtrlListView_AddItem ( $ID_Listview, $sIP, 0)
    
    GUICtrlSetState($ID_Remove, $GUI_ENABLE)
    GUICtrlSetState($ID_Go, $GUI_ENABLE)
EndFunc

Func _RemoveIP()
    _GUICtrlListView_DeleteItemsSelected($ID_Listview)
    GUICtrlSetState($ID_Remove,   _GUICtrlListView_GetItemCount($ID_Listview) = 0 ? $GUI_DISABLE  : $GUI_ENABLE) 
    GUICtrlSetState($ID_Go,   _GUICtrlListView_GetItemCount($ID_Listview) = 0 ? $GUI_DISABLE  : $GUI_ENABLE) 
EndFunc

Func _Exit()
    Exit
EndFunc

 

[DimVar]

@Tommy : Merci, rectifié.
@Jg : Merci, je jette un oeil cet aprem.

[DimVar]

Top ! Merci JG pour le temps passé.
Je me permet qq questions pour ma culture... (d'autres viendront surement )
-------------------------------------------


S'agit il d'un oubli ?

Code : Tout sélectionner

Global $iRunning = 0

Y a t il une raison pour poser des functions dans le pavé des variables ? EX : _GUICtrlListView_SetColumnWidth

Pourquoi chrW() plutôt qu'une string pour le bouton d'ajout d'une IP ?

Comment faire en sorte que la touche entrée valide la saisie de l'IP ?


Cdlt, Dimvar.

[TommyDDR]

1) ChrW(0xBB) permet d'avoir un double chevron vers la droite, rien ne vous oblige à le mettre, c'est juste une question de préférence niveau beauté
2) Pour que la touche enter valide la saisie de l'ip, utilisez GUISetAccelerator, voici un exemple :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt("MustDeclareVars", 1)
Opt("GuiOnEventMode", 1)

Global $gui
Global $taille[2] = [300, 300]
Global $valider

$gui = GUICreate("", $taille[0], $taille[1])
GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $gui)
$valider = GUICtrlCreateButton(ChrW(0xBB), 140, 10, 20, 20)
GUICtrlSetOnEvent($valider, "valider")
Global $accelerators[1][2] = [["{ENTER}", $valider]]
GUISetAccelerators($accelerators, $gui)
GUISetState(@SW_SHOW, $gui)

While(True)
    Sleep(10)
WEnd

Func valider()
    MsgBox(0, "", "clic valider")
EndFunc

Func quit()
    Exit
EndFunc
 

Pour le cas de la touche entrer, vous pouvez aussi utiliser

Code : Tout sélectionner

GUICtrlSetState($button, $GUI_DEFBUTTON

[DimVar]

1) ChrW(0xBB) permet d'avoir un double chevron vers la droite, rien ne vous oblige à le mettre, c'est juste une question de préférence niveau beauté

ça je vois, mais l'aide parle d'un chiffre/nombre entre 0-65535. (et non d'une valeur hexa)...

[EDIT] Merci pour le GUISETACCELERATORS

[TommyDDR]

Une valeur en hexa est est un nombre.
0xBB = 187, c'est juste une autre maniere de l'écrire, mais c'est la même chose

[DimVar]

Ok, merci.

Quel est l’intérêt de la boucle dans _addip() ?

[jguinch]

Global $iRunning = 0 est un oubli (j'étais parti sur un truc que j'ai supprimé)
Pour la boucle dans _AddIp(), elle permet simplement d'éviter qu'une même adresse IP soit ajoutée deux fois dans la liste.
Pour ChrW (0xBB), c'est un truc que j'ai récupéré dans un de mes scripts. J'étais parti avec les valeurs affichés dans charmap.
Pour _GUICtrlListView_SetColumnWidth, il est placé juste après la listview. Ca peut être placé n'importe où, du moment que la variable (hwnd) est accessible.

[DimVar]

Merci JG.

1).Est il possible de faire en sorte que :
Lorsque l'on execute la fonction _go (), elle teste toutes les IP en un tour de boucle, plutot que l'une apres l'autre. Dés que l'on a 10 IPs, on attends 10x sleep(2000) $iTimeout....

2).Quelle est cette bizarrerie ?

Code : Tout sélectionner

_GUICtrlListView_SetItemImage ($ID_Listview, $i,[b](Ping($sIP, $iTimeOut) ? 1 : 2))[/b]

Merci.

[TommyDDR]

2) C'est l'opérateur ternaire (http://forum.phpfrance.com/faq-tutoriel ... 14111.html).
"condition ? _vrai : _faux"
Si la condition est vrai, alors la valeur "_vrai" sera utilisée, sinon, c'est la valeur "_faux" qui sera prise.

[DimVar]

Hum hum...
Donc ca sert à forcer le return value de Ping, en 0 ou 1 ?
Mais dans ce cas, que vaudra le code retour de Ping quand il pinguera et inversement ?
Quid de @error en cas d'echec ? Elle n'est plus renseignée ?

[TommyDDR]

non, ça sert à afficher une image en fonction du retour de la fonction ping.
Cela revient à faire ça :

Code : Tout sélectionner

Local $ping = Ping($sIP, $iTimeOut)
Local $image
If($ping = 0) Then
    $image = 2
Else
    $image = 1
EndIf
_GUICtrlListView_SetItemImage ($ID_Listview, $i, $image)

[DimVar]

@Tommy : Merci

petit UP :
1).Est il possible de faire en sorte que :
Lorsque l'on execute la fonction _go (), elle teste toutes les IP en un tour de boucle, plutot que l'une apres l'autre. Dés que l'on a 10 IPs, on attends 10x sleep(2000) $iTimeout....

[Petit UP]

[TommyDDR]

Le plus simple serait d'exécuter le commande ping dans un processus différent et d'analyser les retours console dans une boucle.
Le plus propre serait de recoder le ping en mode non bloquant.

Voici pour le plus simple :

► Afficher le textecode

Code : Tout sélectionner

#include <Array.au3>
#include <AutoItConstants.au3>

Local $ips = ["127.0.0.1", @IPAddress1, @IPAddress2, "1.1.1.1"]

Local $ping = MultiPingPing($ips)
_ArrayDisplay($ping)

Func MultiPingPing($ips)
    Local $nbIps = UBound($ips, 1)
    Local $retour[$nbIps]
    Local $pids[$nbIps]
    For $i = 0 To $nbIps-1
        $retour[$i] = False
        Local $cmdLineExec = "ping " & $ips[$i] & " -n 1"
        $pids[$i] = Run($cmdLineExec, "", @SW_HIDE, BitOR($STDOUT_CHILD, $STDERR_CHILD, $STDERR_MERGED))
    Next

    Local $noProcess = True

    Do
        $noProcess = True
        For $i = 0 To $nbIps-1
            Local $stdout = StdoutRead($pids[$i])
            If(StringInStr($stdout, "TTL=")) Then
                $retour[$i] = True
            EndIf
            If(ProcessExists($pids[$i])) Then
                $noProcess = False
            EndIf
        Next
        Sleep(50)
    Until($noProcess)
    Return $retour
EndFunc
 

[jguinch]

Pour avoir plusieurs Ping en parallèle, tu n'auras pas d'autre choix que de les faire exécuter dans des programmes externes (comme l'a proposé Tommy).
Je suis reparti de mon code précédent et ajouté quelques trucs.
L'exécution du Ping se fait dans un process parallèle, mais avec la commande Ping AutoIt (qui permet de récupérer le temps de réponse facilement).
En utilisant AdLibRegister, on arrive à faire un truc non bloquant, mais sans forcément avoir un truc simple.
Pour les résultats, j'ai choisi de les stocker temporairement dans un fichier INI, qui évite l'utilisation d'un StdOutRead (c'est une autre méthode, simplement)
Pour les 10 Ping simultanés, c'est paramétrable, mais faudra y aller doucement
Ca donne ça pour l'instant :

► Afficher le texte

Code : Tout sélectionner

#pragma compile(AutoItExecuteAllowed, True)


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiIPAddress.au3>
#include <ListViewConstants.au3>
#include <GuiImageList.au3>

Opt("GUIOnEventMode", 1)


; Variables à changer #########################################################################
Global $sTitle = "IP Status" ; titre de la GUI
Global $iW = 240, $iH = 300 ; taille de la GUI
Global $iTimeOut = 400 ; Timeout du Ping
Global $iMaxRunningProcess = 10 ; nombre de Ping simultanés
Global $sTextStart = "Ping", $sTextStop = "Stop", $sTextStopping = "Arrêt...", $sTextRunning = "En cours" ; texte de la GUI
Global $iColorStatus1 = 0xFFFFFF, $iColorStatus2 = 0x999999, $iColorStatus3 = 0x00ff33, $iColorStatus4 = 0xff0000 ; couleurs des vignettes
Global $sTempFile = @TempDir & "\MultiPingAU3.ini" ; fichier INI temporaire qui stocke les résultats
; #############################################################################################

Global $iRunning = 0
Global $aPingRunning
Global $iRunningCount = 0

Global $hGui = GUICreate($sTitle, $iW, $iH)
Global $hIPAddress = _GUICtrlIpAddress_Create ( $hGui, 10, 10, 125, 20)

Global $ID_Add = GUICtrlCreateButton( ChrW (0xBB), 140, 10, 20, 20)

Global $ID_Listview = GUICtrlCreateListView("Adresse IP|Resultat", 10, 40, 220, 200, BitOR($LVS_NOCOLUMNHEADER, $LVS_SORTASCENDING) )
_GUICtrlListView_SetColumnWidth ( $ID_Listview, 0, 145 )

Global $ID_Go = GUICtrlCreateButton($sTextStart, 50, 270, 140, 25)

Global $ID_Remove = GUICtrlCreateButton( ChrW (0xAB), 210, 240, 20, 20)

GUICtrlSetTip($ID_Add, "Ajouter l'adresse IP à  la liste")
GUICtrlSetTip($ID_Remove, "Supprimer l'adresse IP sélectionnée de la liste")


Global $hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, $iColorStatus1, 16, 16)) ; en attente
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, $iColorStatus2, 16, 16)) ; en cours
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, $iColorStatus3, 16, 16)) ; ping
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($ID_Listview, $iColorStatus4, 16, 16)) ; ping pas
_GUICtrlListView_SetImageList($ID_Listview, $hImage, 1)


; Pré-remplissage #################################################
_GUICtrlListView_AddItem ( $ID_Listview, @IPAddress1, 0)
_GUICtrlListView_AddItem ( $ID_Listview, "127.0.0.1", 0)
_GUICtrlListView_AddItem ( $ID_Listview, "192.168.1.1", 0)
_GUICtrlListView_AddItem ( $ID_Listview, "173.194.45.73", 0)
; #################################################################


GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlSetOnEvent($ID_Add, "_AddIP")
GUICtrlSetOnEvent($ID_Remove, "_RemoveIP")
GUICtrlSetOnEvent($ID_Go, "_Go")

GUISetState()

While 1
    Sleep(0xFFFF)
WEnd



Func _Go()
    Local $sIP, $iPing, $iResult

    If $iRunning Then Return _StopPing()

    $iRunning = 1
    GUICtrlSetData($ID_Go, $sTextStop)
    ControlDisable($hGui, "", $hIPAddress)
    GUICtrlSetState($ID_Add, $GUI_DISABLE)
    GUICtrlSetState($ID_Remove, $GUI_DISABLE)

    FileDelete($sTempFile)
    Local $iCount = _GUICtrlListView_GetItemCount ( $ID_Listview )

    Local $aTemp[$iCount][3]
    $aPingRunning = $aTemp

    For $i = 0 To $iCount - 1
        $sIP = _GUICtrlListView_GetItemText($ID_Listview, $i)
        $aPingRunning[$i][0] = $sIP
    Next
    AdlibRegister("_PingProcess", 500)
EndFunc




Func _PingProcess()
    Local $iResult

    For $i = 0 To UBound($aPingRunning) - 1
        If $aPingRunning[$i][2] == "" Then
            If $aPingRunning[$i][1] = ""  Then
                If $iRunningCount < $iMaxRunningProcess AND $iRunning Then
                    $aPingRunning[$i][1] = Run(@AutoItExe & ' /AutoIt3ExecuteLine "IniWrite(''' & $sTempFile & ''', ''RUNNING'', ''' & $aPingRunning[$i][0] & ''', Ping(''' & $aPingRunning[$i][0] & ''', ' & $iTimeOut & ') )"')
                    $iRunningCount += 1
                    _GUICtrlListView_SetItemImage ( $ID_Listview, $i, 1)
                    _GUICtrlListView_SetItemText($ID_Listview, $i, $sTextRunning, 1)
                EndIf
            Else
                If NOT ProcessExists($aPingRunning[$i][1]) Then
                    $iRunningCount -= 1
                    $iResult = Number(IniRead($sTempFile, "RUNNING", $aPingRunning[$i][0], "0"))
                    $aPingRunning[$i][2] = $iResult

                    If $iResult Then
                        $sRes = $iResult & " ms"
                    Else
                        $sRes = "-"
                    EndIf
                    _GUICtrlListView_SetItemText($ID_Listview, $i, $sRes, 1)
                    _GUICtrlListView_SetItemImage ( $ID_Listview, $i,     ( $iResult ? 2 : 3)     )
                EndIf
            EndIf

        EndIf
    Next

    If $iRunningCount = 0 Then
        AdlibUnRegister("_PingProcess")
        FileDelete($sTempFile)
        _EndPing()
    EndIf

    Return $iRunningCount
EndFunc



Func _StopPing()
    AdlibUnRegister("_PingProcess")
    GUICtrlSetData($ID_Go, $sTextStopping)
    GUICtrlSetState($ID_Go, $GUI_DISABLE)

    AdlibRegister("_PingProcessWait")
EndFunc





Func _PingProcessWait()
    If NOT _PingProcess() Then
        _EndPing()
        AdlibUnRegister("_PingProcessWait")
    EndIf
EndFunc





Func _EndPing()
    $iRunning = 0
    GUICtrlSetData($ID_Go, $sTextStart)
    GUICtrlSetState($ID_Go, $GUI_ENABLE)
    ControlEnable($hGui, "", $hIPAddress)
    GUICtrlSetState($ID_Remove, $GUI_ENABLE)
    GUICtrlSetState($ID_Add, $GUI_ENABLE)
EndFunc




Func _AddIP()
    Local $sIP = _GUICtrlIpAddress_Get($hIPAddress)
    For $i = 0 To _GUICtrlListView_GetItemCount ( $ID_Listview ) - 1
        If $sIP = _GUICtrlListView_GetItemText($ID_Listview, $i) Then Return
    Next

    _GUICtrlIpAddress_ClearAddress ( $hIPAddress )
    _GUICtrlListView_AddItem ( $ID_Listview, $sIP, 0)

    GUICtrlSetState($ID_Remove, $GUI_ENABLE)
    GUICtrlSetState($ID_Go, $GUI_ENABLE)
EndFunc

Func _RemoveIP()
    _GUICtrlListView_DeleteItemsSelected($ID_Listview)
    GUICtrlSetState($ID_Remove,   _GUICtrlListView_GetItemCount($ID_Listview) = 0 ? $GUI_DISABLE  : $GUI_ENABLE)
    GUICtrlSetState($ID_Go,   _GUICtrlListView_GetItemCount($ID_Listview) = 0 ? $GUI_DISABLE  : $GUI_ENABLE)
EndFunc

Func _Exit()
    Exit
EndFunc
 

Voilà, j'ai une fois de plus réinventé la roue, car ce genre de truc existe déjà depuis belle lurette.

[DimVar]

Merci Jg.
Désolé de t'avoir sollicité à "réinventer la roue" mais les qq outils que j'ai pu trouver étaient soit trop complet, soit en share, ou pas du tout intuitif.
Bref, je teste ça, mais à première vue, ça fait le boulot.

Cdlt, Dimvar.