[R] Ecrire dans un fichier (remplacement de chaine)

[DimVar]

Bonjour,

Je n'ai toujours pas réussi à résoudre ce petit pb.
Je re-ouvre donc un topic.

Je souhaite modifier une chaine de caractères dans un fichier, en la remplaçant par une autre.
J'ai donc commencé mon script comme suit :

Code : Tout sélectionner

dim $file = FileOpen ("c:\test\test1.txt",0)
dim $mdp, $read

While $read <> "mdp=mdpDeX"
    $read = FileReadLine ($file)
WEnd

MsgBox (0,"",$read)

FileWriteLine ($file, "mdp=mdpDeY")

1er pb : Ok pour lire le fichier jusque la ligne contenant "mdp=mdpDeX". Le msgbox s'execute bien. Mais la modif sur fichier ne se fait pas. Normal me direz vous puisque j'ouvre le fichier avec le param "0" (fileopen)
Mais si je l'ouvre avec le parametre "1", la msgbox ne s'affiche pas.
2e pb : Comment remplacer l'ancien mdp (mdpDeX) par le nouveau (mdpDey) ?

Cela fait 5 jours que je me bat avec fileopen et filewriteline mais je tourne en rond.

[DimVar]

J'ai trouvé la soluce avec _ReplaceStringInFile. Mais j'aurais aimé comprendre le cheminement sans cette fonction.
Je laisse donc le topic en non resolu.

Merci à vous.

[Tlem]

Voilà comment vous auriez pu faire :

► Afficher le texteCode

Code : Tout sélectionner

#include <File.au3>

Dim $Fic = "test1.txt"
Dim $Count

; Création d'un nouveau fichier pour l'exemple.
_NewFile()

; Lecture du fichier ligne par ligne :
$hFile = FileOpen($Fic, 0)
While 1
    $line = FileReadLine($hFile)
    ; Si c'est la fin du fichier, on sort.
    If @error = -1 Then ExitLoop
    ; Petit compteur pour connaitre la ligne traitée.
    $Count = $Count + 1
    
    ; Ici je regarde si la chaine mdp=mdpDeX existe dans la ligne.
    If StringInStr($line, "mdp=mdpDeX") Then
        ; Je met à jour la variable $Line avec les nouvelles infos.
        $line = StringReplace($line, "mdp=mdpDeX", "mdp=mdpDeY")
        ; Fermeture du fichier (En lecture).
        FileClose($hFile)
        ; On écrit la ligne au bon endroit.
        _FileWriteToLine($Fic, $Count, $line, 1)
        MsgBox(64, "Info", "Le fichier à été modifié.")
        Exit
    EndIf
WEnd
FileClose($hFile)


Func _NewFile()
    ; Ecritur pour l'exemple de quelques lignes.
    FileWriteLine($Fic, "Line1")
    FileWriteLine($Fic, "Line2")
    FileWriteLine($Fic, "Line3")
    FileWriteLine($Fic, "Line4 avec mdp=mdpDeX")
    FileWriteLine($Fic, "Line5")

    MsgBox(64, "Info", "Le fichier " & $Fic & " à été créer !" & @CRLF & _
            "Nous allons modifier la ligne 4," & @CRLF & _
            "pour remplacer mdp=mdpDex par" & @CRLF & _
            "la chaîne mdp=mdpDeY .")

EndFunc   ;==>_NewFile

[DimVar]

Encore merci, je clos.