[R] Bug Report ??

[eheh34]

Bonjour !! J'aurais besoin d'un Script pour Signaler un bug !
Avec une textbox qui demande l'adresse mail
et une autre qui demande une description du bug !
Merci et j'espère que vous m'aurez compris et que j'ai assez décrit :/ !

[PandiPanda]

Bonjour,
et non je pense pas que vous ayez assez décrit ^^

Que voulez vous faire avec ceci?
Voila vous demandez la description du bug, l'adresse mail, mais ensuite??
- ecrire dans un fichier? un fichier log?
- envoi du rapport d'erreur par mail?
- par ftp? par tcp? ...

cette interface est suffisante??

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Rapport de Bug", 431, 249, 168, 144)
Global $LabelMail = GUICtrlCreateLabel("E-mail", 16, 8, 32, 17)
Global $InputMail = GUICtrlCreateInput("", 16, 32, 121, 21)
Global $EditBug = GUICtrlCreateEdit("", 152, 32, 273, 201)
GUICtrlSetData(-1, "EditBug")
Global $LabelBug = GUICtrlCreateLabel("Description du Bug", 152, 8, 94, 17)
Global $BoutonEnvoi = GUICtrlCreateButton("Send Rapport", 16, 56, 121, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $BoutonEnvoi
            ; implementer le boulot a faire
    EndSwitch
WEnd
 

[Uranium]

► Afficher le texte

Code : Tout sélectionner

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.8.1
 Author:         myName

 Script Function:
    Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here
#Include <File.au3>
#include <Inet.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Send it to me ", 213, 328, 192, 124)
$Input1 = GUICtrlCreateInput("adressemail@domaine.com", 8, 8, 193, 21)
$Edit1 = GUICtrlCreateEdit("", 8, 32, 193, 249)
GUICtrlSetData(-1,"Heure|Date : "&@HOUR&':'&@MIN&'  |   '&@WDAY&'/'&@MON&'/'&@YEAR&@crlf&"OS : "&@OSVersion &  ' , ' & @OSArch & @CRLF & "Description du bug : ")
$Button1 = GUICtrlCreateButton("Envoyez", 24, 288, 161, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
Global $s_SmtpServer="smtp.gmail.com"
Global $s_FromName="eheh34"
Global $s_FromAddress="tonadresse@gmail.com"
Global $s_ToAddress=GUICtrlRead($Input1)
Global $s_Subject = "Rapport de beug"
Global $as_Body = GUICtrlRead($Edit1)
Global $s_AttachFiles = ""
Global $s_CcAddress = ""
Global $s_BccAddress = ""
Global $s_Username = "ton adresse mail sans le domaine  , exemple autoit@gamil.com devient autoit"
Global $s_Password = "ton mot de passe"
Global $IPPort = 465
Global $ssl = 1
Global $s_Importance="Normal"

_INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body , $s_AttachFiles , $s_CcAddress, $s_BccAddress, $s_Importance, $s_Username, $s_Password , $IPPort , $ssl)
    EndSwitch
WEnd


_INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body , $s_AttachFiles , $s_CcAddress, $s_BccAddress, $s_Importance, $s_Username, $s_Password , $IPPort , $ssl)

Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
;~     Local $i_Error = 0
;~     Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
            ConsoleWrite('@@ Debug(62) : $S_Files2Attach = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort

    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    $objEmail=""
 EndFunc   ;==>_INetSmtpMailCom

Cette fonction vient du fofo US

[eheh34]

Voila Merci !! Merci pour votre aide et de votre Rapidité !

[eheh34]

Ah oui et encore un truc uranium, Y'aurais pas un moyen de mettre une msgbox a la fin pour quelle confirme si le mail a été envoyer ou pas ?

[eheh34]

A oui et j'ai réparer un bug qui y avait dans ton script !

C'était marqué sa :

Global $s_FromAddress="nom@gmail.com"
Global $s_ToAddress=GUICtrlRead($Input1)

et il fallait échanger en sa :

Global $s_FromAddress=GUICtrlRead($Input1)
Global $s_ToAddress="nom@gmail.com"

Pour que l'adresse email soit fixe !

[PandiPanda]

Bonjour, si vous voulez une msgbox()
il vous suffit de l'ajouter après "_INetSmtpMailCom()" cette ligne ceci;

Code : Tout sélectionner

If @error Then MsgBox(48,"erreur","erreur d'envoi de mail")
MsgBox(64,"Done","Mail envoyé")
 

[Uranium]

Si vous mettez

Code : Tout sélectionner

Global $s_FromAddress=GUICtrlRead($Input1)

alors il faut demandez le mot de passe à chaque fois

[eheh34]

Merci