[R] Array et Gui Child

[Julien]

Bonjour,

Voila un petit résumé du script :

► Afficher le texte

Code : Tout sélectionner

Global $Array[3][2] = [["Col1", "Col2"], _
        ["D1", "D3"], _
        ["D2", "D4"] _
        ]

Global $Form = GUICreate("titr", 200, 500, -1, -1)
Global $Group = GUICtrlCreateGroup("Group", 24, 39, 641, 81)

Global $Form2 = GUICreate("", 637, 224, 26, 215, $WS_POPUP, $WS_EX_MDICHILD, $Form)

While 1
    $nMsg = GUIGetMsg(1) ; Récupération des messages GUI avancés
    Switch $nMsg[1] ; Début du sélecteur de cas sur le handle de la fenêtre de l'événement
        Case $Form
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $GUI_EVENT_CLOSE ; (-3) = La boite de dialogue a été fermée (par le menu système ou un bouton défini).
                    Exit
                Case $Button
                    _ArrayDisplay($Array, "Array1")
            EndSwitch
        Case $Form2
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $Button2
                    _UpdateARRAY()
                    _ArrayDisplay($Array, "Array2")             
                Case $Button3
                    _ArrayDisplay($Array, "Array3")
            EndSwitch
    EndSwitch
WEnd
 

J'ai mis l'essentiel pour l'exemple. Donc une Gui dans une Gui pour afficher une scrollbar, lorsque le tableau est mis à jour ($Button2) Array2 s'affiche correctement en revanche pour les deux autres cas (Array1 et Array3) cela ne me montre que mon tableau d'origine.

Faut il indiquer au premier GUI que le tableau est à jour ?
Comment cela est-ce possible d'autant que $Array est déclaré en Global ?

D'avance merci.

[mikell]

En l'état, le code que tu as posté n'est pas utilisable donc ne sert à rien comme exemple
Qu'est-ce que tu veux faire au juste ?

La solution évidente serait de faire une seule gui avec une listview (qui aura une scrollbar), et des boutons pour mettre à jour la listview en même temps que l'array

[Julien]

Bonjour,

Effectivement le code que j'ai indiqué c'était juste les grandes lignes.

Ce que je veux faire :

Un GUI principal dans lequel il y'a un Tab (plusieurs onglets), dans un des onglets une zone avec scrollbar qui contient une série d’icône et de Checkbox (généré à la volée d'après un "Array" ou pas car je ne parviens pas à en maitriser les événements, l'icône s'affiche si une valeur est a True dans le "Array"), un clic sur une icône déclenche une action et idem pour les checkbox. Voila plus précisément ce que je veux faire.

Pour les événements je veux n'avoir à modifier que mon "Array", c'est à dire que tout le reste s'adapte en fonction de ce dernier. Les fonctions à exécuter y sont indiqués que se soit pour l’icône ou pour la checkbox.

Pour compléter, je vais avoir une fonction qui va juste créer le GUI en fonction du "Array", une fonction qui va se charger de mettre à jour le "Array" et une autre qui ne se chargera que de lire le "Array" pour mettre à jour. J'utilise le même Gui enfant pour faire du multipage (Suivant/Précédent) donc le "tableau" graphiquement est reconstruit à chaque changement de page avec mise à jour des données.

Merci.

En l'état, le code que tu as posté n'est pas utilisable donc ne sert à rien comme exemple

GUI principal :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>


#include "_GUIScrollbars_Ex.au3"

Global $Page = 1 ; Indiquant le numéro de la page en cours
Global $PageTotal = 3 ; Nombre de page total
Global $Array[3][4] = [["Text", "Function", "Icon", "Icon Function"], _
        ["Text1", "Fonction1(param)", "False", ""], _
        ["Text2", "Fonction2()", "True", "Fonction3()"] _
        ]

#include "Form2.au3"

Global $Form = GUICreate("Form", 698, 585, -1, -1)
Global $MenuFile = GUICtrlCreateMenu("&Fichier")
Global $MenuExit = GUICtrlCreateMenuItem("&Quitter", $MenuFile)
GUISetIcon("", -653)
GUISetFont(8, 400, 0, "Verdana")
Global $Tab = GUICtrlCreateTab(8, 8, 673, 481)
GUICtrlSetFont($Tab, 8, 400, 0, "Verdana")
Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
GUICtrlSetState($TabSheet1,$GUI_SHOW)
GUICtrlCreateTabItem("")
Global $TabSheet = GUICtrlCreateTabItem("Onglet")
Global $Button1 = GUICtrlCreateButton("<<", 36, 452, 35, 25)
GUICtrlSetFont($Button1, 8, 800, 0, "Verdana")
Global $Button2 = GUICtrlCreateButton(">>", 80, 452, 35, 25)
GUICtrlSetFont($Button2, 8, 800, 0, "Verdana")
Global $Label = GUICtrlCreateLabel($Page, 118, 456, 470, 17)
GUICtrlSetFont($Label, 8, 400, 0, "Verdana")
Global $CADRE = GUICtrlCreateGroup("CADRE", 24, 200, 641, 241)
GUICtrlSetFont($CADRE, 8, 400, 0, "Verdana")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateTabItem("")
Global $Button3 = GUICtrlCreateButton("Button3", 24, 504, 75, 25)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg(1) ; Récupération des messages GUI avancés
    Switch $nMsg[1] ; Début du sélecteur de cas sur le handle de la fenêtre de l'événement
        Case $Form
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $GUI_EVENT_CLOSE ; (-3) = La boite de dialogue a été fermée (par le menu système ou un bouton défini).
                    Exit
                Case $Tab
                    If GUICtrlRead($Tab) = 1 Then
                        _Form2()
                    Else
                        If IsDeclared("Form2") And $Form2 <> "" Then
                            GUISetState(@SW_HIDE, $Form2)
                        EndIf
                    EndIf
                Case $Button1
                    _UpdateArray($Array) ; Ici le Array doit $etre passé en paramètre car plusieurs page, 1 seul pour l'exemple
                    $Page = $Page - 1
                    _PageChange()
                    _ArrayDisplay($Array, "Array")
                Case $Button2
                    _UpdateArray($Array) ; Ici le Array doit $etre passé en paramètre car plusieurs page, 1 seul pour l'exemple
                    $Page = $Page + 1
                    _PageChange()
                    _ArrayDisplay($Array, "Array")
                Case $Button3
                    _ArrayDisplay($Array, "Array")
            EndSwitch
        Case $Form2
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $Dummy_Start To $Dummy_End
                    ; Evennements sur icon et checkbox ?
            EndSwitch
    EndSwitch
WEnd
 

GUI 2 :

► Afficher le texte

Code : Tout sélectionner

; Création des variables global inexistante en prévision

Global $Form2
Global $Dummy_Start
Global $Dummy_End

If IsDeclared("Array") And IsArray($Array) Then
    If UBound($Array) - 1 <> 0 Then
        For $i = 1 To UBound($Array) - 1
            Assign("IconPage1" & $i, "", 2)
            Assign("CheckboxPage1" & $i, "", 2)
            Assign("Checkbox_Value_Page1" & $i, "", 2)
        Next
    EndIf
EndIf

; Gestion du contenu de l'onglet (2) Regsitre
Func _Form2()
    Local $HeightScroll
    Local $Top = 38
    Global $Form2 = GUICreate("", 637, 224, 26, 215, $WS_POPUP, $WS_EX_MDICHILD, $Form)
    Select
        Case $Page = 1
            Global $Title = GUICtrlCreateLabel("Titre :", 24, 10, 590, 17)
            GUICtrlSetFont($Title, 10, 800, 2, "Verdana")
            Global $Dummy_Start = GUICtrlCreateDummy()
            $HeightScroll = _ReadArray($Array, $Top, "CheckboxPage1", "Checkbox_Value_Page1", "IconPage1")
            Global $Dummy_End = GUICtrlCreateDummy()
        Case $Page = 2
        Case $Page = 3
        Case $Page = 4
        Case $Page = 5
        Case $Page = 6
        Case Else
            Global $button = GUICtrlCreateButton("Erreur", 10, 10, 90, 20)
            $HeightScroll = 0
    EndSelect
    _GUIScrollbars_Generate($Form2, 0, $HeightScroll)
    GUICtrlSetData($Label, "Page " & $Page & "/" & $PageTotal)
    GUISetState(@SW_SHOW, $Form2)
    WinActivate($Form, "")
EndFunc   ;==>_GUIRegistry

Func _ReadArray($Array, $TopStart, $CheckBox, $CheckBoxValue, $Icon)
    Local $Top = $TopStart
    If IsArray($Array) Then
        If UBound($Array) - 1 <> 0 Then
            For $i = 1 To UBound($Array) - 1
                If IsDeclared($CheckBox & $i) And IsDeclared($CheckBoxValue & $i) And IsDeclared($Icon & $i) Then
                    If $Array[$i][0] <> "" Then
                        If $Array[$i][2] = "True" Then
                            Assign($Icon & $i, GUICtrlCreateIcon("Shell32.dll", -14, 10, $Top, 16, 16), 2)
                        EndIf
                        Assign($CheckBox & $i, GUICtrlCreateCheckbox($Array[$i][0], 32, $Top, 577, 17), 2)
                        $Top = $Top + 19
                    EndIf
                EndIf
            Next
        EndIf
    EndIf
    Return $Top
EndFunc

Func _UpdateArray($ArraySelect)
    $ArraySelect[1][0] = "tata"
    _ArrayDisplay($Array, "Array")
EndFunc

Func _PageChange() ; Gestion du changement de page dans GUI enfant
    If $Page > $PageTotal Then
        $Page = 1
    ElseIf $Page <= 0 Then
        $Page = $PageTotal
    EndIf
    GUISetState(@SW_HIDE, $Form2)
    _Form2()
EndFunc   ;==>_CheckPageChange

Et la fonction pour les scrollbar en pièce jointe.

[Julien]

Je me permet de re-poster car je viens de refaire intégralement mon exemple, le principe reste le même mais je génère les différents GUI enfant avant l'affichage du GUI principal, ce qui me permet de ne pas recréer à chaque fois l'ensemble.

Cela fonctionne mieux pour moi et je trouve cela plus propre.
Dans cet exemple je suis obligé de placer l'incude du Form2 juste avant l'affichage, ça fait vraiment moche mais dans mon application j'ai pas le même phénomène, l'include est en début de code avec les autres et cela fonctionne bien sans erreurs.

J'ai fais des test en rapport avec ma premier question de ce post et je ne reproduit pas l'erreur avec ce nouveau code.

Maintenant je m’attaque au événements sur les checkbox et icône générés à la "volé" mais je ne sais pas bien m'y prendre. Est il possible de générer le code dans le switch sachant que plusieurs GUI enfant pourront être crée en fonction de $Total_Value_Page ?

Le GUI Principal :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

#include "_GUIScrollbars_Ex.au3"

Global $Checkbox_Value_HelpView = True
Global $Current_Value_Page = 1 ; Indiquant le numéro de la page en cours
Global $Total_Value_Page = 3 ; Nombre de page total

Global $ArrayPage1[3][12] = [["Name", "Visible", "Enabled", "Check", "Hint", "Function", "Form", "Param 1", "Param 2", "Param 3", "Help", "Help Function"], _
        ["text 1", "True", "True", "False", "", "Function", "Form", "Param 1", "Param 2", "Param 3", "True", ""], _
        ["text 2", "True", "True", "False", "", "Function", "Form", "Param 1", "Param 2", "Param 3", "False", ""] _
        ]

Global $Form = GUICreate("Form", 698, 585, -1, -1)
Global $MenuFile = GUICtrlCreateMenu("&Fichier")
Global $MenuExit = GUICtrlCreateMenuItem("&Quitter", $MenuFile)
GUISetIcon("", -653)
GUISetFont(8, 400, 0, "Verdana")
Global $Tab = GUICtrlCreateTab(8, 8, 673, 481)
GUICtrlSetFont($Tab, 8, 400, 0, "Verdana")
Global $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
GUICtrlSetState($TabSheet1,$GUI_SHOW)
GUICtrlCreateTabItem("")
Global $TabSheet = GUICtrlCreateTabItem("Onglet")
Global $Button1 = GUICtrlCreateButton("<<", 36, 452, 35, 25)
GUICtrlSetFont($Button1, 8, 800, 0, "Verdana")
Global $Button2 = GUICtrlCreateButton(">>", 80, 452, 35, 25)
GUICtrlSetFont($Button2, 8, 800, 0, "Verdana")
Global $Label = GUICtrlCreateLabel($Current_Value_Page, 118, 456, 470, 17)
GUICtrlSetFont($Label, 8, 400, 0, "Verdana")
Global $CADRE = GUICtrlCreateGroup("CADRE", 24, 200, 641, 241)
GUICtrlSetFont($CADRE, 8, 400, 0, "Verdana")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateTabItem("")
Global $Button3 = GUICtrlCreateButton("Button3", 24, 504, 75, 25)

#include "Form2.au3"
_BuildingGui()

GUISetState(@SW_SHOW, $Form)

While 1
    $nMsg = GUIGetMsg(1) ; Récupération des messages GUI avancés
    Switch $nMsg[1] ; Début du sélecteur de cas sur le handle de la fenêtre de l'événement
        Case $Form
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $GUI_EVENT_CLOSE ; (-3) = La boite de dialogue a été fermée (par le menu système ou un bouton défini).
                    Exit
                Case $Tab
                    _PageChange("")
                Case $Button1
                    _PageChange("-")
                Case $Button2
                    _PageChange("+")
                Case $Button3
                    _ArrayDisplay($ArrayPage1, "Array")
            EndSwitch
        Case $GuiPage1
            Switch $nMsg[0] ; Début du sélecteur de cas sur l'EventID ou sur le ControlID
                Case $DummyPage1_Start To $DummyPage1_End
                    ; Evennements sur icon et checkbox ?
            EndSwitch
    EndSwitch
WEnd
 

Le GUI 2 :

► Afficher le texte

Code : Tout sélectionner

Func _BuildingGui()
    Local $HeightScroll
    Local $TopStart = 38
    If IsDeclared("ArrayPage1") And IsArray($ArrayPage1) Then
        If UBound($ArrayPage1) - 1 <> 0 Then
            _DeclarationVariables($ArrayPage1, "CheckboxPage1", "Checkbox_Value_Page1", "HelpPage1")
            Global $GuiPage1 = GUICreate("", 637, 224, 26, 215, $WS_POPUP, $WS_EX_MDICHILD, $Form)
            Global $TitlePage1 = GUICtrlCreateLabel("Titre :", 24, 10, 590, 17)
            GUICtrlSetFont($TitlePage1, 10, 800, 2, "Verdana")
            Global $DummyPage1_Start = GUICtrlCreateDummy()
            $HeightScroll = _ReadArray($ArrayPage1, $TopStart, "CheckboxPage1", "Checkbox_Value_Page1", "HelpPage1")
            Global $DummyPage1_End = GUICtrlCreateDummy()
            _GUIScrollbars_Generate($GuiPage1, 0, $HeightScroll)
        EndIf
    EndIf
EndFunc

Func _DeclarationVariables($Array, $CheckBox, $CheckBoxValue, $Help)
    For $i = 1 To UBound($Array) - 1
        Assign($CheckBox & $i, "", 2)
        Assign($CheckBoxValue & $i, "", 2)
        Assign($Help & $i, "", 2)
    Next
EndFunc

Func _ReadArray($Array, $TopStart, $CheckBox, $CheckBoxValue, $Help)
    Local $Top = $TopStart
    For $i = 1 To UBound($Array) - 1
        If IsDeclared($CheckBox & $i) And IsDeclared($CheckBoxValue & $i) And IsDeclared($Help & $i) Then
            If $Array[$i][1] = "True" Then
                Assign($CheckBox & $i, GUICtrlCreateCheckbox("", 32, $Top, 577, 17), 2)
                If $Array[$i][0] <> "" Then
                    GUICtrlSetData(Eval($CheckBox & $i), $Array[$i][0])
                    If $Array[$i][2] <> "True" Then
                        GUICtrlSetState(Eval($CheckBox & $i), $GUI_DISABLE)
                    EndIf
                    If $Array[$i][3] = "True" Then
                        GUICtrlSetState(Eval($CheckBox & $i), $GUI_CHECKED)
                    Else
                        GUICtrlSetState(Eval($CheckBox & $i), $GUI_UNCHECKED)
                    EndIf
                    If $Array[$i][4] <> "" Then
                        GUICtrlSetTip(Eval($CheckBox & $i), $Array[$i][5])
                    EndIf
                    If $Checkbox_Value_HelpView = True Then
                        If $Array[$i][1] = "True" And $Array[$i][2] = "True" And $Array[$i][10] = "True" Then
                            Assign($Help & $i, GUICtrlCreateIcon("Shell32.dll", -14, 10, $Top, 16, 16), 2)
                            GUICtrlSetTip(Eval($Help & $i), "Aide")
                            GUICtrlSetCursor (Eval($Help & $i), 4)
                        EndIf
                    EndIf
                    $Top = $Top + 19
                EndIf
            EndIf
        EndIf
    Next
    Return $Top
EndFunc

Func _PageChange($Operator, $Force = False) ; Gestion du changement de page dans GUI enfant
    If GUICtrlRead($Tab) = 1 And $Force = False Then
        _UpdateArray()
        If $Operator = "+" Then
            $Current_Value_Page += 1
        ElseIf $Operator = "-" Then
            $Current_Value_Page -= 1
        EndIf
        If $Current_Value_Page > $Total_Value_Page Then
            $Current_Value_Page = 1
        ElseIf $Current_Value_Page <= 0 Then
            $Current_Value_Page = $Total_Value_Page
        EndIf
        For $i = 1 To $Total_Value_Page
            If IsDeclared("GuiPage" & $i) Then
                If Eval("GuiPage" & $i) <> Eval("GuiPage" & $Current_Value_Page) Then
                    GUISetState(@SW_HIDE, Eval("GuiPage" & $i))
                Else
                    GUISetState(@SW_SHOW, Eval("GuiPage" & $i))
                EndIf
            EndIf
        Next
        GUICtrlSetData($Label, "Page " & $Current_Value_Page & "/" & $Total_Value_Page)
        WinActivate($Form, "")
    Else
        For $i = 1 To $Total_Value_Page
            If IsDeclared("GuiPage" & $i) Then
                GUISetState(@SW_HIDE, Eval("GuiPage" & $i))
            EndIf
        Next
    EndIf
EndFunc   ;==>_CheckPageChange

Func _UpdateArray()
    Switch $Current_Value_Page
        Case 1
            If IsDeclared("ArrayPage1") And IsArray($ArrayPage1) Then
                If UBound($ArrayPage1) - 1 <> 0 Then
                    For $i = 1 To UBound($ArrayPage1) - 1
                        If GUICtrlGetState(Eval("CheckboxPage1" & $i)) = 80 Then ; Si 80 = Active
                            If GUICtrlRead(Eval("CheckboxPage1" & $i)) = 1 Then ; Si 1 = cochée
                                $ArrayPage1[$i][3] = "True"
                            Else
                                $ArrayPage1[$i][3] = "False"
                            EndIf
                        Else
                            $ArrayPage1[$i][3] = "False"
                        EndIf
                    Next
                EndIf
                _ArrayDisplay($ArrayPage1, "Array")
            EndIf
        Case 2
        Case 3
        Case 4
        Case 5
        Case 6
        Case Else
            $Current_Value_Page = 1
            _PageChange("", True)
    EndSwitch
EndFunc

[mikell]

Il me semble que oui

Code : Tout sélectionner

For $i = ... to ...
    Switch $nMsg[0]
           Case Eval("CheckBox" & $i)
             ....
    EndSwitch
Next

Mais vu que je n'aurais pas du tout construit le script comme ça (question d'habitude) et que je ne sais pas à quoi il va servir, je t'avoue que je suis un peu perdu dans tes guis et tes assign

[Julien]

Merci Mikell, je vais essayé ça. Je me pose quand même la question de savoir si je devrais pas mieux m'orienter vers le mode événementiel.

Mais vu que je n'aurais pas du tout construit le script comme ça (question d'habitude)...

Par curiosité tu aurais fait comment ?

... je ne sais pas à quoi il va servir, je t'avoue que je suis un peu perdu dans tes guis et tes assign

Il sert à créer dynamiquement une liste de cases à cocher et afficher une icône pour l'aide juste avant la checkbox si défini à true dans le tableau. En fait je veux n'avoir à toucher que mon "Array" et que la construction graphique, les actions, etc... soient tirées à partir du "Array".

[mikell]

Oui non mais je voulais dire "à quoi va servir le programme"
J'imagine que sa finalité n'est pas juste d'afficher des checkboxes

Par curiosité tu aurais fait comment ?

Eh bien, ça dépend du but du soft, justement !
Afficher plusieurs "pages" n'implique pas nécessairement de faire une gui par page
Apparemment, tu utilises la même array que tu mets à jour, en adaptant les icones checkboxes etc à chaque mise à jour
Donc j'aurais fait une seule gui, et des arrays icons[] et $checkbox[] évolutives en même temps que l'array principale pour contenir les ids des controles créés
A chaque modif, les arrays sont mises à jour en même temps et la gui est actualisée

On peut aussi faire une listview avec icones et checkboxes pour chaque item
Le choix est large, mais les heures de vol m'ont appris que plus tu crées de trucs, plus les risques de cagade croissent exponentiellement

Et oui, le onevent (ou le GuiRegisterMsg) c'est mieux, ya pas photo

[Julien]

En fin de compte je vais utiliser plusieurs array. Merci Mikell pour ton aide.
J'ai transformé tout mon code pour le mode évènementiel et cela fonctionne.

[mikell]

En fait, plutôt que plusieurs arrays qui évoluent en parrallèle, rien n'empêche de garder la méthode mais de tout stocker dans la même array, ça allège bien le script
Dans ce petit script c'est pour une gestion array <=> listview mais la démarche est la même

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Global Const $WM_NOTIFY = 0x004E
Global $ini = @scriptdir & "\testini.ini"
Global $array = _ReadZeIni($ini)        ; lecture du ini => $array pour stocker les infos
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $array[3][3]      ; array par défaut
   $array[0][0] = "chemin1"
   $array[0][1] = @Autoitexe
   $array[1][0] = "chemin2"
   $array[1][1] = @SystemDir & "\cmd.exe"      
   $array[2][0] = "chemin3"
   $array[2][1] = @SystemDir & "\notepad.exe"   
EndIf
; _ArrayDisplay($array, "debug") 

$gui = GUICreate("listview programmes", 420, 180, 500, 20, -1)
$listview = GUICtrlCreateListView("|" &"soft", 10, 10, 400, 130, $LVS_NOCOLUMNHEADER, $LVS_EX_FULLROWSELECT + $LVS_EX_CHECKBOXES)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 90)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 320)
; remplissage de la listview, stockage des ids des items dans $array[$i][2]
For $i = 0 To UBound($array)-1
   $array[$i][2] = GUICtrlCreateListViewItem($array[$i][0] &"|" & $array[$i][1], $listview)
   GUICtrlSetImage(-1, $array[$i][1], -1)  
Next
$ajoute = GuiCtrlCreateButton("ajoute", 50, 145, 80, 25)
$degage = GuiCtrlCreateButton("supprime", 150, 145, 80, 25)
$label = GuiCtrlCreateLabel("double clic sur une ligne", 250, 150, 180, 20)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
    _WriteInZeIni($ini)
       Exit
    Case $degage
    If $array <>"" Then 
        $count = ControlListView($gui, "", $listview, "GetItemCount")
        For $index0 = $count-1 To 0 step -1
        If BitAnd(GuiCtrlRead($array[$index0][2], 1), $GUI_CHECKED) = $GUI_CHECKED Then
             GUICtrlDelete($array[$index0][2])
                _ArrayDelete($array, $index0)
        EndIf
        Next
      _WriteInZeIni($ini)
    EndIf
    Case $ajoute
    If $array = "" Then 
        Dim $array[1][3] 
        $prevnb = 0
    Else
        $prevnb = UBound($array)
        ReDim $array[$prevnb+1][3]
    EndIf
    $var = FileOpenDialog("choisir...", @DesktopDir & "\", "softs (*.exe)")
    If not @error Then
        $array[$prevnb][0] = "chemin" & $prevnb+1
        $array[$prevnb][1] = $var
        $array[$prevnb][2] = GUICtrlCreateListViewItem($array[$prevnb][0] &"|" & $array[$prevnb][1], $listview)
        GUICtrlSetImage(-1, $array[$prevnb][1], -1)
        _WriteInZeIni($ini)
 ;_ArrayDisplay($array, "debug") 
    EndIf   
EndSwitch
Wend

;===========================================
Func _WriteInZeIni($file)  
  FileDelete($file)    ; on peut faire un backup avant
   For $i = 0 To UBound($array)-1
    IniWrite($file, $i, $array[$i][0], $array[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
   $var = IniReadSectionNames($file)
   If @error Then Return SetError(1)
   Dim $array[$var[0]][3]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1][0] = $readsection[1][0]  
    $array[$i-1][1] = $readsection[1][1]  
   Next
Return $array
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
   $tagNMHDR = "hwnd hWndFrom;uint_ptr IDFrom;INT Code"
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = $listview
       If Not IsHWnd($listview) Then $hWndListView = GUICtrlGetHandle($listview)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
            Case -3  ; $NM_DBLCLK
            $indexLV = ControlListView($gui, "", $hWndListView, "GetSelected")
            $itemtxt = ControlListView($gui, "", $hWndListView, "GetText", $indexLV, 1)
            Run($itemtxt)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 

[Julien]

Bonjour,

Désolé mikell de ne pas avoir répondu avant, cela fait deux fois que je ne répond pas à vos derniers messages. Je ne reçois pas les mails de notifications et n'ai pas trop le reflexe de passer par le panneu utilisateur.

Pour ce qui est du script j'ai fais plusieurs test et refait plusieurs fois le tout. Votre exemple est vraiment interessant.

Merci.