[R] Propriétés étendues personnalisées d'un script compilé

[ZDS]

Bonjour à tous,

J'aimerai savoir si quelqu'un sait comment lire les propriétés customisables du résumé sur un exécutable. Le genre de propriétés qui sont ajoutées lors de la compilation avec "#AutoIt3Wrapper_Res_Field=Propriété à moi|Ma valeur à lire".

► Afficher le texteEntête de compilation

Code : Tout sélectionner

#AutoIt3Wrapper_Res_Field=Nom (short)|ConnexionWU
#AutoIt3Wrapper_Res_Field=Nom (long)|Connexion With Uplauncher
#AutoIt3Wrapper_Res_Field=Version (short)|1.2c
#AutoIt3Wrapper_Res_Field=Version (long)|1.2.1.0
#AutoIt3Wrapper_Res_Field=Description|Module de connexion
#AutoIt3Wrapper_Res_Field=Type|Connexion
#AutoIt3Wrapper_Res_Field=Compilation|AutoIt v%AutoItVer%
#AutoIt3Wrapper_Res_Field=Auteur|ZDS [Equipe nAiO]
#AutoIt3Wrapper_Res_Field=Site|http://www.naio.fr

Je cherche à faire une fonction FileGetProperty($fichier, $property), avec un appel du style :
FileGetProperty("C:\Script.exe", "Nom (long)") => "Connexion With Uplauncher".

Merci d'avance pour votre aide, à bientôt !

PS: J'ai déjà trouvé comment écrire et lire les propriétés classiques, comme la version (quand on utilise #AutoIt3Wrapper_Res_Fileversion) ou l'auteur (cf topic http://autoitscript.fr/forum/viewtopic.php?f=20&t=5388, ou http://autoitscript.fr/forum/viewtopic.php?f=3&t=13, ou encore http://www.autoitscript.fr/forum/viewto ... =21&t=2295). Ce n'est pas ce que je demande cette fois, c'est bien les propriétés induites par #AutoIt3Wrapper_Res_Field.

----------------------------------------------------------------

Réponse : Utilisez FileGetVersion("C:\Script.exe", "Nom (long)"), le second paramètre est disponible depuis AutoIt 3.2.?.

[TT22]

FileGetVersion() ?

Edit : J'avais fais ce script il y a quelques temps :

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>;Inclu le fichier servant à gérer les constantes GUI.

$File = "";Déclaration de la variable $File (vide).

If UBound($CmdLine) > 1 Then;Si le script a été lancé avec des paramètres alors...
    $File = $CmdLine[1];...ils sont récupérés dans la variable $File.
EndIf

If Not $File Then;Sinon...
    $File = FileOpenDialog("Choisissez un fichier :",@UserProfileDir,"Tous les fichiers (*.*)");...L'utilisateur les choisis.
    If @error Then Exit;Quitte le script si l'utilisateur appuie sur "Annuler" ou sur fermer.
EndIf

If Not FileExists($File) Then;Si le fichier n'existe pas alors...
    MsgBox(16,"Erreur","Le fichier demandé n'existe pas !");...on affiche un message d'erreur...
    Exit;...et on quitte le script.
EndIf

$FileName = StringSplit($File,"\");Récupère le nom du fichier
$FileName = $FileName[UBound($FileName)-1];                     sans son chemin d'accès.

GUICreate('Informations sur le fichier "'&$FileName&'"',500,500);Crée la GUI.
GUISetBkColor(0xF0F0F0);On choisis la couleur de fond de la GUI.
$Edit = GUICtrlCreateEdit("",10,10,480,480,3);On crée un Edit...
GUICtrlSetBkColor($Edit,0xF0F0F0);...et on choisis sa couleur.
GUISetState(@SW_SHOW); TRES IMPORTANT : On affiche la GUI.

Dim $Info[12] = ["Comments", "LegalCopyright", "CompanyName", "FileDescription", "FileVersion", "ProductVersion", "InternalName", "BuildID", "CompiledScript"];Déclaration de la variable contenant les informations à récuperer.
Dim $Name[12] = ["Commentaires", "Copyright", "Compagnie", "Description", "Version du fichier", "Version du produit", "Nom interne", "BuildID   ", "Script Compilé"];Déclaration le la variable contenant le nom des informations.

For $i = 0 To 11 Step 1;On lance une boucle...
    $FileInfo = FileGetVersion($File,$Info[$i]);...dans laquelle on recherche des information...
    If $FileInfo Then;...et si elles sont trouvées alors...
        GUICtrlSetData($Edit,GUICtrlRead($Edit)&$Name[$i]&" :       "&$FileInfo&@CRLF);...on les affiches.
    EndIf
Next

Dim $TimeName[3] = ["Modifié", "Créé", "Accédé"];Déclaration le la variable contenant le nom des informations.

For $i = 0 To 2 Step 1;On lance une boucle...
    $FileTime = FileGetTime($File,$i);...dans laquelle on recherche des information...
    If UBound($FileTime) Then;...et si elles sont trouvées alors...
        GUICtrlSetData($Edit,GUICtrlRead($Edit)&$TimeName[$i]&" le "&$FileTime[2]&"/"&$FileTime[1]&"/"&$FileTime[0]&" à "&$FileTime[3]&" heures, "&$FileTime[4]&" minutes et "&$FileTime[5]&" secondes."&@CRLF);...on les affiches.
    EndIf
Next

Dim $Attrib[9] = ["R", "A", "S", "H", "N", "D", "O", "C", "T"];Déclaration de la variable contenant les informations à récuperer.
Dim $AttribName[9] = [" peut seulement être lu", ", est une archive", ", est un fichier système", ", est caché", ", est normal", ", est un répertoire", ", est hors-ligne", ", est compressé ( en NTFS, pas en zip)", ", est temporaire"];Déclaration le la variable contenant le nom des informations.

$FileAttrib = FileGetAttrib($File);On récupère ces informations...
If $FileAttrib Then;...et si il y en alors...
    For $i = 0 To 8 Step 1;...on crée une boucle...
        $FileAttrib = StringReplace($FileAttrib,$Attrib[$i],$AttribName[$i],0,1);...dans laquelle on remplace les informations par leur nom.
    Next
    GUICtrlSetData($Edit,GUICtrlRead($Edit)&"Ce fichier"&$FileAttrib&"."&@CRLF);Puis on les affiches.
EndIf

$FileSize = FileGetSize($File);On récupère ces informations...
If $FileSize Then;...et si il y en alors...
    GUICtrlSetData($Edit,GUICtrlRead($Edit)&"Ce fichier fait "&Floor($FileSize/1000)&" Ko."&@CRLF);...on les affiches.
EndIf

If GUICtrlRead($Edit) = "" Then;Si aucune information n'a été trouvés alors...
    GUICtrlSetData($Edit,"Désolé, aucune information n'est disponible pour ce fichier !");...on écrit un message.
EndIf

$Data = GUICtrlRead($Edit);On sauvegarde le contenu de la GUI.

While 1;On démarre une boucle.
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then;Si l'utilisateur ferme la GUI alors...
        Exit;On quitte le script.
    EndIf
    If GUICtrlRead($Edit) <> $Data Then;Si l'utilisateur modifie le contenu de l'Edit alors...
        GUICtrlSetData($Edit,$Data);...on réécris l'original en fonction de la variable $Data.
    EndIf
WEnd

[ZDS]

Bonjour,

Tu n'as pas compris ma demande :

PS: J'ai déjà trouvé comment écrire et lire les propriétés classiques, comme la version [...] Ce n'est pas ce que je demande cette fois, c'est bien les propriétés induites par #AutoIt3Wrapper_Res_Field.

FileGetVersion ne récupère que la donnée induite par "#AutoIt3Wrapper_Res_Fileversion=Ma_Donnée", mais pas celle que je pourrais chercher dans "#AutoIt3Wrapper_Res_Field=Version|Ma_Donnée".

Exemple, compile le script suivant, et depuis un autre script, essaye de trouver la valeur "Bazinga" (que l'on peut voir en faisant un clic droit sur le script compilé > menu "Propriétés" > Onglet "Version" > SubPanel "Autres informations de version" > élément "TBBT") :

► Afficher le texteElément de test

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Res_Fileversion=1.2.3.4
#AutoIt3Wrapper_Res_Field=TBBT|Bazinga
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
MsgBox(0,"foo","bar")

Un simple FileGetVersion permet de récupérer "1.2.3.4", mais comment récupérer "Bazinga" ?

[mikell]

Code : Tout sélectionner

#Include <WinAPIEx.au3>
$Data = _WinAPI_VerQueryValue(@desktopdir & "\test.exe", "TBBT")
Msgbox(0,"", $Data[1][1])

[Iste]

FileGetVersion() ?
Ha ben, ca à déja été dit... En lisant la doc alors peut etre ?
(j'ai été tester avant pour etre sur)

[mikell]

En lisant la doc alors peut etre ?

Et m3rde ... évidemment
C'est vrai Iste on devrait jamais tenir pour acquis que la doc a bien été lue correctement avant la question, ça éviterait des prises de tête

Code : Tout sélectionner

Msgbox(0,"", FileGetVersion (@desktopdir & "\test.exe", "TBBT") )

[ZDS]

Bonjour à tous,

Nouille comme je suis, et vacances obligent, je n'avais pas testé ailleurs que sur l'ordinateur familial dont l'AutoIt date de Mathusalem Ier... Je trouvais aussi que l'aide était pas des masses explicites. Donc juste au cas où, pour ceux qui fonctionnent encore avec AutoIt 3.1.X, la fonction de Mikell par l'UDF WinApiEx pourrait bien marcher nickel. Pour les autres (99% des gens, quoi), oubliez mes conneries, FileGetVersion suffit amplement ^^ (pourtant je suis le premier à pester quand on me demande de l'aide sur un truc qui est pas à jour...)

A bientôt, et merci de ne pas m'avoir enfoncé trop la tête dans mon c**a !

PS: Encore désolé d'avoir dénigrer tes affirmations TT22, en fait tu avais raison depuis le début.