[R] Afficher les espaces et les sauts de ligne.

[eric]

Bonjour,

Je voudrais afficher dans une Edit, les espaces et les sauts de ligne.

Y a-t-il quelque chose de déjà existant pour faire cela, ou doit je plutôt partir dans l'idée de remplacer tous les espaces par des • et tous les sauts de ligne par des ¶ (en boucle).

Merci

[mikell]

On pourrait avoir un exemple du résultat souhaité ?

[PandiPanda]

quelque chose de ce genre ci?

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)

Global $oMyError

Example()

Func Example()
    Local $myedit, $msg

    GUICreate("My GUI edit")  ; will create a dialog box that when displayed is centered

    $myedit = GUICtrlCreateEdit("Ma Premiere Ligne" & @CRLF, 176, 32, 121, 97, $ES_AUTOVSCROLL + $WS_VSCROLL)

    GUISetState()

    ; will be append dont' forget 3rd parameter
    GUICtrlSetData($myedit, GUICtrlRead($myedit)&"Second line", 1)
    _Replace($myedit)
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        Sleep(75)
        _Replace($myedit)
    WEnd

    GUIDelete()
EndFunc   ;==>Example

Func _Replace($ctrlId)
    Local $str=GUICtrlRead($ctrlId)
    $str=StringReplace($str," ","•")
    $str=StringReplace($str,@CRLF,"¶")
    GUICtrlSetData($ctrlId,$str)
EndFunc

[eric]

Merci PandiPanda,

C'est bien le résultat que j'aimerais obtenir.
Mais le problème c'est que l'Edit n'est plus vraiment éditable.
Le curseur reste coincé sur le dernier caractère, et je ne peux plus modifier le texte qui est avant.

Pour Mikel :

Au lieu de :

Bonjour
Comment allez vous ?

J'aimerais

Bonjour¶
Comment•allez•vous•?

En gros un peu comme le fait Word

[mikell]

Dans le script du Panda, la fonction Replace dans la boucle While doit fonctionner sous conditions sinon ça bloque ^^

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

    GUICreate("My GUI edit")  
    $myedit = GUICtrlCreateEdit("", 100, 30, 180, 100, $ES_WANTRETURN)
    GUISetState()

GUICtrlSetData($myedit, "Bonjour" &@CRLF& "Comment allez vous ?")
_Replace($myedit)

    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        Sleep(10)
        _Replace($myedit)
    WEnd

Func _Replace($ctrlId)
    Local $str=GUICtrlRead($ctrlId)
    If StringInStr($str, " ") Then $str=StringReplace($str," ","•")
    If StringInStr($str, @CRLF) Then $str=StringReplace($str,@CRLF,"¶")
    GUICtrlSetData($ctrlId,$str)
EndFunc

[eric]

Merci Mikell mais le problème est le même.

L'edit n'est pas modifiable ailleurs qu'en fin de ligne et l'autre problème c'est que les sauts de lignes sont remplacés par le symbole ¶.

Du coup tout se retrouve sur la même ligne de texte.

[jchd]

Bah oui. Il faut remplacer @CRLF par "pied de mouche @CRLF" sinon ça fusionne toutes les lignes, bien sûr.

[eric]

Bonjour jchd,

Si je remplace :

$str=StringReplace($str,@CRLF,"¶")
Par
$str=StringReplace($str,@CRLF,"¶"&@CRLF)

Ça me rajoute plein de ¶ à la fin de ligne

[Ahbadiane]

Pour contourner le problème il faut d'abord remplacer les "¶" & @CRLF par autre chose (Chr(0) par exemple) , puis remplacer effectivement les @CRLF par "¶" & @CRLF et enfin remettre les "¶" & @CRLF à la place des Chr(0)
D'autre part, il serait bon de ne pas appeler la fonction tout le temps mais simplement en cas de changement, d'où le test If $str <> GUICtrlRead($myedit) Then

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

Global $str
GUICreate("My GUI edit")
$myedit = GUICtrlCreateEdit("", 100, 30, 180, 100)
GUISetState()

GUICtrlSetData($myedit, "Bonjour" &@CRLF& "Comment allez vous ?")

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    Sleep(10)
    If $str <> GUICtrlRead($myedit) Then
        $str = GUICtrlRead($myedit)
        _Replace($myedit)
    EndIf
WEnd

Func _Replace($ctrlId)
    Local $str=GUICtrlRead($ctrlId)
    If StringInStr($str, " ") Then $str=StringReplace($str," ","•")
    If StringInStr($str, "¶" & @CRLF) Then $str=StringReplace($str, "¶" & @CRLF, Chr(0))
    If StringInStr($str, @CRLF) Then $str=StringReplace($str, @CRLF, "¶" & @CRLF)
    If StringInStr($str, Chr(0)) Then $str=StringReplace($str, Chr(0), "¶" & @CRLF)
    GUICtrlSetData($ctrlId,$str)
EndFunc

[eric]

Bonjour Ahbadiane,

Merci pour ce code, il fonctionne effectivement comme souhaité.

Si j'avais juste une petite remarque à apporter, dès que le texte dépasse la hauteur de l'édit, (donc dès qu'il y a les ascenseurs), l'affichage de l'édit revient toujours en début du texte (tout en haut)

Résultat on ne peut pas voir ce que l'on écrit si l'on dépasse la hauteur de l'édit.

Y a t il un moyen de résoudre ce problème ?

Merci

[TT22]

Est-ce que ce code te convient ?

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

Global $OLD_EDIT = ""

GUICreate("My GUI edit",500,500)
$myedit = GUICtrlCreateEdit("", 10, 10, 480, 480)
GUISetState()

GUICtrlSetData($myedit, "Bonjour" &@CRLF& "Comment allez vous ?")
_Replace($myedit)

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    Sleep(10)
    _Replace($myedit)
WEnd

Func _Replace($ctrlId)
    If GUICtrlRead($myedit) <> $OLD_EDIT Then
        $Split = StringSplit(GUICtrlRead($myedit),@CRLF)
        $Return = ""
        For $i = 1 To UBound($Split)-1 Step 1
            If _IsImpair($i) Then
                If $i <> UBound($Split)-1 Then
                    If StringRight($Split[$i],1) <> "¶" Then
                        $Split[$i]=$Split[$i]&"¶"
                    EndIf
                ElseIf StringRight($Split[$i],1) = "¶" Then
                    $Split[$i]=StringLeft($Split[$i],StringLen($Split[$i])-1)
                EndIf
                If $i <> UBound($Split)-1 Then
                    $Return=$Return&$Split[$i]&@CRLF
                Else
                    $Return=$Return&$Split[$i]
                EndIf
            EndIf
        Next
        $Return = StringReplace($Return," ","•")
        GUICtrlSetData($myedit,$Return)
        $OLD_EDIT = GUICtrlRead($myedit)
    EndIf
EndFunc

Func _IsImpair($Number)
    If $Number/2 <> Floor($Number/2) Then
        Return 1
    Else
        Return 0
    EndIf
EndFunc

Il fait en sorte que l'Edit défile en même temps, et le caractère ¶ se supprime automatiquement lorsqu'une le dernière ligne est supprimée.

[eric]

Bonjour TT22.

Le script fonctionne mais le problème est le même.

Si j'ai un texte plus grand que la taille de l'édit et que je veux rajouter du texte à la fin, dès que j'appuie sur une touche l'affichage et l’ascenseur remonte au début du texte.

[TommyDDR]

Essayez ça :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>

Global $OLD_EDIT = ""

GUICreate("My GUI edit",500,500)
$myedit = GUICtrlCreateEdit("", 10, 10, 480, 480)
GUISetState()

Local $texte = ""
For $i = 0 To 100
    For $j = 0 To 100
        $texte &= Chr(Random(30, 100, 1))
    Next
    $texte &= @CRLF
Next
$texte = StringTrimRight($texte, 2)
GUICtrlSetData($myedit, $texte)
_Replace($myedit)
Local $Lignes = _GUICtrlEdit_GetLineCount($myedit)
_GUICtrlEdit_LineScroll($myedit, 0, $Lignes)

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    Sleep(10)
    _Replace($myedit)
WEnd

Func _Replace($ctrlId)
    If GUICtrlRead($myedit) <> $OLD_EDIT Then
        $Split = StringSplit(GUICtrlRead($myedit),@CRLF)
        $Return = ""
        For $i = 1 To UBound($Split)-1 Step 1
            If _IsImpair($i) Then
                If $i <> UBound($Split)-1 Then
                    If StringRight($Split[$i],1) <> "¶" Then
                        $Split[$i]=$Split[$i]&"¶"
                    EndIf
                ElseIf StringRight($Split[$i],1) = "¶" Then
                    $Split[$i]=StringLeft($Split[$i],StringLen($Split[$i])-1)
                EndIf
                If $i <> UBound($Split)-1 Then
                    $Return=$Return&$Split[$i]&@CRLF
                Else
                    $Return=$Return&$Split[$i]
                EndIf
            EndIf
        Next
        $Return = StringReplace($Return," ","•")
        GUICtrlSetData($myedit,$Return)
        $OLD_EDIT = GUICtrlRead($myedit)
    EndIf
EndFunc

Func _IsImpair($Number)
    If $Number/2 <> Floor($Number/2) Then
        Return 1
    Else
        Return 0
    EndIf
EndFunc

[eric]

Bonjour TommyDDR,

Même problème avec ce code.

Au passage on commence à avoir du code balèze que j'ai du mal à interpréter.

Si c'est trop compliqué je m'en passerais.

[TT22]

Désolé, j'ai posté une mauvaise version du script (où je n'avais pas encore ajouté la bonne fonction).
Donc, voilà ce que tu veux :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#Include <GuiEdit.au3>
#include <ScrollBarConstants.au3>

Global $OLD_EDIT = ""

GUICreate("My GUI edit",500,500)
$myedit = GUICtrlCreateEdit("", 10, 10, 480, 480)
GUISetState()

GUICtrlSetData($myedit, "Bonjour" &@CRLF& "Comment allez vous ?")
_Replace($myedit)

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    Sleep(10)
    _Replace($myedit)
WEnd

Func _Replace($ctrlId)
    If GUICtrlRead($myedit) <> $OLD_EDIT Then
        $Split = StringSplit(GUICtrlRead($myedit),@CRLF)
        $Return = ""
        For $i = 1 To UBound($Split)-1 Step 1
            If _IsImpair($i) Then
                If $i <> UBound($Split)-1 Then
                    If StringRight($Split[$i],1) <> "¶" Then
                        $Split[$i]=$Split[$i]&"¶"
                    EndIf
                ElseIf StringRight($Split[$i],1) = "¶" Then
                    $Split[$i]=StringLeft($Split[$i],StringLen($Split[$i])-1)
                EndIf
                If $i <> UBound($Split)-1 Then
                    $Return=$Return&$Split[$i]&@CRLF
                Else
                    $Return=$Return&$Split[$i]
                EndIf
            EndIf
        Next
        $Return = StringReplace($Return," ","•")
        GUICtrlSetData($myedit,$Return)
        $OLD_EDIT = GUICtrlRead($myedit)
        _GUICtrlEdit_Scroll($myedit,$SB_PAGEDOWN)
    EndIf
EndFunc

Func _IsImpair($Number)
    If $Number/2 <> Floor($Number/2) Then
        Return 1
    Else
        Return 0
    EndIf
EndFunc

La fonction manquante était _GUICtrlEdit_Scroll($myedit,$SB_PAGEDOWN)

[eric]

Ben, pas si simple que ça cette histoire

TT22, votre second script permet effectivement de voir ce que l'on écrit en bas de l'édit.

Par contre je ne peux pas modifier le texte qui est au début puisque le curseur redescend automatiquement en bas.

[mikell]

La vie est pleine de choix difficiles...

Si j'ai un texte plus grand que la taille de l'édit et que je veux rajouter du texte à la fin, dès que j'appuie sur une touche l'affichage et l’ascenseur remonte au début du texte.

je ne peux pas modifier le texte qui au début puisque le curseur redescend automatiquement en bas.

[eric]

Bonsoir,

En cherchant une autre idée j'ai trouvé cela, qui semble bien fonctionner.

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiEdit.au3>
#include <StaticConstants.au3>

    Local $myedit, $msg
    
    $mygui = GUICreate("My GUI edit")  ; will create a dialog box that when displayed is centered
    $myedit = GUICtrlCreateEdit("Bonjour" & @CRLF & "Comment allez vous ?" & @CRLF, 10, 10, 200, 200)
    GUISetState()

_Replace($myedit)

    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        Sleep(10)
        $etatedit = ControlGetFocus ( $mygui)
        if $etatedit="Edit1" Then
        HotKeySet("{enter}", "toucheentrer")
        HotKeySet("{space}", "toucheespace")
    else
        HotKeySet("{enter}")
        HotKeySet("{space}")
        EndIf
    WEnd

func toucheentrer()
_GUICtrlEdit_ReplaceSel ($myedit,"¶"&@crlf)
endfunc

func toucheespace()
_GUICtrlEdit_ReplaceSel ($myedit,"•")
endfunc

Func _Replace($ctrlId)
    Local $str=GUICtrlRead($ctrlId)
    If StringInStr($str, " ") Then $str=StringReplace($str," ","•")
    If StringInStr($str, @CRLF) Then $str=StringReplace($str,@CRLF,"¶"& @crlf)
    GUICtrlSetData($ctrlId,$str)
EndFunc