[..] let's enable drag&drop on a list

[lesolutionneur]

Encore bonjour tout le monde,
J'ai créé une liste dans une gui avec Guicreate list, le problème est que je veux qu'on puisse déplacer un ou plusieurs fichiers à l'intérieur pour que je puisse récupérer leur chemin.

J'ai essayé les accept drop et les autres trucs mais la documentation n'étant pas claire, je n'ai pas réussi.

Pouvez-vous me donner un exemple d'une list acceptant la drag&drop, qui récupère les adresses des différents fichiers qu'on dépose dessus (1 ou plusieurs en même temps), mais qui ne change pas sa valeur par le drag and drop, juste recuperer les adresses, je me chargerais moi même de mettre à jour la list.


Merci d'avance (à Matwachich probablement, car elle répond à 3/4 de mes questions ! )

[Tlem]

Sujet déjà abordé à plusieurs reprises : En utilisant la recherche du forum, voici ce que ça donne !

[lesolutionneur]

Oui, mais avec un rapide coup d'oeil, je ne vois pas comment je peux le faire à une liste.

N'est-il vraiment pas possible de me faire rapidemment un exemple ?

Merci d'avance.

[mikell]

Voilà un exemple simple
Après si tu veux compliquer, faut chercher pour l'adapter comme tu veux

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;#include <ListBoxConstants.au3>
#include <GUIListBox.au3>

Global $sItems = ""
$gui = GUICreate("My GUI list", 400, 200, -1, -1, -1, $WS_EX_ACCEPTFILES) 
$read = GUICtrlCreateButton("lire", 10, 10, 75, 25)
$mylist = GUICtrlCreateList("", 10, 50, 350, 100, $LBS_EXTENDEDSEL )
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUISetState()

While 1
   $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit
            Case $msg = $GUI_EVENT_DROPPED
        GUICtrlSetData($mylist, @GUI_DRAGFILE)
            Case $msg = $read
        $aItems = _GUICtrlListBox_GetSelItemsText($mylist)
        For $iI = 1 To $aItems[0]
            $sItems &= @LF & $aItems[$iI]
        Next
        MsgBox(4160, "Information", "Items Selected: " & $sItems)
             ; MsgBox(0, "", GuiCtrlRead($mylist))
        EndSelect
WEnd
 

[Tlem]

@mikell,
J'ai besoin d'aller aux toilettes, est-ce que tu peut me venir en aide STP ?

[lesolutionneur]

Ok, merci !
@Tlem: hors-sujet ? C'est bien parce que t'es en rouge (donc fâché) que je ne signale pas ton message aux modérateurs !

► Afficher le textetoi

non, je rigole

[Tlem]

Oui, je suis fâché parce que vous avez à peine regardé le lien que j'ai donné, car la réponse y était toute faites.

Et oui, je suis tout rouge de colère.

[mikell]

@mikell,
J'ai besoin d'aller aux toilettes, est-ce que tu peut me venir en aide STP ?

façon zeshrek

Code : Tout sélectionner

Func _SecondDoorOnZeLeft()
Local $pq, $journal
Do
   If $pq = 0 Then 
         $pq = $journal / 16
         $journal = 0
   EndIf
   If $time > 600*1000 Then 
         If $journal Then 
              _Read($journal)
         Else
             If $pq = $journal / 16 Then 
                _Read($pq)
             Else
                 Sleep(1000)
             EndIf
         EndIf
    EndIf
Until ($soundplay = true OR $time >= 3600*1000)
EndFunc

[DimVar]

PTDR

[lesolutionneur]

Hilarant mais on s'écarte du sujet, là..

@Tlem: ton lien n'était qu'une vulgaire recherche que j'avais faite moi même auparavant. Ce que je voulais, c'est avec une listbox. Mais merci de ne pas hijacker le topic, je préviendrais si la solution qu'un membre a bien voulu me donner marche.

[mikell]

Bon quelque part Tlem a bien raison de râler (et moi tort de poster)
En effet, cette "vulgaire" recherche avec le lien qu'il t'a donné t'aurait rapidement amené à ce post
http://www.autoitscript.fr/forum/viewto ... 640#p28640
qui correspond exactement à ce que tu demandes
Certes l'exemple donné là concerne une Listview, mais pour peu qu'on s'en donne la peine on comprend de suite que le script est facilement adaptable à une Listbox en quelques minutes :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListBox.au3>

Global $sItems = "", $DropFilesArr[1]

$gui = GUICreate("My GUI list", 400, 200, -1, -1, -1, $WS_EX_ACCEPTFILES) 
GUIRegisterMsg(0x233, "WM_DROPFILES_FUNC")
$read = GUICtrlCreateButton("lire", 10, 10, 75, 25)
$mylist = GUICtrlCreateList("", 10, 50, 350, 100, $LBS_EXTENDEDSEL )
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUISetState()

While 1
   $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit
            Case $msg = $GUI_EVENT_DROPPED
            For $i = 1 To UBound($DropFilesArr)-1
                GUICtrlSetData($mylist, $DropFilesArr[$i])
            Next
            Case $msg = $read
        $aItems = _GUICtrlListBox_GetSelItemsText($mylist)
        For $iI = 1 To $aItems[0]
            $sItems &= @LF & $aItems[$iI]
        Next
        MsgBox(4160, "Information", "Items Selected: " & $sItems)
        EndSelect
WEnd


Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 255)
    For $i = 0 To $nAmt[0] - 1
        $nSize = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
        $nSize = $nSize[0] + 1
        $pFileName = DllStructCreate("char[" & $nSize & "]")
        DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", _
            DllStructGetPtr($pFileName), "int", $nSize)
        ReDim $DropFilesArr[$i + 2]
        $DropFilesArr[$i+1] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
    $DropFilesArr[0] = UBound($DropFilesArr)-1
EndFunc

Et puis qualifier une recherche de "vulgaire" est ... vulgaire

[DimVar]

Et puis qualifier une recherche de "vulgaire" est ... vulgaire

[MODE TROLL POUBELLISABLE ON]
Tres juste !
[MODE TROLL POUBELLISABLE OFF]