[R] Supprimer un élément de la GUI

[banane]

Bonjour j'aimerais créer des onglets "dynamiques", quand on appui sur l'onglet "+" de la boite d'onglets, un nouvel onglet se créer automatiquement, et apres je veux aussi que cet "onglet" puisse se quitter en appuyant sur un autre bouton. Je ne sais pas si c'est possible.
J'ai déjà essayer de créer des onglets, ça marche mais je n'arrive pas à les fermer.
En gros je voudrais que les onglets marchent comme ceux de google chrome (c'est un exemple)

mikell Je sais que tu regarde ce Topic!

[mikell]

Mouais ça devient Big Brother ici

En fait ton script, ou tu le fais simple, quelque chose comme ça

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

GUICreate("My GUI Tab", 250, 170)
$tab = GUICtrlCreateTab(10, 10, 200, 100)
$plus = GUICtrlCreateButton("ajoute", 50, 120, 50, 22)
$moins = GUICtrlCreateButton("enlève", 120, 120, 50, 22)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
        Case $GUI_EVENT_CLOSE 
             ExitLoop
        Case $plus
            GUICtrlCreateTabItem("onglet")
        Case $moins
            GuiCtrlDelete(GUICtrlRead($tab, 1))
EndSwitch
WEnd
 

et ça sera pas trop dur à gérer, ou alors tu veux refaire chrome et dans ce cas il te faut éplucher le forum US et les fonctions _GUICtrlTab... et _GUIImageList... mais là tu te fais tes recherches et on en reparle dans 2 mois ^^

[blacksoul305]

et on en reparle dans 2 mois ^^

C'est si dur que ça ? Tu t'y es frotté ?

[banane]

Merci, comme un c n j'avais mis GUIDELETE au lieu de GUICTRLDELETE . (ou un truc du genre)
Et oui ici c'est une grande famille , j'avais vu ton pseudo dans: utilisateurs parcourant actuellement le forum

[mikell]

Bon j'ai un peu exagéré (mais à peine ^^)
Façon chrome ça pourrait se faire comme ça, mais après bonjour pour garnir les tabitems et gérer les contenus ...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>

$gui = GUICreate("My GUI Tab", 350, 170)
$tab = GUICtrlCreateTab(10, 10, 300, 100)
$tab0 = GUICtrlCreateTabItem("tab 0")
$tab1 = GUICtrlCreateTabItem("+")
GUICtrlCreateTabItem("")
$moins = GUICtrlCreateButton("enlève", 120, 120, 50, 22)
GUISetState()
$n = 0

While 1
$msg = GUIGetMsg()
Switch $msg
        Case $GUI_EVENT_CLOSE 
             ExitLoop
        Case $moins
            $selected = _GUICtrlTab_GetCurSel($tab)
            _GUICtrlTab_DeleteItem($tab, $selected)
            _GUICtrlTab_SetCurSel($tab, $selected-1)
       Case $tab
            If GUICtrlRead($tab) = _GUICtrlTab_FindTab($tab, "+")  Then  
               $n += 1
               $count = _GUICtrlTab_GetItemCount($tab)
               $tabindex = _GUICtrlTab_InsertItem($tab, $count-1, "tab " & $n)
               _GUICtrlTab_SetCurSel($tab, $tabindex)
           EndIf
EndSwitch
WEnd