[R] Problème avec _IEQuit

[yohan8]

Bonjour,

Mes scripts se confrontent parfois à des problèmes que j'aimerais régler :
Lorsqu'il passe au code '_IEQuit' , ma page internet 'bug' (elle passe d'actif à inactif, en gros elle clignote) et mon script n'arrive pas à le fermer. Lorsqu'on ferme manuellement on obtient les messages 'ne répond plus' & 'fermer le programme immédiatement'.

Donc non seulement mon script se bloque vu qu'il n'arrive pas a fermer ma page internet, aucun message d'erreur s'affiche donc impossible de détecter le bug avec autoit et en plus je ne peux pas fermer les processus d'internet car j'ai une autre page internet que je ne doit pas fermer.

Je pensais faire la liste des fenêtres ouverte (winlist), chercher celle qui m'intéresse (??), puis fermer son processus (processusclose).

Yohan

[mikell]

Pas facile de répondre sans voir le script ^^
Peut-être une confusion entre $oIE=0 qui ferme l'objet et _IEQuit qui ferme l'objet et le navigateur

[yohan8]

Il me semblais qu'il n'y avait pas besoin de script car c'est tout simple

Code : Tout sélectionner

$oIE = _IEcreat('www.google.fr')
;action
_IEQuit($oIE)
;suite

Le script ne veut pas passer à la suite car il bloque au code '_IEQuit' car la page internet a subi un 'bug'. Lorsqu'on la ferme manuellement un message de windows nous informe que internet ne répond pas et qu'il à planté. Windows cherche par la suite à résoudre le problème [...]
Ne me dite pas qu'il y a que moi qui subit des plantages d'internet ?

Donc ma question est : comment fermer une page internet autrement qu'en passant par _IEQuit($oIE) ?
La réponse je la suppose : par les processus

Mon autre question est : comment fermer le processus d'une fenêtre ?
Et la réponse je la connais pas

[mikell]

Si ce script

Code : Tout sélectionner

#include <IE.au3>
$oIE = _IEcreate('www.google.fr')
msgbox(0,"", "ouvert")
_IEQuit($oIE)
msgbox(0,"", "fermé")

ne fonctionne pas chez toi, il faut désinstaller/réinstaller IE, ou alors formater
Mais il reste fort probable que le bug soit dans le script et pas dans IE ^^

[yohan8]

Flûte ma question n'a pas été claire.

Alors j'ai deux page internet différentes. J'aimerais fermer l'une d'elle. Lorsque j'applique le code '_IEQuit($oIE2)' sur ma fenêtre que je veux fermer (qui s'appelle $oIE2), celle-ci 'bug'.

'bug' = succession d'ordre donné à une fenêtre. Ces trop nombreux ordre bloque la fenêtre et celle-ci ne répond plus. Par exemple quand ma page internet charge une adresse web et que je l'a ferme alors qu'elle à pas finit, elle ce met à 'bugger ' et ne répond plus.


Si vous n'avez toujours pas comprit mon histoire je peux vous poser un autre problème dont la réponse répond à ma première question :
J'aimerais fermer le processus d'une fenêtre par le titre de la fenêtre et non par le titre de l'application. Est-ce possible ?
Je pensais faire une liste des fenêtres active puis choisir la fenêtre qui m'intéresse puis fermer son processus.

[TopXm]

Hello
Hum, vu que tu parles un coup de page après de processus, je ne sais pas trop où tu veux en venir.
J'ai fait ça [doit y avoir plus simple ] ça te retourne le PID et le titre de la fenêtre/onglet avec en entrée le nom du processus

► Afficher le texte_GetAllWindowsTitle

Code : Tout sélectionner

#include <array.au3>

Global $MyArray = _GetAllWindowsTitle("iexplore.exe")
_ArrayDisplay($MyArray )

; Récupére les titre des fenêtres/onglet d'un processus
Func _GetAllWindowsTitle($ExeName)
    Local $nPid
    Local $aPid = ProcessList($ExeName)
    Local $aProc = WinList()
    Local $aRet[1][2]
    $aRet[0][0] = 0
    For $A = 1 To $aProc[0][0]
        If $aProc[$A][0] <> "" Then
            $nPid = WinGetProcess($aProc[$A][0])
            If _ArraySearch($aPid, $nPid) > 0 _
            And _ArraySearch($aRet, $aProc[$A][0]) < 1 Then     ;évite les doublons???
                $aRet[0][0] += 1
                ReDim $aRet[$aRet[0][0]+1][2]
                $aRet[$aRet[0][0]][0] = $nPid
                $aRet[$aRet[0][0]][1] = $aProc[$A][0]
            EndIf
        EndIf
    Next
    Return $aRet
EndFunc

Ou encore via EnumWindows (Voir aide F1 sur DllCallbackRegister)

► Afficher le texteEnumWindows

Code : Tout sélectionner

#include <array.au3>
Global $aRet[1][2]
Global $aPid = ProcessList('iexplore.exe')
If $aPid[0][0] = 0 Then Exit                    ;pas de process actif

$aRet[0][0] = 0

; Create callback function
Local $handle = DllCallbackRegister("_EnumWindowsProc", "int", "hwnd;lparam")

; Call EnumWindows
DllCall("user32.dll", "int", "EnumWindows", "ptr", DllCallbackGetPtr($handle), "lparam", 10)

; Delete callback function
DllCallbackFree($handle)

_ArrayDisplay($aRet)
Exit

; Callback Procedure
Func _EnumWindowsProc($hWnd, $lParam)
    If WinGetTitle($hWnd) <> "" _
    And _ArraySearch($aPid, WinGetProcess($hWnd)) > 0 _
    And _ArraySearch($aRet, WinGetTitle($hWnd)) < 1 Then
        ConsoleWrite('---------------------------------------------------------------------------------' & @CRLF & _
                     'Title  => ' & WinGetTitle($hWnd) & @CRLF & _
                     'Process=> ' & WinGetProcess($hWnd) & @CRLF & _
                     "$hWnd  => " & $hWnd & @CRLF & _
                     "lParam => "  & $lParam & @CRLF &  _
                     "hWndTyp=> " & VarGetType($hWnd) & @CRLF)

        $aRet[0][0] += 1
        ReDim $aRet[$aRet[0][0]+1][2]
        $aRet[$aRet[0][0]][0] = WinGetProcess($hWnd)
        $aRet[$aRet[0][0]][1] = WinGetTitle($hWnd)
    EndIf
    Return 1 ; Return 1 to continue enumeration
EndFunc   ;==>_EnumWindowsProc
 

Testé sur quelques onglets d'IE ouverts ça donne ceci :

► Afficher le texteCapture _ArrayDisplay

[mikell]

quand ma page internet charge une adresse web et que je l'a ferme alors qu'elle à pas finit, elle ce met à 'bugger ' et ne répond plus.

Code : Tout sélectionner

_IEAction ($oIE, "stop")

" Cancels any pending navigation or download operation and stops any dynamic page elements, such as background sounds and animations. "