[R] _SoundPlay et AdlibRegister

[TommyDDR]

Bonjour,

Après plusieurs dizaines de minutes de debug... je tiens à partager mon dernier problème.

Certes cette situation n'arrivera pas tous les jours, mais si vous avez une fonction qui lance un AdlibRegister qui lance un _SoundPlay et un AdlibRegister, alors le 2eme AdlibRegister se lancera INSTANTANÉMENT sans prendre en compte son second paramètre ($time).

Exemple : Vous avez un bouton (fonction) qui lance un son différé dans le temps (AdlibRegister) qui lance une fonction _SoundStop différé de 2sec dans le temps (AdlibRegister)

J'ai fait un script qui contient le minimum de code pour reproduire ce test, essayez le en commentant / dé-commentant la ligne _SoundPlay(xxx)
Appuyez sur "a" pour lancer la fonction.

Si quelqu'un trouve une parade à ce bug...

/!\ Vous devez placer un mp3 nommé "test.mp3" à coté du script /!\

► Afficher le textecode

Code : Tout sélectionner

#include <Sound.au3>

HotKeySet("a", "BugAdLib1")

While(True)
    Sleep(10)
WEnd

Func BugAdLib1()
    ConsoleWrite("BugAdLib1() -> " & HeureActuelle() & @CRLF)
    AdlibRegister("BugAdLib2", 1000)
EndFunc

Func BugAdLib2()
    AdlibUnRegister("BugAdLib2")
    ConsoleWrite("BugAdLib2() -> " & HeureActuelle() & @CRLF)
    _SoundPlay("test.mp3")
    AdlibRegister("TestBug", 2000)
EndFunc

Func TestBug()
    ConsoleWrite("TestBug() -> " & HeureActuelle() & @CRLF)
    AdlibUnRegister("TestBug")
    Exit
EndFunc

Func HeureActuelle()
    Return  @HOUR  & ":" & @MIN & ":" & @SEC & ":" & @MSEC
EndFunc
 

Testé sous Win XP Pro SP3

[jchd]

Le problème des AdlibRegister en cascade ont été fixés dans les betas.

[TommyDDR]

D'accord, merci pour l'info

[sylvanie]

En attendant on peut contourner en conditionnant le lancement du 2eme adlibregister dans la boucle principale :

► Afficher le texte

Code : Tout sélectionner

#include <Sound.au3>

HotKeySet("a", "BugAdLib1")
Global $sound = _SoundOpen("pouette.mp3")

Global $second_to_launch=0
While(True)
    Sleep(10)
    if $second_to_launch=1 Then lance2()
WEnd

Func BugAdLib1()
    ConsoleWrite("BugAdLib1() -> " & HeureActuelle() & @CRLF)
    AdlibRegister("BugAdLib2", 1000)
EndFunc

Func BugAdLib2()

    AdlibUnRegister("BugAdLib2")
    ConsoleWrite("BugAdLib2() -> " & HeureActuelle() & @CRLF)
    If _SoundStatus($sound)="stopped" Then
        ConsoleWrite("playing"&@CRLF)
        _SoundPlay($sound,0)
        $second_to_launch=1
    EndIf
EndFunc

Func lance2()
    If $second_to_launch=1 Then
        AdlibRegister("TestBug", 5000)
        $second_to_launch=0
    EndIf
EndFunc

Func TestBug()
    ConsoleWrite("TestBug() -> " & HeureActuelle() & @CRLF)
    AdlibUnRegister("TestBug")
    _SoundClose($sound)
    Exit
EndFunc

Func HeureActuelle()
    Return  @HOUR  & ":" & @MIN & ":" & @SEC & ":" & @MSEC
EndFunc
 

En tout cas c'est effectivement un sacré cas tordu

[TommyDDR]

Ouai, je me suis débrouillé de la même manière ^^

Merci.