[R] Fenêtre saisie identifiants

[dj37]

Bonjour,

je suis encore novice sous autoit et malgrès pas mal de recherche je bloque pour traduire un petit fichier bat en autoit.

Concretement, mon fichier bat est le suivant :

Code : Tout sélectionner

@echo off
echo entrez le nom d'utilisateur:
set /p utilisateur=
echo entrez le mot de passe:
set /p psword=
net use V: \\TEST\%utilisateur% /USER:%utilisateur% %psword%
start /b explorer V:

Ce que je voudrais arriver à obtenir, c'est d'avoir une fenêtre où l'on doit saisir son nom d'utilisateur et son mot de passe et récupérer cette saisie comme variable pour utiliser la fonction drivemapadd.

Merci d'avance si quelqu'un peut me donner un coup de main.

Jérôme

[sylvanie]

Bonjour
On peut partir là dessus

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Connexion lecteur résseau", 438, 258, 300, 200)
$label_login = GUICtrlCreateLabel("Login", 40, 40, 30, 17)
$Input_login = GUICtrlCreateInput(@username, 96, 35, 185, 21)
$label_passwd = GUICtrlCreateLabel("Password", 42, 110, 50, 17)
$Input_password = GUICtrlCreateInput("", 98, 105, 185, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
$Button_connexion = GUICtrlCreateButton("Connexion", 312, 192, 73, 33)
$Label_encours = GUICtrlCreateLabel("Montage en cours ...", 42, 200, 100, 17)
GUICtrlSetState(-1,$GUI_HIDE)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $Button_connexion
            connexion_map()
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func connexion_map()
    Local $login,$passwd,$ctrl,$err,$lecteur
    $login=GUICtrlRead($Input_login)
    $passwd=GUICtrlRead($Input_password)
    $lecteur="V:"
    If ($login="") Or ($passwd="") Then
        MsgBox(16,"Erreur","Saisie d'identification incorrecte")
        return 0
    EndIf
    GUICtrlSetState($Button_connexion,$GUI_HIDE)
    GUICtrlSetState($Label_encours,$GUI_SHOW)
    $ctrl=DriveMapAdd($lecteur,"\\TEST\"&$login,0,$login,$passwd)
    $err=@error
    GUICtrlSetState($Label_encours,$GUI_HIDE)
    GUICtrlSetState($Button_connexion,$GUI_SHOW)
    If ($ctrl=0) Then
        MsgBox(16,"Erreur","Le montage de "&$lecteur&" a échoué"&@CRLF&"code erreur = "&$err)
        return 0
    EndIf
    return 1
EndFunc

 

Pour l'exploitation des retours d'erreur, cf l'aide de DriveMapAdd
Il se peut que vous ayez à compléter le login avec le nom de domaine

[dj37]

Merci, je vais essayer ça et je vous tiens au courant.

Jérôme

[dj37]

Merci beaucoup, c'est impeccable, il me reste à voir les retours d'erreurs de drivemapadd et à rajouter des contrôles.

En tout cas un grand merci pour la réactivité.

Jérôme

[sylvanie]

Tant mieux !
pensez alors à passer le sujet en [R] au niveau du premier message.
Merci