[R] Traffic/Utilisation réseaux pour un seul processus.

[benjahinfo]

Bonjour,

J'ai trouvé des fonctions permettant de voir l'utilisation du réseau en générale à partir de la carte réseau.
1) Seulement voila, je ne veux pas voir toute l'utilisation du réseau, je ne veux que l'utilisation du réseau par rapport à un processus, un seul !
2) Est-il possible de connaître les connections TCP/UDP sur un seul processus ? Si oui, comment ?

Merci de vos réponses.

[Baku]

Yop, il me semble qu'un port ne peut être occupé que par une liaison, donc par un seul processus ? Il faudrait à mon avis sélectionner le port concerné, par contre sans chercher là comme ca, j'peux pas te dire comment t'y prendre, j'regarde un peu voir si j'trouve quelque chose d'intéressant.

EDIT : J'vois pas, dans le sens où pour écouter un port faut l'occuper bloquant l'accès au programme en question :/ Ou bien je m'y prends mal, je sais pas

[ZDS]

Bonjour,

Les fonctions fournies de bases pour AutoIt ne permettent pas de faire ce genre de manipulation. Par contre, en utilisant conjointement le driver WinPCap, et l'UDF "WinPcap Autoit3 UDF", tu auras moyen de créer un sniffeur de réseau, à la manière de WireShark. Par contre, à toi de jouer pour savoir sur quel port le logiciel discute.

A bientôt !

PS: J'ai volontairement omis de mettre les liens, étant donné que les sources que j'ai trouvé (très facilement) sont sur des sites externes et personnels. Je ne prendrai pas le risque de poster un lien de ce genre. Par contre, voici un topic sur le forum anglophone qui parle de ton souci : http://www.autoitscript.com/forum/topic ... t-sniffer/

EDIT: J'ai testé la manip, et l'exemple fourni avec l'UDF permet de scanner une interface réseau à la manière de WireShark. Fonctionnel sur AutoIt 3.3.8.1 (même si il a été codé pour 3.3.0.0), il suffit juste d'installer WinPCap.

[Baku]

Ah ben oui, j'ai pas pensé à aller voir si WinPCap était utilisable avec autoit, mais c'est vrai que tous les sniffeurs que je connais l'utilisent ^^
Plus qu'à stocker les paquets recus et envoyés pour connaitre le débit total utilisé !

[ZDS]

Re,

Tant que j'y pense, il existe une autre méthode qui permet de jeter un coup d'oeil à l'utilisation de la bande passante pour une interface choisie.

► Afficher le texteBandwidth monitor

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$aLabel = _GetNames(_GetObj())
Dim $aCheckBox[$aLabel[0] + 1][2]
Dim $aAdapter[2]

$hSelection = GUICreate("Selection", 300, $aLabel[0] * 30 + 30, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_WINDOWEDGE))
If $aLabel[0] = 0 Then
    MsgBox(0, "Error", "No Adapters Found", 0, $hSelection)
    Exit
EndIf

For $i = 1 To $aLabel[0]
    $aCheckBox[$i][0] = GUICtrlCreateCheckbox($aLabel[$i], 8, $i * 20, 290)
    $aCheckBox[$i][1] = $aLabel[$i]
Next
$aCheckBox[0][0] = $aLabel[0]

$Button1 = GUICtrlCreateButton("okay", 100, $aLabel[0] * 30, 75)
GUISetState(@SW_SHOW)

While 1
    Sleep(50)
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $i1 = 1
            $bExit = 0
            For $i = 1 To $aCheckBox[0][0]
                If GUICtrlRead($aCheckBox[$i][0]) = 1 Then
                    $aAdapter[0] = $i1
                    ReDim $aAdapter[$i1 + 1]
                    $aAdapter[$i1] = $aCheckBox[$i][1]
                    $i1 += 1
                    $bExit = 1
                EndIf
            Next
            If $bExit = 1 Then
                GUIDelete($hSelection)
                ExitLoop
            Else
                MsgBox(0, "Error", "No Adapter Selected", 0, $hSelection)
            EndIf
    EndSwitch
WEnd

Opt("GUIOnEventMode", 1)
$hMonitor = GUICreate("Monitor", 150, 100, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_WINDOWEDGE))
GUISetFont(12)
$Label1 = GUICtrlCreateLabel("", 8, 8, 100, 24)
$Label2 = GUICtrlCreateLabel("", 8, 23, 100, 24)
$Label3 = GUICtrlCreateLabel("", 8, 38, 100, 24)
$Label4 = GUICtrlCreateLabel("", 8, 53, 100, 24)
$label5 = GUICtrlCreateLabel("", 8, 68, 100, 24)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW)
$Data_now = _GetData(_GetObj(), $aAdapter)
GUICtrlSetData($Label5, Round($Data_now[0] / 073741824, 2) & "Total GB")
While 1
    $btmp= _GetData(_GetObj(), $aAdapter)
    Sleep(1000)

    $aData = _GetData(_GetObj(), $aAdapter)

    $bData = $aData[0] - $Data_now[0]
   
    $difftmp= ($aData[0]-$btmp[0])
   
    GUICtrlSetData($Label1, Round($difftmp, 2) & " Diff")
   
    GUICtrlSetData($Label2, Round($bData / 1024, 2) & " KB")

    GUICtrlSetData($Label3, Round($bData / 1048576, 2) & " MB")

    GUICtrlSetData($Label4, Round($bData / 073741824, 2) & " GB")
WEnd

Func _GetNames($colItems)
    Local $aName[2], $i = 1
    If IsObj($colItems) Then
        For $objItem In $colItems
            $aName[0] = $i
            ReDim $aName[$i + 1]
            $aName[$i] = $objItem.Name
            $i += 1
        Next
    EndIf
    Return $aName
EndFunc   ;==>_GetNames

Func _GetData($colItems, $aAdapter)
    Local $aData[2]
    If IsObj($colItems) Then
        For $objItem In $colItems
            For $i = 1 To $aAdapter[0]
                If $objItem.Name = $aAdapter[$i] Then
                    $aData[0] += $objItem.BytesReceivedPersec
                    $aData[1] += $objItem.BytesSentPersec
                EndIf
            Next
        Next
    EndIf
    Return $aData
EndFunc   ;==>_GetData

Func _GetObj()
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20, $colItems = "", $strComputer = "localhost"
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")

    $colItems = $objWMIService.ExecQuery("SELECT BytesReceivedPersec,BytesSentPersec,Name FROM Win32_PerfRawData_Tcpip_NetworkInterface", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    Return $colItems
EndFunc   ;==>_GetObj

Func _Exit()
    Exit
EndFunc

► Afficher le texteBandwidth monitor alternative

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$aLabel = _GetNames(_GetObj())
Dim $aCheckBox[$aLabel[0] + 1][2]
Dim $aAdapter[2]

$hSelection = GUICreate("Selection", 300, $aLabel[0] * 45, -1, -1, -1, BitOR($WS_EX_TOOLWINDOW,$WS_EX_WINDOWEDGE))
If $aLabel[0] = 0 Then
    MsgBox(0, "Error", "No Adapters Found", 0)
    Exit
EndIf

For $i = 1 to $aLabel[0]
    $aCheckBox[$i][0] = GUICtrlCreateCheckbox($aLabel[$i], 8, $i * 20, 290)
;~     GUICtrlSetState(-1, $GUI_CHECKED)
    $aCheckBox[$i][1] = $aLabel[$i]
Next
$aCheckBox[0][0] = $aLabel[0]

$Button1 = GUICtrlCreateButton("Okay", 100, $aLabel[0] * 30, 75)
GUISetState(@SW_SHOW)

While 1
    Sleep(50)
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $i1 = 1
            $bExit = 0
            For $i = 1 to $aCheckBox[0][0]
                If GUICtrlRead($aCheckBox[$i][0]) = 1 Then
                    $aAdapter[0] = $i1
                    ReDim $aAdapter[$i1 + 1]
                    $aAdapter[$i1] = $aCheckBox[$i][1]
                    $i1 += 1
                    $bExit = 1
                EndIf
            Next
            If $bExit = 1 Then
                GUIDelete($hSelection)
                ExitLoop
            Else
                MsgBox(0, "Error", "No Adapter Selected", 0)
            EndIf
    EndSwitch
WEnd

$Tenth = 20

$hMonitor   = GUICreate("Monitor", 212, 100, -1, -1)
              GUISetFont(9)
$Menu       = GUICtrlCreateMenu("&Options")
$bytesize   = GUICtrlCreateMenu("Byte Size", $Menu)
$kbyte      = GUICtrlCreateMenuItem("KB", $bytesize)
$mbyte      = GUICtrlCreateMenuItem("MB", $bytesize)
              GUICtrlSetState(-1, $GUI_CHECKED)
$gbyte      = GUICtrlCreateMenuItem("GB", $bytesize)

$Label1     = GUICtrlCreateLabel("Bandwidth: Megabytes", 8, 8, 145, 24)
$Label3     = GUICtrlCreateLabel("", 8, 32, 210, 24)
$Label5     = GUICtrlCreateLabel("", 100, 32, 110, 20, $SS_RIGHT)
$progress   = GUICtrlCreateProgress(8, 56, 160, 15)
$Label7     = GUICtrlCreateLabel("4 GB", 180, 55, 100, 24)

GUISetState(@SW_SHOW)

While 1
    $Msg = GUIGetMsg()
    If $Msg = $GUI_EVENT_CLOSE Then Exit

    If $Msg = $kbyte Then
        GUICtrlSetState($kbyte, $GUI_CHECKED)
        GUICtrlSetState($mbyte, $GUI_UNCHECKED)
        GUICtrlSetState($gbyte, $GUI_UNCHECKED)

        $Tenth = 10

        GUICtrlSetData($Label1, "Bandwidth: Kilobytes")
    ElseIf $Msg = $mbyte Then
        GUICtrlSetState($kbyte, $GUI_UNCHECKED)
        GUICtrlSetState($mbyte, $GUI_CHECKED)
        GUICtrlSetState($gbyte, $GUI_UNCHECKED)

        $Tenth = 20

        GUICtrlSetData($Label1, "Bandwidth: Megabytes")
    ElseIf $Msg = $gbyte Then
        GUICtrlSetState($kbyte, $GUI_UNCHECKED)
        GUICtrlSetState($mbyte, $GUI_UNCHECKED)
        GUICtrlSetState($gbyte, $GUI_CHECKED)

        $Tenth = 30

        GUICtrlSetData($Label1, "Bandwidth: Gigabytes")
    EndIf
    $aData = _GetData(_GetObj(), $aAdapter)

    $BYTE = Round( ($aData[0]) / (2 ^ $Tenth),4)

    GUICtrlSetData($Label3, $BYTE)
    GUICtrlSetData($progress, ($aData[0] / (4 * (2^30))) * 100)
    GUICtrlSetData($Label5, Round($aData[0] / (4 * (2^30)) * 100, 2) & "%")


WEnd

Func _GetNames($colItems)
    Local $aName[2], $i = 1
    If IsObj($colItems) then
        For $objItem In $colItems
            $aName[0] = $i
            ReDim $aName[$i + 1]
            $aName[$i] = $objItem.Name
            $i += 1

        Next
    EndIf
    Return $aName
EndFunc

Func _GetData($colItems, $aAdapter)
    Local $aData[2]
    If IsObj($colItems) then
        For $objItem In $colItems
            For $i = 1 to $aAdapter[0]
                If $objItem.Name = $aAdapter[$i] Then
                    $aData[0] += $objItem.BytesReceivedPersec
                    $aData[1] += $objItem.BytesSentPersec
                EndIf
            Next
        Next
    EndIf
    Return $aData
EndFunc

Func _GetObj()
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20, $colItems = "", $strComputer = "localhost"
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
    $colItems = $objWMIService.ExecQuery("SELECT BytesReceivedPersec,BytesSentPersec,Name FROM Win32_PerfRawData_Tcpip_NetworkInterface", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    Return $colItems
EndFunc

Ceci sans utiliser WinPCap (script issu de http://www.autoitscript.com/forum/topic ... h-monitor/).

A bientôt.

PS: Je sais que tu as déjà trouvé ce genre d'utilisation, mais si d'autres personnes tombent sur ce topic, ça pourra les aider.

[benjahinfo]

Merci pour tes scripts.
Donc, et bien je ferais sa avec WinPcap alors ^^, merci de votre temps et de vos réponse.