[..] Gestion base de donnée/structure (sqlite)

[SurPriseS]

Bonjour !

Bon, explication :
Je bosse dans une petite boite d'informatique, et on à une douchette à code barre qui traine depuis des lustres mais elle est inutilisée...
Donc je me suis dit, on va faire un ptit programme autoit pour s'en servir



(la partie vide sur le coté droit servira à de l'affichage de donnée, pour la partie recherche)


L'idée de base pour le moment, c'est pas de la gestion de stock (je verrais si je vais aussi "loin" plus tard), mais la création d'une BDD contenant :
- Prix d'achat/vente
- les code barre articles
- catégorie/marques
- fournisseurs (que j'ai oublié dans ma gui :$ )
-...

Voilà pour le planté de décors...

Ma question est donc, comment faire pour gérer/créer au mieux, la/les bases de données....

En gros, je sais à peut près me servir de SQLite, mais je ne sais pas du tout comment m'y prendre pour ranger/structurer "correctement" mes données dedans et permettre par la suite d'aller plus loin.

Les bdd, c'est pas mon truc, j'en ai presque jamais fait donc je suis un peu "perdu"


Bon, c'est un bon gros pavé pour presque rien dire, mais bon, j'espère être à peu près clair ^^

Merci !

[Alex74]

Bonjour,

Pour le management de votre BDD, vous pouvez vous servir du soft SQLite Expert. Il existe une version gratuite pour utilisation perso si je ne dit pas de betises.

[SurPriseS]

Mon problème, enfaite, c'est pas d'écrire la base en elle même, c'est d'ordonné/ranger les données et les tables...

Je ne sais pas comment structuré ma base quoi je connais très mal SQL et c'est possibilité :\

[Yogui]

En faite la question est comment créer un MCD et la un peu de lecture s'impose.

http://fdigallo.online.fr/cours/merise.pdf

Le but est de trier les données pour éviter d'avoir des enregistrements redondant.

Dans votre imprim'écran vous avez catégorie qui devra certainement avoir une table idem pour marque sauf si vous avez un article par marque.

Vous indiquez que vous voulez une table avec : Prix d'achat/vente mais le prix de vente est calculé (avec une TVA et une Marge qui peuvent varier donc seul le prix d'achat sera enregistrer en base dans la table produit.

Si vous douchez un de vos code barre sur google vous risquez de le retrouver les codes barre sont souvent des identifiants produit fiable, donc pas de table code barre....

La table fournisseur dépend beaucoup de vos fournisseurs un fournisseur peux t il vendre une ou plusieurs marque d'une ou plusieurs cathégorie.

je verrai :

une table Produit($codebarre,prixHA,designationproduit,#IDTVA,#IDfournisseur,IDMarque)
Une table TVA ($IDTVA,tauxTVA)
Une table fournisseur(#IDfournisseur,designationfournisseur,(rue adresse nom ...), #Idmarque,#idcaterorie)
....

Il existe des logiciel qui aide à créer des MCD comme http://www.quest.com/toad-data-modeler/

Pour finir Attention faire plus tard la gestion du stock c'est prendre un risque de devoir faire évoluer la base le truc pour bien construire un BDD c'est de se poser les bonnes questions.

faites votre MCD (cf doc merise) je vous le corrigerai mais vous seul pouvez vous poser les bonnes questions

Yog

[overflow]

J ai fait un truc similaire avec Sqlite pour géré des medicament

tient je te joint le source
Dedans tu a toute ce qu il te faut connaitre pour debuté
Creation de base/table/champ
Ajout/surprime et édition
Recherche et affichage

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <ToolbarConstants.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>
#include <ComboConstants.au3>

Global $bdd=@ScriptDir & "\sqbdd.db",$medoc="cachets",$Col=6
Global $page=1
Global $pagemax=1
_SQLite_Startup ()
If @error Then
    MsgBox(16, "SQLite Error", "SQLite.dll Can't be Loaded!")
    Exit - 1
EndIf


if Not FileExists($bdd) Then
    $ex=MsgBox(1,"Erreur","Bdd introuvable " & @CRLF & "Créer une nouvelle ?")
    If $ex=1 Then
        makebase()
    Else
        Exit
    EndIf
EndIf


$Form1 = GUICreate("BDD", 444, 400);, 199, 298)
$Tab1 = GUICtrlCreateTab(8, 48, 425, 337)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$TabSheet2 = GUICtrlCreateTabItem("Operations")
$Label7 = GUICtrlCreateLabel("Rechercher : ", 48, 104, 69, 17)
$Input7 = GUICtrlCreateInput("", 144, 104, 121, 21)
$Button1 = GUICtrlCreateButton("Trouve !", 296, 104, 75, 25, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Ajouter", 56, 192, 75, 25, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Effacer", 176, 192, 75, 25, $WS_GROUP)
$Button4 = GUICtrlCreateButton("Modifier", 296, 192, 75, 25, $WS_GROUP)
$Button6 = GUICtrlCreateButton("Afficher", 176, 144, 75, 25, $WS_GROUP)
$Edit1 = GUICtrlCreateEdit("", 56, 240, 321, 113, BitOR($ES_AUTOVSCROLL,$ES_AUTOHSCROLL,$ES_WANTRETURN,$WS_VSCROLL))
$PPlus = GUICtrlCreateButton(">", 304, 356, 51, 22, $WS_GROUP)
$PMoinS = GUICtrlCreateButton("<", 71, 356, 51, 22, $WS_GROUP)
$Label1 = GUICtrlCreateLabel("Page : ", 160, 360, 102, 17)

GUICtrlCreateTabItem("")
$Label8 = GUICtrlCreateLabel("Base", 32, 16, 28, 17)
$path_base = GUICtrlCreateInput("", 72, 16, 137, 21)
$Label9 = GUICtrlCreateLabel("Nb d'enregistrement", 248, 16, 150, 17)
GUISetState(@SW_SHOW)


vmax()
Afpage($page)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $GUI_EVENT_CLOSE
            _SQLite_Shutdown ()
            Exit
        Case $Button2
            insertbase()
        Case $Button3
            $id=InputBox("Effacer","Numero d ID")
            delentre($id)
        Case $PPlus
            $page +=1
            If $page > $pagemax Then $page -=1
            Afpage($page)
            GUICtrlSetData($Label1,"Page : " & $page & " / " & $pagemax)
        Case $PMoinS
            $page -=1
            If $page <= 0 Then $page =1
            Afpage($page)
            GUICtrlSetData($Label1,"Page : " & $page & " / " & $pagemax)
        Case $Button6
            $id=InputBox("Afficher","Numero d ID")
            Afinfo($id)
        Case $Button4
            $id=InputBox("Modifier","Numero d ID")
            modif($id)
        Case $Button1
            $id=GUICtrlRead($Input7)
            If $id="" Then
                MsgBox(0,"Erreur","Rien a chercher")
            Else
                recher($id)
            EndIf

    EndSwitch
WEnd

; ============================Fonctions

Func vmax()

    Local $hQuery, $aRow, $compte

    _SQLite_Open ($bdd)

        _SQlite_Query (-1, "SELECT count(*)FROM " & $medoc & " ;", $hQuery)

            While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK
                $compte &= $aRow[0]
            WEnd
    _SQLite_Close()

    GUICtrlSetData($Label9,"Nb d'enregistrement : " & $compte)

    GUICtrlSetData($path_base,$bdd)
    $pagemax=Ceiling($compte/10)
    GUICtrlSetData($Label1,"Page : " & $page & " / " & $pagemax)
EndFunc

Func Afpage($arg)
    Local $hQuery, $aRow, $sMsg
    $arg=($arg-1)*10
    _SQLite_Open ($bdd)
    _SQlite_Query (-1, "SELECT * FROM " & $medoc & " LIMIT " & $arg & ",10 ;", $hQuery) ; the query

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK
            $sMsg &= "ID : " & $aRow[0] & ": Nom : " & $aRow[1] & @CRLF
        WEnd

    _SQLite_Close()
    GUICtrlSetData($Edit1,$sMsg)
EndFunc
Func Afinfo($arg)
    Local $hQuery, $aRow, $sMsg
        _SQLite_Open ($bdd)
        _SQlite_Query (-1, "SELECT * FROM " & $medoc & " WHERE id=" & $arg & ";", $hQuery) ; the query

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK

            $sMsg &= "ID : " & $aRow[0] & @CRLF & @CRLF &"Nom : " & $aRow[1] & @CRLF &@CRLF & "Composition : " & $aRow[2]& @CRLF &@CRLF & "Laboratoire : " & $aRow[3]& @CRLF &@CRLF & "Coordonnées labo : " & $aRow[4]& @CRLF &@CRLF & "Proprités : " & $aRow[5]& @CRLF &@CRLF & "Posologie : " & $aRow[6]
        WEnd

    _SQLite_Close()
    If $sMsg="" Then
        MsgBox(0,"Erreur","ID introuvable")
    Else
        $Afi = GUICreate("Produit", 405, 294);, 302, 218)
        $Editprod = GUICtrlCreateEdit("", 32, 40, 337, 209)
        $Bton1 = GUICtrlCreateButton("Ok", 152, 256, 75, 25, $WS_GROUP)
        GUISetState(@SW_SHOW)

        GUICtrlSetData($Editprod,$sMsg)

            While 1
                $nMsg = GUIGetMsg()
                    Switch $nMsg
                        Case $Bton1
                            GUIDelete($Afi)
                            ExitLoop

                    EndSwitch
            WEnd
    EndIf
EndFunc
Func modif($arg)
            Local $hQuery, $aRow, $sMsg
        _SQLite_Open ($bdd)
        _SQlite_Query (-1, "SELECT * FROM " & $medoc & " WHERE id=" & $arg & ";", $hQuery) ; the query

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK

            $sMsg &= $aRow[0] & "|" &$aRow[1] & "|" &$aRow[2] & "|" &$aRow[3] & "|" &$aRow[4] & "|" &$aRow[5] & "|" &$aRow[6]

        WEnd
        If $sMsg="" Then
            MsgBox(0,"Erreur","ID introuvable")
                _SQLite_Close()
        Else
        $aRow=StringSplit($sMsg,"|")
        popupinfos()
                GUICtrlsetdata($infosI1,$aRow[2])
                GUICtrlsetdata($infosI2,$aRow[3])
                GUICtrlsetdata($infosI3,$aRow[4])
                GUICtrlsetdata($infosI4,$aRow[5])
                GUICtrlsetdata($infosI5,$aRow[6])
                GUICtrlsetdata($infosI6,$aRow[7])
                    While 1
                    $nMsg = GUIGetMsg()
                        Switch $nMsg
                            Case $infosB1
                                $name=_sqlSpecialChars(GUICtrlRead($infosI1))
                                $Compo=_sqlSpecialChars(GUICtrlRead($infosI2))
                                $Labo=_sqlSpecialChars(GUICtrlRead($infosI3))
                                $Adrlab=_sqlSpecialChars(GUICtrlRead($infosI4))
                                $Propri=_sqlSpecialChars(GUICtrlRead($infosI5))
                                $Poso=_sqlSpecialChars(GUICtrlRead($infosI6))

                                If $name & $Compo & $Labo & $Adrlab & $Propri & $Poso ="" Then
                                    MsgBox(0,"","Pas d infos a enregistrer")
                                GUIDelete($infos)
                                _SQLite_Close ()
                                ExitLoop
                                EndIf
                                _SQLite_Exec (-1, "UPDATE  " & $medoc & " SET NOM='" & $name & "',COMPOSITION='"& $Compo & "',LABORATOIRE='" & $Labo & "',COORLABO='"& $Adrlab &"',PROPRIETES='" & $Propri & "',POSOLOGIE='"& $Poso & "' WHERE id="& $arg & ";")


                                _SQLite_Close ()
                                GUIDelete($infos)
                                vmax()
                                Afpage($page)
                                ExitLoop
                            Case $infosB2
                                _SQLite_Close()
                                GUIDelete($infos)
                                ExitLoop
                        EndSwitch
                    WEnd
        EndIf
EndFunc
Func delentre($arg)
        Local $hQuery, $aRow, $sMsg
        _SQLite_Open ($bdd)
        _SQlite_Query (-1, "SELECT * FROM " & $medoc & " WHERE id=" & $arg & ";", $hQuery)

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK

            $sMsg &= $aRow[0] & "|" &$aRow[1] & "|" &$aRow[2] & "|" &$aRow[3] & "|" &$aRow[4] & "|" &$aRow[5] & "|" &$aRow[6]

        WEnd
        If $sMsg="" Then
            MsgBox(0,"Erreur","ID introuvable")
                _SQLite_Close()
        Else
        $aRow=StringSplit($sMsg,"|")
        popupinfos()
                GUICtrlsetdata($infosI1,$aRow[2])
                GUICtrlsetdata($infosI2,$aRow[3])
                GUICtrlsetdata($infosI3,$aRow[4])
                GUICtrlsetdata($infosI4,$aRow[5])
                GUICtrlsetdata($infosI5,$aRow[6])
                GUICtrlsetdata($infosI6,$aRow[7])
                    While 1
                    $nMsg = GUIGetMsg()
                        Switch $nMsg
                            Case $infosB1
                                $req=_SQLite_Exec (-1, "DELETE FROM " & $medoc & " WHERE id="& $arg &";")
                                _SQLite_Close()
                                If $req<>$SQLITE_OK Then Exit MsgBox(0,"Erreur","Erreur a l efacement !!")

                                GUIDelete($infos)
                                vmax()
                                Afpage($page)
                                ExitLoop
                            Case $infosB2
                                _SQLite_Close()
                                GUIDelete($infos)
                                ExitLoop
                        EndSwitch
                    WEnd


        EndIf


EndFunc
Func makebase()

    _SQLite_Open ($bdd)
            If @error > 0 Then Exit MsgBox(16, "SQLite Error", "Impossible de créer la Base de donnée!")
            _SQLite_Exec (-1, "CREATE TABLE " & $medoc & " (id INTEGER NOT NULL PRIMARY KEY AUTOINCREMENT,NOM ,COMPOSITION , LABORATOIRE , COORLABO , PROPRIETES , POSOLOGIE);")


    _SQLite_Close ()

EndFunc
Func recher($arg)
    Local $hQuery, $aRow, $sMsg,$first,$sMsg
        $first=0
        _SQLite_Open ($bdd)
        _SQlite_Query (-1, "SELECT * FROM " & $medoc & " WHERE NOM LIKE '%"&$arg & "%';", $hQuery) ; the query

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK

            $sMsg &= $aRow[0] & " : " & $aRow[1] & "|"
            If $first=0 Then $first=$aRow[0] & " : " & $aRow[1]
        WEnd

    _SQLite_Close()
    If $sMsg="" Then
        MsgBox(0,"Recherche","Aucun resultat")
        Return
    EndIf

    $Find = GUICreate("Resultats", 393, 288)
Global  $Afres = GUICtrlCreateEdit("", 32, 56, 337, 209)
    ;$Bt1 = GUICtrlCreateButton("Selection", 296, 24, 75, 25, $WS_GROUP)
    $Combo = GUICtrlCreateCombo("", 40, 24, 233, 25)
    GUICtrlSetData($Combo,$sMsg,$first)
    GUISetState(@SW_SHOW)

    $id0=StringSplit(GUICtrlRead($Combo),":")
    $id1=$id0[1]
    afcombo($id1)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                GUIDelete($Find)
                ExitLoop
            Case $Combo
                $id0=StringSplit(GUICtrlRead($Combo),":")
                $id1=$id0[1]
                afcombo($id1)

        EndSwitch
    WEnd
EndFunc

Func afcombo($arg)

        Local $hQuery, $aRow, $sMsg
        _SQLite_Open ($bdd)
        _SQlite_Query (-1, "SELECT * FROM " & $medoc & " WHERE id=" & $arg & ";", $hQuery) ; the query

        While _SQLite_FetchData ($hQuery, $aRow) = $SQLITE_OK

            $sMsg &= "ID : " & $aRow[0] & @CRLF & @CRLF &"Nom : " & $aRow[1] & @CRLF &@CRLF & "Composition : " & $aRow[2]& @CRLF &@CRLF & "Laboratoire : " & $aRow[3]& @CRLF &@CRLF & "Coordonnées labo : " & $aRow[4]& @CRLF &@CRLF & "Proprités : " & $aRow[5]& @CRLF &@CRLF & "Posologie : " & $aRow[6]
        WEnd

        _SQLite_Close()

        GUICtrlSetData($Afres,$sMsg)

EndFunc

Func _sqlSpecialChars($in)
    $in = StringReplace($in, "'", "''")
    $in = StringReplace($in, '\', '\\')
    Return $in
EndFunc



Func insertbase()
    popupinfos()
    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $infosB1
                $name=_sqlSpecialChars(GUICtrlRead($infosI1))
                $Compo=_sqlSpecialChars(GUICtrlRead($infosI2))
                $Labo=_sqlSpecialChars(GUICtrlRead($infosI3))
                $Adrlab=_sqlSpecialChars(GUICtrlRead($infosI4))
                $Propri=_sqlSpecialChars(GUICtrlRead($infosI5))
                $Poso=_sqlSpecialChars(GUICtrlRead($infosI6))

                If $name & $Compo & $Labo & $Adrlab & $Propri & $Poso ="" Then
                    MsgBox(0,"","Pas d infos a enregistrer")
                    GUIDelete($infos)
                    Return
                EndIf

                _SQLite_Open ($bdd)
                    If @error > 0 Then Exit MsgBox(16, "SQLite Error", "Impossible de lire la Base de donnée!")
                _SQLite_Exec (-1, "Insert into " & $medoc & " values (NULL,'" & $name & "','"& $Compo & "','" & $Labo & "','"& $Adrlab &"','" & $Propri & "','"& $Poso & " ');")


                _SQLite_Close ()
                GUIDelete($infos)
                vmax()
                Afpage($page)
                ExitLoop

        Case $infosB2
                GUIDelete($infos)

                ExitLoop


        EndSwitch
    WEnd

EndFunc

Func popupinfos()
Global  $infos=GUICreate("Infos", 459, 250);, 211, 351)
Global  $infosL1 = GUICtrlCreateLabel("NOM", 24, 24, 29, 17)
Global  $infosL2 = GUICtrlCreateLabel("COMPOSITION", 24, 54, 79, 17)
Global  $infosL3 = GUICtrlCreateLabel("LABORATOIRE", 24, 84, 80, 17)
Global  $infosL4 = GUICtrlCreateLabel("COORDONNEES LABO", 24, 114, 119, 17)
Global  $infosL5 = GUICtrlCreateLabel("PROPRIETES", 24, 144, 73, 17)
Global  $infosL6 = GUICtrlCreateLabel("POSOLOGIE RECOMMANDEE", 24, 174, 154, 17)
Global  $infosI1 = GUICtrlCreateInput("", 200, 24, 169, 21)
Global  $infosI2 = GUICtrlCreateInput("", 200, 54, 241, 21)
Global  $infosI3 = GUICtrlCreateInput("", 200, 84, 241, 21)
Global  $infosI4 = GUICtrlCreateInput("", 200, 114, 241, 21)
Global  $infosI5 = GUICtrlCreateInput("", 200, 144, 241, 21)
Global  $infosI6 = GUICtrlCreateInput("", 200, 174, 241, 21)
Global  $infosB1 = GUICtrlCreateButton("Ok", 120, 216, 75, 25, $WS_GROUP)
Global  $infosB2 = GUICtrlCreateButton("Annule", 224, 216, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
EndFunc



 

[SurPriseS]

Yogui, c'est exactement le genre d'info que je cherchais merci beaucoup ! C'est vrai aussi que si je part sur de la gestion de stock, sa va modifier complétement la structure de la base, à voir, je vais essayer de faire ça proprement dans un premier temps sans me faire une base énorme pour testé, je verrais après si je tente la gestion de stock et tout

overflow, j'en demandais pas tant, mais en tout cas, c'est quasiment ce que je veux faire, donc ça va mettre très utile pour gagner du temps Je vais étudier de près votre code

Merci beaucoup tout les 2

[jchd]

Je vais devoir ajouter mon grain de sel ce soir ou demain.

A+, pas le temps là.

Me revoilou. Quelques remarques à la suite de ce qui a été déjà écrit.

1) Commencer par l'interface, c'est mettre la charrue avant les boeufs.

2) A ce qu'a dit Yogui j'ajouterai que l'expérience pousse à dissocier plus encore les choses dans le cas général, quite à élaguer si ces points n'ont aucune chance de refléter la réalité.
2.a) Un produit a parfois plusieurs fournisseurs proposant souvent des conditions distinctes.
2.b) Le prix d'achat est lié à une entrée en stock, une livraison, une commande, un fournisseur.
2.c) Le prix d'achat seul ne reflète que rarement le prix de revient d'un article : il faut la plupart du temps tenir compte de ce qu'on appelle les frais d'approche (transport, frais de douane et transitaires, [re-]conditionnement, manutention, ...). Le total de ces deux composantes fait le véritable prix de l'article en stock.
2.d) Un article "trop longtemps" (une notion floue !) en stock se déprécie.
2.e) Le code barre d'un produit n'est pas forcément enregistré en nomenclature publique : il peut s'agir d'un code bidon (même EAN8/13), d'un code interne, d'un code de fabrication, etc.
2.f) Un même produit (offert à la vente par exemple) peut avoir plusieurs codes barres distincts (même de l'EAN).



3) Le code proposé par overflow, tout plein de bonne volonté qu'il ait été en le postant, n'est franchement pas un modèle et pour beaucoup de raisons.

3.a) Sauf circonstances très particulières, on n'ouvre et ne ferme la base qu'une fois dans le programme, jamais à chaque opération.

3.b) Ne sachant pas ce que va devenir l'appli, il est prudent de travailler avec le handle de connexion retourné par _SQLite_Open et éviter le paramètre -1 qui devient piégeant si on doit travailler avec une autre base dans le même programme (base mémoire temporaire ou autre).

3.c) SELECT * from ... est à proscrire : si on doit un jour réorganiser l'ordre des colonnes d'une ou plusieurs tables, toutes les applis utilisant cette base devront être modifiées en conséquence.

3.d) Ne pas indiquer de type dans la création d'une table n'est pas une bonne chose, SQLite ou pas.

3.e) La table unique proposée est une hérésie qui va à l'encontre de tous les principes sous-jacents à SQL (cf post de Yogui) et même au bon sens.

3.f) Il existe des fonctions de haut-niveau qui permettent d'effectuer des requêtes de façon fiable et qui renvoient un résultat correct ou une erreur circonstanciée. Il n'y a que des inconvénients à utiliser _SQLite_Query, *_FetchData et autres sans savoir exactement ce qu'on fait et pourquoi on fait ça avec ces fonctions-là.
_SQLite_QuerySingleRow, _SQLite_GetTable et surtout _SQLite_GetTable2d sont 100 fois plus solides.

Il va vraiment falloir que je trouve le moyen de refaire toute la doc SQLite et en particulier les exemples, car la plupart sont désastreux.

3.g) ...


Attendons déjà d'en savoir plus sur le modèle de données dont a vraiment besoin l'appli. Ce qui veut dire : "quelles entités, avec quelle sémantique ?" et ensuite "quelles relations les lient ?", puis "quelles contraintes les encadrent ?".

Alors seulement faire un machin qui tient le pavé à l'aide d'Expert, puis le faire tourner à la main (c'est facile) et ensuite seulement coder de l'AutoIt quand tout est stable et cohérent (vues comprises).