[R] Supprimer UN élément d'une "List"

[Fish]

Bonjour tout le monde!

En réalité j'ai deux problèmes. Avant de vous les exposer, je vous explique la situation :
Je fais pour ma prof' de travaux pratiques un petit programme qui lui permettrait d'imprimer ses TP en une seule fois, un par un, une bouton qui lui permettrait d'éditer un TP, de le supprimer.

Mes problèmes :
1) Quand je veux supprimer UN SEUL élément de la List dans la GUI, je n'y arrive pas... J'ai testé plusieurs trucs mais au bout d'un moment une erreur apparait. Cela provient du fait que je gère ma liste de TP via un fichier Ini pour ne pas avoir à refaire à chaque fois une liste. Le problème étant que je n'arrive pas à supprimer "proprement" un tp dans l'Ini, il reste une trace quelque part ou alors, vu que les tp sont répertoriés par numéros, la liste prends "1, 2, 4, 5" une fois le TP supprimé et cela fait bugger le programme...

2) Quand je veux imprimer toute la liste, une erreur apparait...


Voici mon code :

► Afficher le texte

Code : Tout sélectionner

; Includes
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

$numberoftp = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0) ; Nombre de TP dans la liste contenue dans l'Ini

$cleactuelle = $numberoftp ; Variable servant a récupérer dans la List le bon nombre de Tps.


; Gui Koda
#Region ### START Koda GUI section ### Form=l:\documents gaspard\programmation\autoit\projets\printer lycée\printer final édition\printer gui.kxf
Global $Form1 = GUICreate("Impression dynamique des TP", 306, 407, 305, 130)
Global $List1 = GUICtrlCreateList("", 8, 8, 289, 253)
Global $Button1 = GUICtrlCreateButton("Editer le TP", 8, 272, 139, 25, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("Imprimer le TP", 152, 272, 147, 25, $WS_GROUP)
Global $Button3 = GUICtrlCreateButton("Ajouter un TP à la liste", 152, 304, 147, 25, $WS_GROUP)
Global $Button4 = GUICtrlCreateButton("Supprimer le TP de la liste", 8, 304, 139, 25, $WS_GROUP)
Global $Button5 = GUICtrlCreateButton("Imprimer toute la liste", 8, 336, 291, 33, $WS_GROUP)
Global $Button6 = GUICtrlCreateButton("Informations", 8, 376, 139, 25, $WS_GROUP)
Global $Button7 = GUICtrlCreateButton("Quitter", 160, 376, 139, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
;Fin de la partie Gui

;Boucle de récupération des tp dans l'ini et insertion dans la List
While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
    GUICtrlSetData ($List1, IniRead (@ScriptDir&"\test.ini", "numeros", $cleactuelle, "Error in Ini file")) ;On ajoute une ligne à la liste
    $cleactuelle = $cleactuelle -1; Et on incrémente
WEnd

;Boucle de la Gui
While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $Button1
      ;On veut ouvrir le tp dans world ou autre le TP pour l'éditer
      $itemoflist = GUICtrlRead ($List1) ;On récupère le TP séléctionné
      If Not $itemoflist = 0 Then ;Si un tp est séléctioné
          $CheminTPchoisis = IniRead (@ScriptDir&"\test.ini", "Relations", $itemoflist, "Error") ;On lit à quel chemin il retourne dans l'Ini
          ShellExecute ($CheminTPchoisis) ;Et on le lance!
      EndIf


  Case $Button2
      ;On veut imprimer le tp
      $itemoflist = GUICtrlRead ($List1) ;On récupère la ligne du tp séléctioné dans la Gui
      If Not $itemoflist = 0 Then ;Si un nom de tp est séléctioné
          $CheminTPchoisis = IniRead (@ScriptDir&"\test.ini", "Relations", $itemoflist, "Error") ;On récupère son chemin dans l'Ini
          ShellExecute ($CheminTPchoisis, "", "", "print") ;Et on l'imprime
      EndIf

  Case $Button3 ;Si on veut àjouter un tp à la liste
      $CheminTP = FileOpenDialog ("Choisissez le TP à ajouter à la liste", "", "Documents Word (*.doc)|Documents word (*.xdoc)") ;On demande son chemin
      $nomdutpencours = InputBox ("Nom du TP à ajouter", "Veuillez choisir un nom pour le TP à afficher dans la liste.") ;Et le nom dui lui correspond dans la liste
      If not $CheminTP = "" Then ;Si il a été entré un chemin correct
          If Not $nomdutpencours = "" Then ; Et un nom à afficher correct
            $numberoftp = $numberoftp + 1 ;On ajoute un tp au nombre de tp

            ;On écrit dans l'ini les valeurs nécessaires
            IniWrite (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur",$numberoftp)
            IniWrite (@ScriptDir&"\test.ini","Relations",$nomdutpencours, $CheminTP)
            IniWrite (@ScriptDir&"\test.ini","numeros",$numberoftp, $nomdutpencours)
            ;On édite la Gui
            GUICtrlSetData($List1,$nomdutpencours)
            GUICtrlSetData($List1,$nomdutpencours,"Test")
          Else
            ;Sinon il y a eu une couille dans le paté
            MsgBox (0, "Erreur", "Le nom du tp n'a pas été entré.")
          EndIf
      Else
          ;Idem pour ici
          MsgBox (0, "Erreur", "Le chemin du tp n'a pas été entré.")
      EndIf
  Case $Button4
      ;Je ne sais pas comment faire...

  Case $Button5
      ;On veut imprimer tous les tp
      $cleactuelle = $numberoftp ;On remet à jour le nombre des tp dans l'Ini dans une variable modifiable
      While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés imprimés :
        $nomdutpencours = IniRead (@ScriptDir&"\test.ini", "numeros", $cleactuelle, "Error in Ini File") ;On récupère le nom du tp
        $CheminTP = IniRead (@ScriptDir&"\test.ini", "Relations", $nomdutpencours, "Error in Ini File") ;On en déduit son chemin
        If Not $nomdutpencours = "Error in Ini File" Then  ;Si il n'y a pas d'erreurs
            If Not $CheminTP = "Error in Ini File" Then ;//
                $Error = ShellExecuteWait ($CheminTP, "", "", "print") ;On imprime en attendant que ce soit terminé
                If $Error = 1 then $cleactuelle = $cleactuelle -1; Et on incrémente si tout s'est bien passé
            Else
                MsgBox (0, "Erreur", "Erreur dans le fichier Ini!")
                $cleactuelle = 0
            EndIf
        Else
            MsgBox (0, "Erreur", "Erreur dans le fichier Ini!")
            $cleactuelle = 0
        EndIf
      WEnd

  Case $Button6
      MsgBox (0, "Informations", "Ce logiciel d'impréssion de TPs à été codé par FishPanai en AutoIT pour la classe de 2PSEN du lycée Vaucanson.") ;About
  Case $Button7
      Exit ;On sort (moi aussi d'aileurs, a+!)
EndSwitch
WEnd
 

Et en pièce jointe le dossier complet.

[mikell]

A priori je dirais que ton ini n'est pas pratique
Je le verrais plutôt comme ça :

Code : Tout sélectionner

[0]
Tp multimédia=C:\Users\FishPanai\Documents\TP1.doc
[1]
Tp caméscope=C:\Users\FishPanai\Documents\TP2.doc

Beaucoup plus facile à gérer dans une array, le nombre de TP correspond au nombre de sections, l'index de l'array correspond au n° de section (index des items pour affichage dans une listview par exemple)

[Fish]

Oulah, je ne m'en sort pas bien du tout avec les Arrays...
Et puis ça ne résous pas mon problème, si on supprime le TP 2, on supprime la section 2, il va donc y avoir la section 1 et 3 alors que l'on à 2 tps. Il va aussi y avoir des erreurs.

[mikell]

Et puis ça ne résous pas mon problème

Ben si...
Tu gères ta liste, l'array et le ini en même temps
Mais un exemple vaut mieux que de longs discours
Essaye ce script et regarde la façon dont le ini évolue

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Global $ini = @scriptdir & "\testini.ini"
Global $array = _ReadZeIni($ini)        ; lecture du ini => 1ère array ($array) pour stocker les infos
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $array[3][2]      ; array par défaut
   $array[0][0] = "chemin1"
   $array[0][1] = @Autoitexe
   $array[1][0] = "chemin2"
   $array[1][1] = @SystemDir & "\cmd.exe"      
   $array[2][0] = "chemin3"
   $array[2][1] = @SystemDir & "\notepad.exe"   
EndIf
; _ArrayDisplay($array)

$gui = GUICreate("listview programmes", 420, 180, 500, 20, -1)
$listview = GUICtrlCreateListView("|" &"soft", 10, 10, 400, 130, $LVS_NOCOLUMNHEADER)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 70)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 320)

; remplissage de la listview
Dim $ligne[UBound($array)]            ; 2ème array ($ligne) pour stocker les handles des items
For $i = 0 To UBound($array)-1
   $ligne[$i] = GUICtrlCreateListViewItem($array[$i][0] &"|" & $array[$i][1], $listview)
   GUICtrlSetImage(-1, $array[$i][1], -1)  
Next

$ajoute = GuiCtrlCreateButton("ajoute", 50, 145, 80, 25)
$degage = GuiCtrlCreateButton("supprime", 150, 145, 80, 25)
GUISetState()


While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
    _WriteInZeIni($ini)
       Exit
    Case $degage
        $index = ControlListView($gui, "", $listview, "GetSelected")
        GUICtrlDelete($ligne[$index])
        _ArrayDelete($ligne, $index)
        _ArrayDelete($array, $index)
    _WriteInZeIni($ini)
    Case $ajoute
    $var = FileOpenDialog("choisir...", @DesktopDir & "\", "softs (*.exe)")
    If not @error Then
        $prevnb = UBound($array)
        ReDim $array[$prevnb+1][2]
        $array[$prevnb][0] = "chemin" & $prevnb+1
        $array[$prevnb][1] = $var
        ReDim $ligne[$prevnb+1]
        $ligne[$prevnb] = GUICtrlCreateListViewItem($array[$prevnb][0] &"|" & $array[$prevnb][1], $listview)
        GUICtrlSetImage(-1, $array[$prevnb][1], -1)
    EndIf   
EndSwitch
Wend

Func _WriteInZeIni($file)   ; 
 ; en lisant l'array $array
  FileDelete($file)    ; on peut faire un backup avant
   For $i = 0 To UBound($array)-1
    IniWrite($file, $i, $array[$i][0], $array[$i][1])
   Next
; on peut aussi écrire le ini en lisant la listview :
; $count = ControlListView($gui, "", $listview, "GetItemCount")
; For $i = 0 To $count-1
;   IniWrite($file, $i, ControlListView($gui, "", $listview, "GetText", $i, 0), _ 
;           ControlListView($gui, "", $listview, "GetText", $i, 1) )
; Next
EndFunc

Func _ReadZeIni($file)
   $var = IniReadSectionNames($file)
   If @error Then 
    SetError(1)
    Return
   EndIf
   Dim $array[$var[0]][2]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1][0] = $readsection[1][0]  
    $array[$i-1][1] = $readsection[1][1]  
   Next
Return $array
EndFunc
 

[Fish]

Merci pour ton script, je commence à comprendre le principe. Mais c'est pas encore gagné!
Toutes les fonctions marchent à part ce fichu "supprimer un tp".

Voila le nouveau code :

► Afficher le texte

Code : Tout sélectionner

; Includes
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
Global $ini = @scriptdir & "\test.ini"
$numberoftp = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0) ; Nombre de TP dans la liste contenue dans l'Ini
If @error = 0 Then
    FileDelete($ini)
    $numberoftp = 0
Else
    Dim $TableauTP[$numberoftp][2]
EndIf
$cleactuelle = $numberoftp ; Variable servant a récupérer dans la List le bon nombre de Tps.
; Gui Koda
#Region ### START Koda GUI section ### Form=l:\documents gaspard\programmation\autoit\projets\printer lycée\printer final édition\printer gui.kxf
Global $Form1 = GUICreate("Impression dynamique des TP", 306, 407, 305, 130)
Global $List1 = GUICtrlCreateList("", 8, 8, 289, 253)
Global $Button1 = GUICtrlCreateButton("Editer le TP", 8, 272, 139, 25, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("Imprimer le TP", 152, 272, 147, 25, $WS_GROUP)
Global $Button3 = GUICtrlCreateButton("Ajouter un TP à la liste", 152, 304, 147, 25, $WS_GROUP)
Global $Button4 = GUICtrlCreateButton("Supprimer le TP de la liste", 8, 304, 139, 25, $WS_GROUP)
Global $Button5 = GUICtrlCreateButton("Imprimer toute la liste", 8, 336, 291, 33, $WS_GROUP)
Global $Button6 = GUICtrlCreateButton("Informations", 8, 376, 139, 25, $WS_GROUP)
Global $Button7 = GUICtrlCreateButton("Quitter", 160, 376, 139, 25, $WS_GROUP)
GUISetState(@SW_HIDE)
#EndRegion ### END Koda GUI section ###
;Fin de la partie Gui

;Boucle de récupération des tp dans l'ini et insertion dans la List
While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
    $var = IniReadSection (@ScriptDir&"\test.ini", $cleactuelle)
    If @error Then
        $cleactuelle = $cleactuelle - 1
    Else
        For $i = 1 To $var[0][0]
            GUICtrlSetData ($List1,$var[$i][0])
            MsgBox (0, "Waw", $var[$i][0])
            $cleactuelle = $cleactuelle -1
        Next
    EndIf
WEnd
GUISetState (@SW_SHOW)

;Boucle de la Gui
While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg


  Case $GUI_EVENT_CLOSE
   Exit


  Case $Button1
      ;On veut ouvrir le tp dans world ou autre le TP pour l'éditer
      $itemoflist = GUICtrlRead ($List1) ;On récupère le TP séléctionné
      If Not $itemoflist = 0 Then ;Si un tp est séléctioné
          $cleactuelle = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0)
          While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
            $var = IniReadSection (@ScriptDir&"\test.ini", $cleactuelle)
            If @error Then
                $cleactuelle = 0
            Else
                For $i = 1 To $var[0][0]
                    If $var[$i][0] = $itemoflist Then
                        ShellExecute ($var[$i][1])
                        $cleactuelle = 0
                        ExitLoop
                    Else
                        $cleactuelle = $cleactuelle -1
                    EndIf
                Next
            EndIf
        WEnd
      Else
        MsgBox (0, "Erreur", "Aucun TP n'a été séléctioné!")
      EndIf


  Case $Button2


      ;On veut imprimer le tp
      $itemoflist = GUICtrlRead ($List1) ;On récupère le TP séléctionné
      If Not $itemoflist = 0 Then ;Si un tp est séléctioné
          $cleactuelle = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0)
          While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
            $var = IniReadSection (@ScriptDir&"\test.ini", $cleactuelle)
            If @error Then
                $cleactuelle = 0
            Else
                For $i = 1 To $var[0][0]
                    If $var[$i][0] = $itemoflist Then
                        ShellExecute ($var[$i][1], "", "", "print")
                        $cleactuelle = 0
                        ExitLoop
                    Else
                        $cleactuelle = $cleactuelle -1
                    EndIf
                Next
            EndIf
        WEnd
      Else
        MsgBox (0, "Erreur", "Aucun TP n'a été séléctioné!")
      EndIf

  Case $Button3 ;Si on veut àjouter un tp à la liste
      $CheminTP = FileOpenDialog ("Choisissez le TP à ajouter à la liste", "", "Documents Word (*.doc)|Documents word (*.xdoc)") ;On demande son chemin
      $nomdutpencours = InputBox ("Nom du TP à ajouter", "Veuillez choisir un nom pour le TP à afficher dans la liste.") ;Et le nom dui lui correspond dans la liste
      If not $CheminTP = "" Then ;Si il a été entré un chemin correct
          If Not $nomdutpencours = "" Then ; Et un nom à afficher correct
            $numberoftp = $numberoftp + 1 ;On ajoute un tp au nombre de tp

            ;On écrit dans l'ini les valeurs nécessaires
            IniWrite (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur",$numberoftp)
            IniWrite (@ScriptDir&"\test.ini",$numberoftp,$nomdutpencours, $CheminTP)
            ;On édite la Gui
            GUICtrlSetData($List1,$nomdutpencours)
          Else
            ;Sinon il y a eu une couille dans le paté
            MsgBox (0, "Erreur", "Le nom du tp n'a pas été entré.")
          EndIf
      Else
          ;Idem pour ici
          MsgBox (0, "Erreur", "Le chemin du tp n'a pas été entré.")
      EndIf
  Case $Button4
    $itemoflist = GUICtrlRead ($List1) ;On récupère le TP séléctionné
      If Not $itemoflist = 0 Then ;Si un tp est séléctioné
          $cleactuelle = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0)
          $var = IniReadSection (@ScriptDir&"\test.ini", $cleactuelle)
          $numberoftp = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0)
          FileDelete ($ini)
          GUICtrlSetData ($List1, "")
          While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
                  For $i = 1 To $var[0][0]
                      MsgBox (0, "Test", "Valeur de $cleactuelle : "&$cleactuelle &@CRLF &"Valeur de $i : "&$i &@CRLF&"Valeur de $var[$i][0] : "&$var[$i][0]&@CRLF&"Valeur de $var[$i][1] : "&$var[$i][1])
                      IniWrite (@ScriptDir&"\test.ini", $cleactuelle , $var[$i][0],$var[$i][1])
                      GUICtrlSetData ($List1,$var[$i][0])
                      $cleactuelle = $cleactuelle -1
                  Next
          WEnd
      Else
        MsgBox (0, "Erreur", "Aucun TP n'a été séléctioné!")
      EndIf
  IniWrite (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur",$numberoftp)
  Case $Button5
      ;On veut imprimer tous les tp
    $cleactuelle = IniRead (@ScriptDir&"\test.ini", "Nombre_de_TP", "valeur", 0)
    While ($cleactuelle <> 0) ;Tant que tous les TP (suivant leurs nombre) n'ont pas étés importés :
    $var = IniReadSection (@ScriptDir&"\test.ini", $cleactuelle)
    If @error Then
        $cleactuelle = $cleactuelle -1
    Else
        For $i = 1 To $var[0][0]
                ShellExecute ($var[$i][1], "", "", "print")
        Next
        $cleactuelle = $cleactuelle -1
    EndIf
    WEnd
  Case $Button6
      MsgBox (0, "Informations", "Ce logiciel d'impréssion de TPs à été codé par FishPanai en AutoIT pour la classe de 2PSEN du lycée Vaucanson.") ;About
  Case $Button7
      Exit ;On sort (moi aussi d'aileurs, a+!)
EndSwitch
WEnd
 

[mikell]

Hmmm ce n'est pas la première fois que je dis ça et certainement pas la dernière, mais une Listview est *beaucoup* plus facile à gérer qu'une List
Par exemple dans ton cas il serait très utile de pouvoir récupérer l'index dans la liste de l'item sélectionné ... avec une listview c'est facile, avec une liste faut utiliser des fonctions compliquées comme _GUICtrlListBox_GetCurSel () qui demandent de gros includes

[Fish]

Qu'entends-tu par "l'index"?
Qu'entends-tu par "handle" (dans ton script)?
Que contient $array?
Tout est embrouillé dans ma tête.

[mikell]

Cool
ça a l'air compliqué mais ça ne l'est pas (enfin pas trop)

- le handle c'est le numéro d'identité que Windows attribue à chaque controle quand il est créé
- $array dans mon script contient ce qui a été lu dans le ini, et qui va être écrit dans la liste
- l'index c'est simplement le rang de l'item dans la liste, son numéro de ligne si tu préfères
c'est pratique si on veut faire le parallèle avec le contenu d'une array, les index (les rangs) sont les mêmes
Pour une List on peut récupérer l'index comme ça (attention le n° 1 a un index 0)

Code : Tout sélectionner

Case $msg = $read
    MsgBox(0, "", GuiCtrlRead($mylist) & @crlf & "index :  " & GUICtrlSendMsg($mylist, 0x0188, 0, 0))

[Fish]

Pour que ce soit plus logique et clair, on peux incrémenter l'index de 1 à chaque fois?

[mikell]

Prenons un exemple simple

Dans ton ini tu as 10 valeurs
Tu vas lire ça dans une array à 10 éléments, les index de ces éléments dans l'array iront de 0 à 9
Tu utilises cette array pour écrire une liste de 10 lignes
Les index (numéros de ligne) des éléments dans la liste iront de 0 à 9

Si tu supprimes un item de la liste, il suffit de supprimer l'item d'index identique dans l'array (avec _ArrayDelete($array, $index), puis de réécrire le ini à partir de l'array rectifiée

Et oui, le gros intérêt des index est qu'ils peuvent être utilisés avec incrémentation dans des boucles For

[Fish]

Ca y est j'ai compris!

J'ai repris votre code pour l'adapter à mon programme :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
Global $ini = @scriptdir & "\List.ini"
Global $contenuini = _ReadZeIni($ini)
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $contenuini[3][2]      ; array par défaut
   $contenuini[0][0] = "chemin1"
   $contenuini[0][1] = ""
   $contenuini[1][0] = "chemin2"
   $contenuini[1][1] = ""
   $contenuini[2][0] = "chemin3"
   $contenuini[2][1] = ""
EndIf
#Region ### START Koda GUI section ### Form=l:\documents gaspard\programmation\autoit\projets\printer lycée\printer final édition\printer gui.kxf
Global $gui = GUICreate("Impression dynamique des TP", 306, 402, 297, 130)
Global $editer = GUICtrlCreateButton("Editer le TP", 8, 272, 139, 25, $BS_NOTIFY)
Global $imprimer1 = GUICtrlCreateButton("Imprimer le TP", 152, 272, 147, 25, $BS_NOTIFY)
Global $ajouter = GUICtrlCreateButton("Ajouter un TP à la liste", 152, 304, 147, 25, $BS_NOTIFY)
Global $supprimer1 = GUICtrlCreateButton("Supprimer le TP de la liste", 8, 304, 139, 25, $BS_NOTIFY)
Global $imprimertout = GUICtrlCreateButton("Imprimer toute la liste", 8, 336, 139, 25, $BS_NOTIFY)
Global $supprimertout = GUICtrlCreateButton("Supprimer toute la liste", 152, 336, 147, 25)
Global $about = GUICtrlCreateButton("Informations", 8, 368, 139, 25)
Global $quitter = GUICtrlCreateButton("Quitter", 152, 368, 147, 25)
Global $ListView1 = GUICtrlCreateListView("|" &"soft", 8, 8, 290, 254,$LVS_NOCOLUMNHEADER)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 0, 70)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 1, 320)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Dim $ligne[UBound($contenuini)]            ; 2ème array ($ligne) pour stocker les handles des items
For $i = 0 To UBound($contenuini)-1
   $ligne[$i] = GUICtrlCreateListViewItem($contenuini[$i][0] &"|" & $contenuini[$i][1], $ListView1)
   GUICtrlSetImage(-1, $contenuini[$i][1], -1)
Next


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
   Case $GUI_EVENT_CLOSE
   _WriteInZeIni($ini)
   Exit
   Case $supprimer1
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
            GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
            _ArrayDelete($contenuini, $index)
            _WriteInZeIni($ini)
        EndIf
    Case $ajouter
    $cheminTP = FileOpenDialog("choisir...", @DesktopDir & "\", "Documents word (*.doc)|Documents word (*.xdoc)")
    $nomdutp = InputBox ("Nom du TP", "Choisissez un nom du tp pour l'affichage dans la liste : ")
    If not $cheminTP = 0 Then
        If Not $nomdutp = 0 Then
            $prevnb = UBound($contenuini)
            ReDim $contenuini[$prevnb+1][2]
            $contenuini[$prevnb][0] = $nomdutp
            $contenuini[$prevnb][1] = $cheminTP
            ReDim $ligne[$prevnb+1]
            $ligne[$prevnb] = GUICtrlCreateListViewItem($contenuini[$prevnb][0] &"|" & $contenuini[$prevnb][1], $ListView1)
            GUICtrlSetImage(-1, $contenuini[$prevnb][1], -1)
            _WriteInZeIni($ini)
        EndIf
    EndIf
 EndSwitch
WEnd


Func _WriteInZeIni($file)   ;
  FileDelete($file)
   For $i = 0 To UBound($contenuini)-1
    IniWrite($file, $i, $contenuini[$i][0], $contenuini[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
   $variable = IniReadSectionNames($file)
   If @error Then
    SetError(1)
    Return
   EndIf
   Dim $contenuini[$variable[0]][2]
   For $i = 1 To $variable[0]
    $readsection = IniReadSection($ini, $variable[$i])
    $contenuini[$i-1][0] = $readsection[1][0]
    $contenuini[$i-1][1] = $readsection[1][1]
   Next
Return $contenuini
EndFunc
 

Le problème c'est que quand la liste est vide, on ne peux ni supprimer ni ajouter, le programme se ferme et donne une erreur...
Edit : plus que l'erreur pour l'ajout de TP dans la liste... Je regarde... => Je sais d'où vient le problème mais pas comment le régler... En gros quand je fais un ReDim sur $contenuini et que $prevnb = 0 il m'affiche une erreur, et ne veut pas faire $contenuini[1][2].... Pourquoi? (Je précise au cas ou que le problème est aussi dans votre script. )

[mikell]

Hé oui, il manquait une gestion d'erreur dans mon script, voilà le bon

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Global $ini = @scriptdir & "\testini.ini"
Global $array = _ReadZeIni($ini)        ; lecture du ini => 1ère array ($array) pour stocker les infos
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $array[3][2]      ; array par défaut
   $array[0][0] = "chemin1"
   $array[0][1] = @Autoitexe
   $array[1][0] = "chemin2"
   $array[1][1] = @SystemDir & "\cmd.exe"      
   $array[2][0] = "chemin3"
   $array[2][1] = @SystemDir & "\notepad.exe"   
EndIf
; _ArrayDisplay($array)

$gui = GUICreate("listview programmes", 420, 180, 500, 20, -1)
$listview = GUICtrlCreateListView("|" &"soft", 10, 10, 400, 130, $LVS_NOCOLUMNHEADER)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 70)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 320)

; remplissage de la listview
Dim $ligne[UBound($array)]            ; 2ème array ($ligne) pour stocker les handles des items
For $i = 0 To UBound($array)-1
   $ligne[$i] = GUICtrlCreateListViewItem($array[$i][0] &"|" & $array[$i][1], $listview)
   GUICtrlSetImage(-1, $array[$i][1], -1)  
Next

$ajoute = GuiCtrlCreateButton("ajoute", 50, 145, 80, 25)
$degage = GuiCtrlCreateButton("supprime", 150, 145, 80, 25)
GUISetState()


While 1
$msg = GUIGetMsg()
Switch $msg

    Case  -3
    _WriteInZeIni($ini)
       Exit

    Case $degage
    If $ligne <>"" Then    ; si l'array $ligne n'est pas vide
            $index = ControlListView($gui, "", $listview, "GetSelected")
            GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
            _ArrayDelete($array, $index)
        _WriteInZeIni($ini)
    EndIf

    Case $ajoute
    If $ligne = "" Then  ; si l'array $ligne est vide
        Dim $ligne[1]
        Dim $array[1][2] 
        $prevnb = 0
    Else
        $prevnb = UBound($array)
        ReDim $array[$prevnb+1][2]
        ReDim $ligne[$prevnb+1]
    EndIf
    $var = FileOpenDialog("choisir...", @DesktopDir & "\", "softs (*.exe)")
    If not @error Then
        $array[$prevnb][0] = "chemin" & $prevnb+1
        $array[$prevnb][1] = $var
        $ligne[$prevnb] = GUICtrlCreateListViewItem($array[$prevnb][0] &"|" & $array[$prevnb][1], $listview)
        GUICtrlSetImage(-1, $array[$prevnb][1], -1)
        _WriteInZeIni($ini)
 ;_ArrayDisplay($array, "debug") 
    EndIf   

EndSwitch
Wend

Func _WriteInZeIni($file)  
  FileDelete($file)    ; on peut faire un backup avant
   For $i = 0 To UBound($array)-1
    IniWrite($file, $i, $array[$i][0], $array[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
   $var = IniReadSectionNames($file)
   If @error Then 
    SetError(1)
    Return
   EndIf
   Dim $array[$var[0]][2]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1][0] = $readsection[1][0]  
    $array[$i-1][1] = $readsection[1][1]  
   Next
Return $array
EndFunc
 

Et pour le fun, le même pour listbox (après tout, c'était le titre du sujet...)

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <Array.au3>

Global $ini = @scriptdir & "\testini.ini"
Global $array = _ReadZeIni($ini)        ; lecture du ini => 1ère array ($array) pour stocker les infos
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $array[3][2]      ; array par défaut
   $array[0][0] = "chemin1"
   $array[0][1] = @Autoitexe
   $array[1][0] = "chemin2"
   $array[1][1] = @SystemDir & "\cmd.exe"      
   $array[2][0] = "chemin3"
   $array[2][1] = @SystemDir & "\notepad.exe"   
EndIf
; _ArrayDisplay($array)

$gui = GUICreate("listbox programmes", 420, 180, 500, 20, -1)
$list = GUICtrlCreateList("", 10, 10, 400, 130)

; remplissage de la list
For $i = 0 To UBound($array)-1
   GUICtrlSetData($list, $array[$i][0] &"=" & $array[$i][1]&"|")
Next

$ajoute = GuiCtrlCreateButton("ajoute", 50, 145, 80, 25)
$degage = GuiCtrlCreateButton("supprime", 150, 145, 80, 25)
GUISetState()


While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
    _WriteInZeIni($ini)
       Exit
    Case $degage
       If $array <>"" Then 
        $index = GUICtrlSendMsg($list, 0x0188, 0, 0)  ; $LB_GETCURSEL
         GUICtrlSendMsg($list, 0x0182, $index, 0)  ; $LB_DELETESTRING
         _ArrayDelete($array, $index)
        _WriteInZeIni($ini)
      EndIf
    Case $ajoute
    If $array = "" Then 
        Dim $array[1][2] 
        $prevnb = 0
    Else
        $prevnb = UBound($array)
        ReDim $array[$prevnb+1][2]
    EndIf
    $var = FileOpenDialog("choisir...", @DesktopDir & "\", "softs (*.exe)")
    If not @error Then
        $array[$prevnb][0] = "chemin" & $prevnb+1
        $array[$prevnb][1] = $var
        GUICtrlSetData($list, $array[$prevnb][0] &"=" & $array[$prevnb][1]&"|")
    EndIf   
EndSwitch
Wend

Func _WriteInZeIni($file)   ; en lisant l'array $array
  FileDelete($file)    ; on peut faire un backup avant
   For $i = 0 To UBound($array)-1
    IniWrite($file, $i, "chemin" & $i+1, $array[$i][1])
    ;IniWrite($file, $i, $array[$i][0], $array[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
   $var = IniReadSectionNames($file)
   If @error Then 
    SetError(1)
    Return
   EndIf
   Dim $array[$var[0]][2]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1][0] = $readsection[1][0]  
    $array[$i-1][1] = $readsection[1][1]  
   Next
Return $array
EndFunc
 

[Fish]

Je patauge toujours... Des erreurs de partout... Jugez par vous même :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
Global $ini = @scriptdir & "\List.ini"
Global $contenuini = _ReadZeIni($ini)
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde si corrompu
   FileDelete($ini)        ; recréation nouveau ini
   Dim $contenuini[1][2]      ; array par défaut
   $contenuini[0][0] = "Fichier de la liste"
   $contenuini[0][1] = $ini
   _WriteInZeIni ($ini)
EndIf
#Region ### START Koda GUI section ### Form=l:\documents gaspard\programmation\autoit\projets\printer lycée\printer final édition\printer gui.kxf
Global $gui = GUICreate("Impression dynamique des TP", 306, 402, 297, 130)
Global $editer = GUICtrlCreateButton("Editer le TP", 8, 272, 139, 25, $BS_NOTIFY)
Global $imprimer1 = GUICtrlCreateButton("Imprimer le TP", 152, 272, 147, 25, $BS_NOTIFY)
Global $ajouter = GUICtrlCreateButton("Ajouter un TP à la liste", 152, 304, 147, 25, $BS_NOTIFY)
Global $supprimer1 = GUICtrlCreateButton("Supprimer le TP de la liste", 8, 304, 139, 25, $BS_NOTIFY)
Global $imprimertout = GUICtrlCreateButton("Imprimer toute la liste", 8, 336, 139, 25, $BS_NOTIFY)
Global $supprimertout = GUICtrlCreateButton("Supprimer toute la liste", 152, 336, 147, 25)
Global $about = GUICtrlCreateButton("Informations", 8, 368, 139, 25)
Global $quitter = GUICtrlCreateButton("Quitter", 152, 368, 147, 25)
Global $ListView1 = GUICtrlCreateListView("Nom du TP|" &"Chemin", 8, 8, 290, 254)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 0, 70)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 1, 320)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Dim $ligne[UBound($contenuini)]            ; 2ème array ($ligne) pour stocker les handles des items
For $i = 0 To UBound($contenuini)-1
   $ligne[$i] = GUICtrlCreateListViewItem($contenuini[$i][0]&"|"& $contenuini[$i][1], $ListView1)
   GUICtrlSetImage(-1, $contenuini[$i][1], -1)
Next


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
   Case $GUI_EVENT_CLOSE
   _WriteInZeIni($ini)
   Exit
   Case $supprimer1
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
            GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
            _ArrayDelete($contenuini, $index)
            _WriteInZeIni($ini)
        EndIf
    Case $ajouter
        $cheminTP = FileOpenDialog("choisir...", @DesktopDir & "\", "Documents word (*.doc)|Documents word (*.xdoc)")
        If Not @error Then
            $nomdutp = InputBox ("Nom du TP", "Choisissez un nom du tp pour l'affichage dans la liste : ")
            If not $cheminTP = "" Then
                If Not $nomdutp = "" Then
                    If $ligne = "" Then
                        Dim $ligne[1]
                        Dim $contenuini[1][2]
                        $prevnb = 0
                    Else
                        $prevnb = UBound($contenuini)
                        ReDim $contenuini[$prevnb+1][2]
                        ReDim $ligne[$prevnb+1]
                    EndIf
                    If not @error Then
                        $contenuini[$prevnb][0] = $nomdutp
                        $contenuini[$prevnb][1] = $cheminTP
                        $ligne[$prevnb] = GUICtrlCreateListViewItem($contenuini[$prevnb][0] &"|" & $contenuini[$prevnb][1], $ListView1)
                        GUICtrlSetImage(-1, $contenuini[$prevnb][1], -1)
                    EndIf
                Else
                    MsgBox (0, "Erreur", "Vous devez choisir un nom pour le ficher!")
                EndIf
            Else
                MsgBox (0, "Erreur", "Vous devez choisir un fichier!")
            EndIf
        Else
            MsgBox (0, "Erreur", "Vous devez choisir un fichier!")
        EndIf
    _WriteInZeIni($ini)
    Case $editer
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
            $contenuini = _ReadZeIni($ini)
            ShellExecute ($contenuini[$index][1])
        EndIf
    Case $imprimer1
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
            $contenuini = _ReadZeIni($ini)
            ShellExecute ($contenuini[$index][1], "", "", "print")
        EndIf
    Case $imprimertout
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        $variable = ControlListView ($gui, "", $ListView1, "GetItemCount")
        $contenuini = _ReadZeIni($ini)
        For $i = 0 To $variable
            ShellExecuteWait ($contenuini[$i][1], "", "", "print")
        Next
 EndSwitch
WEnd


Func _WriteInZeIni($file)   ;
  FileDelete($file)
   For $i = 1 To UBound($contenuini)-1
    IniWrite($file, $i, $contenuini[$i][0], $contenuini[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
        $variable = IniReadSectionNames($file)
        If @error Then
            SetError(1)
            Return
        EndIf
        Dim $contenuini[$variable[0]][2]
        For $i = 1 To $variable[0]
            $readsection = IniReadSection($ini, $variable[$i])
            $contenuini[$i-1][0] = $readsection[1][0]
            $contenuini[$i-1][1] = $readsection[1][1]
        Next
        Return $contenuini
EndFunc

Si vous pouviez m'aider à le corriger s'il vous plais... Moi je n'y arrive pas, ça fait 2 heures que je me casse la tête dessus...

[mikell]

Voilà ça devrait le faire maintenant
ça y était presque (comparer avec l'ancien script)
Note : pour éditer et imprimer pas besoin de relire le ini, le chemin est déjà dans l'array... on peut aussi récupérer ce chemin par lecture directe dans la listview de l'item sélectionné (exemple inside)

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $wordpath = StringTrimRight(RegRead("HKEY_CLASSES_ROOT\Word.Document.8\DefaultIcon", ""), 2)
Global $ini = @scriptdir & "\List.ini"
Global $ligne = ""
Global $contenuini = _ReadZeIni($ini)
If @error Then MsgBox (64, "Info", "La liste de TP est vide ou absente ")   ; si ini pas trouvé ou corrompu

#Region ### START Koda GUI section ### Form=l:\documents gaspard\programmation\autoit\projets\printer lycée\printer final édition\printer gui.kxf
Global $gui = GUICreate("Impression dynamique des TP", 346, 402, 297, 130)
Global $editer = GUICtrlCreateButton("Editer le TP", 8, 272, 159, 25, $BS_NOTIFY)
Global $imprimer1 = GUICtrlCreateButton("Imprimer le TP", 172, 272, 167, 25, $BS_NOTIFY)
Global $ajouter = GUICtrlCreateButton("Ajouter un TP à la liste", 172, 304, 167, 25, $BS_NOTIFY)
Global $supprimer1 = GUICtrlCreateButton("Supprimer le TP de la liste", 8, 304, 159, 25, $BS_NOTIFY)
Global $imprimertout = GUICtrlCreateButton("Imprimer toute la liste", 8, 336, 159, 25, $BS_NOTIFY)
Global $supprimertout = GUICtrlCreateButton("Supprimer toute la liste", 172, 336, 167, 25)
Global $about = GUICtrlCreateButton("Informations", 8, 368, 159, 25)
Global $quitter = GUICtrlCreateButton("Quitter", 172, 368, 167, 25)
Global $ListView1 = GUICtrlCreateListView("Nom du TP|" &"Chemin", 8, 8, 330, 254)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 0, 95)
GUICtrlSendMsg($ListView1, $LVM_SETCOLUMNWIDTH, 1, 230)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

If $contenuini<> "" Then
    Dim $ligne[UBound($contenuini)]            ; 2ème array ($ligne) pour stocker les handles des items
    For $i = 0 To UBound($contenuini)-1
       $ligne[$i] = GUICtrlCreateListViewItem($contenuini[$i][0]&"|"& $contenuini[$i][1], $ListView1)
       GUICtrlSetImage(-1, $wordpath, -1)
    Next
EndIf


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
   Case $GUI_EVENT_CLOSE, $quitter
         _WriteInZeIni($ini)
          Exit

   Case $supprimer1
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
            GUICtrlDelete($ligne[$index])
            _ArrayDelete($ligne, $index)
            _ArrayDelete($contenuini, $index)
            _WriteInZeIni($ini)
        EndIf

   Case $supprimertout
       $variable = ControlListView ($gui, "", $ListView1, "GetItemCount")
        For $i = 0 To $variable-1
            GUICtrlDelete($ligne[$i])
        Next
        $ligne = ""
        $contenuini = ""
        FileDelete($ini)

    Case $ajouter
        $cheminTP = FileOpenDialog("choisir...", @DesktopDir & "\", "Documents word (*.doc)|Documents word (*.xdoc)")
        If Not @error Then
        $nomdutp = InputBox ("Nom du TP", "Choisissez un nom du tp pour l'affichage dans la liste : ")
              If $nomdutp <> "" Then
                    If $ligne = "" Then
                        Dim $ligne[1]
                        Dim $contenuini[1][2]
                        $prevnb = 0
                    Else
                        $prevnb = UBound($contenuini)
                        ReDim $contenuini[$prevnb+1][2]
                        ReDim $ligne[$prevnb+1]
                    EndIf
                    $contenuini[$prevnb][0] = $nomdutp
                    $contenuini[$prevnb][1] = $cheminTP
                    $ligne[$prevnb] = GUICtrlCreateListViewItem($contenuini[$prevnb][0] &"|" & $contenuini[$prevnb][1], $ListView1)
                    GUICtrlSetImage(-1, $wordpath, -1)
                    _WriteInZeIni($ini)
              Else
                    MsgBox (0, "Erreur", "Vous devez choisir un nom pour le ficher!")
              EndIf
        Else
            MsgBox (0, "Erreur", "Vous devez choisir un fichier!")
        EndIf

    Case $editer
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else
          ;  $contenuini = _ReadZeIni($ini)
            ShellExecute ($contenuini[$index][1])
        EndIf

    Case $imprimer1
        $index = ControlListView($gui, "", $ListView1, "GetSelected")
        If $index = "" Then
            MsgBox (0, "Erreur", "Aucun TP séléctioné!")
        Else

; récupération du chemin par lecture de la listview
          ;  $path_tp = ControlListView($gui, "", $ListView1, "GetText", $index, 1)
         ;   MsgBox (0, "debug", $path_tp)   
 ; récupération du chemin par lecture de l'array
            MsgBox (0, "debug", $contenuini[$index][1])    
                     ; $contenuini = _ReadZeIni($ini)     ; <<<< pas nécessaire !
          ;  ShellExecute ($contenuini[$index][1], "", "", "print")
        EndIf

    Case $imprimertout
        $variable = ControlListView ($gui, "", $ListView1, "GetItemCount")
        For $i = 0 To $variable-1
            ;  MsgBox (0, "debug", $contenuini[$i][1])
            ShellExecuteWait ($contenuini[$i][1], "", "", "print")
        Next
 EndSwitch
WEnd


Func _WriteInZeIni($file)   ;
  FileDelete($file)
   For $i = 0 To UBound($contenuini)-1
    IniWrite($file, $i, $contenuini[$i][0], $contenuini[$i][1])
   Next
EndFunc

Func _ReadZeIni($file)
        $variable = IniReadSectionNames($file)
        If @error Then
            SetError(1)
            Return
        EndIf
        Dim $contenuini[$variable[0]][2]
        For $i = 1 To $variable[0]
            $readsection = IniReadSection($ini, $variable[$i])
            $contenuini[$i-1][0] = $readsection[1][0]
            $contenuini[$i-1][1] = $readsection[1][1]
        Next
        Return $contenuini
EndFunc

[Fish]

Je comprends mieux!
En tout cas merci beaucoup, c'est résolu!