[R] Remplir un List à partir d'un fichier texte

[GMH]

Bonjour,

Sauriez-vous me dire quelle(s) erreur(s) j'ai faite(s) dans ce code, souhaitant que le List soit rempli par les lignes d'un fichier texte :

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

global $lexique = "c:\autoit\lexique.dat"
global $fichier
global $list1
global $item

$gui = GUIcreate("Lexique",1010,720,10,10)
$list1 = GUIctrlCreateListView("",20, 80, 200,500)

$fichier = FileOpen($lexique,0)
If $fichier = -1 Then
    MsgBox(0, "Erreur", Le fichier ne peut être ouvert.")
    Exit
EndIf

While 1
    Local $ligne = FileReadLine($fichier)
    If @error = -1 Then ExitLoop
    $item = GUICtrlCreateListViewItem($ligne, $list1)
WEnd

FileClose($fichier)
GUIsetState()

sleep(20000)
 

Je vous remercie.

[sylvanie]

Bonjour,
Sur une listview, il faut obligatoirement nommer une colonne de réception :

► Afficher le texte

Code : Tout sélectionner

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>


global $lexique = @ScriptDir&"\lexique.dat"
global $fichier
global $list1
global $item

$gui = GUIcreate("Lexique",1010,720,10,10)
$list1 = GUIctrlCreateListView("colonne1",20, 80, 200,500)

$fichier = FileOpen($lexique,0)
If $fichier = -1 Then
    MsgBox(0, "Erreur", "Le fichier ne peut être ouvert.")
    Exit
EndIf

While 1
    Local $ligne = FileReadLine($fichier)
    If @error = -1 Then ExitLoop
    $item = GUICtrlCreateListViewItem($ligne, $list1)
WEnd
FileClose($fichier)
GUIsetState(@SW_SHOW )

While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE  Then ExitLoop
        Sleep(50)
WEnd
Exit 0

 

[jguinch]

Salut
Il faut indiquer le nom de colonne dans le ListView :

Code : Tout sélectionner

$list1 = GUIctrlCreateListView("NomDeLaColonne",20, 80, 200,500)

... sinon, utiliser GUICtrlCreateList puis ajouter avec les données avec GUICtrlSetData

Code : Tout sélectionner

[...]
$list1 = GUIctrlCreateList("",20, 80, 200,500)
[...]
While 1
    Local $ligne = FileReadLine($fichier)
    If @error = -1 Then ExitLoop

    GUICtrlSetData($list1, $ligne)
WEnd
[...]

[GMH]

Grand merci à tous deux.