[..] Tirage au sort et réalisation de deux équipes

[tomasomalley]

Bonjour à tous, j'utilise AutoIt depuis peu et j'aimerai faire un petit truc (qui va vous paraitre simple) mais j'avoue que je sèche depuis plusieurs heures...
Je voudrai faire un petit outil qui me tire au sort deux équipes (à partir de quatre joueurs ou plus)
Dans mon GUI j'ai 4 champs texte que je renseigne, puis un bouton "tirage au sort" et j'aimerai obtenir mes deux équipes aléatoirement...
voici ce que j'ai fait pour le moment,
merci pour vos lumière (il y a peut-être plus simple ??)

► Afficher le texte

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <GUIComboBox.au3>

Example2()
Func Example2()
Local $gui, $msg, $random, $resultat1, $resultat2
; créer la fenêtre...
$gui = GUICreate("Tirage au sort", 400, 400)

$Button = GUICtrlCreateButton("Tirage", 140, 100, 70, 20)

Local $player1 = GUICtrlCreateInput("", 10, 30, 120, 20)
Local $player2 = GUICtrlCreateInput("", 10, 60, 120, 20)
Local $player3 = GUICtrlCreateInput("", 10, 90, 120, 20)
Local $player4 = GUICtrlCreateInput("", 10, 120, 120, 20)


GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
; lancement du tirage....
Case $msg = $Button

$resultat1 = GUICtrlCreateCombo("", 100, 170)
$resultat2 = GUICtrlCreateCombo("", 100, 200)


Local $Array1[4]
$array1[0] = GUICtrlRead($player1, 0)
$array1[1] = GUICtrlRead($player2, 0)
$array1[2] = GUICtrlRead($player3, 0)
$array1[3] = GUICtrlRead($player4, 0)

$i = 0

While 1


Sleep(1000)
$random = $array1[Random(0,3,1)]


MsgBox(0, "", GUICtrlRead($resultat1))

if $random = GUICtrlRead($player1, 0) then GUICtrlSetData($player1, "")

if $random = GUICtrlRead($player2, 0) then GUICtrlSetData($player2, "")

if $random = GUICtrlRead($player3, 0) then GUICtrlSetData($player3, "")

if $random = GUICtrlRead($player4, 0) then GUICtrlSetData($player4, "")


GUICtrlSetData($resultat1, $random)

$i = $i + 1

WEnd


MsgBox(0, "", "Equipe 01 terminée")

EndSelect
WEnd

EndFunc

le but du script :

1. je rempli mes 4 champs
2. Je lance le tirage
3. un random, me choisi 1 des 4 champs et m'efface le contenu du champ tiré au sort
4. puis me place le résultat dans une liste "résultat1"
5. Un autre random me fait la même chose mais me place le résultat dans une liste "résultat2"
6. on reviens à résultat1....random... et ainsi de suite (je pensais faire une gestion du genre
if résultat de mon random == "" alors je refais un random)
7. (fin du script) les quatre champs sont vides...
merci
encore une fois ce n'est peut'être pas le meilleur moyen pour faire cela ?

[mikell]

Je voudrai faire un petit outil qui me tire au sort deux équipes (à partir de quatre joueurs ou plus)

A la fin, ça doit faire 2 équipes de 2 joueurs ou 2 équipes de 4 joueurs ?

[Tlem]

On peut mieux faire, mais voici ce que je propose :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <GUIComboBox.au3>

Global $GUI, $msg, $Random, $Pool = 1

; créer la fenêtre...
Global $GUI = GUICreate("Tirage au sort", 361, 196, -1, -1)

Global $Input1 = GUICtrlCreateInput("Joueur 1", 10, 30, 120, 21)
Global $Input2 = GUICtrlCreateInput("Joueur 2", 10, 60, 120, 21)
Global $Input3 = GUICtrlCreateInput("Joueur 3", 10, 90, 120, 21)
Global $Input4 = GUICtrlCreateInput("Joueur 4", 10, 120, 120, 21)

Global $Label1 = GUICtrlCreateLabel("Equipe 1", 176, 24, 46, 15)
Global $Equipe1 = GUICtrlCreateList("", 152, 42, 89, 97)
Global $Label2 = GUICtrlCreateLabel("Equipe 2", 280, 24, 46, 15)
Global $Equipe2 = GUICtrlCreateList("", 256, 42, 89, 97)

Global $Button = GUICtrlCreateButton("Tirage(s)", 137, 156, 86, 28)

GUISetState(@SW_SHOW)


While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop

        ; lancement du tirage....
        Case $msg = $Button
            If GUICtrlRead($Input1) = "" And GUICtrlRead($Input2) = "" And GUICtrlRead($Input3) = "" And GUICtrlRead($Input4) = "" Then
                MsgBox(16, "Erreur", "Il n'y à plus assez de joueur pour un tirage au sort (1 au minimum)" & @TAB)
                ContinueCase
            EndIf
            Do ; Boucle d'exécution
                $Random = Random(1, 4, 1) ; tirage au sort de 1 à 4
            Until GUICtrlRead(Eval("Input" & $Random)) <> "" ; on vérifie que l'input correspondant ne soit pas vide.

        If $Pool = 1 Then ; Pour l'équipe 1
            GUICtrlSetData($Equipe1, GUICtrlRead(Eval("Input" & $Random))) ; On ajoute le joueur à la liste 1
            $Pool = 2 ; On prépare pour le tirage suivant
        Else ; Pour l'équipe 2
            GUICtrlSetData($Equipe2, GUICtrlRead(Eval("Input" & $Random))) ; On ajoute le joueur à la liste 2
            $Pool = 1 ; On prépare pour le tirage suivant
        EndIf

        GUICtrlSetData(Eval("Input" & $Random), "") ; On efface l'input tiré au sort.

        Case Else
            ; Ne sert que pour le ContinueCase précédent.

    EndSelect
WEnd

Ce code permet de faire plusieurs tirages consécutifs.
Personnellement, je verrais plutôt un tirage automatique du genre : on clique une fois et ça fait le tirage complet.

Edit : Voici la version automatique :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <GUIComboBox.au3>

Global $GUI, $msg

; créer la fenêtre...
Global $GUI = GUICreate("Tirage au sort", 361, 196, -1, -1)

Global $Input1 = GUICtrlCreateInput("Joueur 1", 10, 30, 120, 21)
Global $Input2 = GUICtrlCreateInput("Joueur 2", 10, 60, 120, 21)
Global $Input3 = GUICtrlCreateInput("Joueur 3", 10, 90, 120, 21)
Global $Input4 = GUICtrlCreateInput("Joueur 4", 10, 120, 120, 21)

Global $Label1 = GUICtrlCreateLabel("Equipe 1", 176, 24, 46, 15)
Global $Equipe1 = GUICtrlCreateList("", 152, 42, 89, 97)
Global $Label2 = GUICtrlCreateLabel("Equipe 2", 280, 24, 46, 15)
Global $Equipe2 = GUICtrlCreateList("", 256, 42, 89, 97)

Global $Button = GUICtrlCreateButton("Tirage(s)", 137, 156, 86, 28)

GUISetState(@SW_SHOW)


While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop

        ; lancement du tirage....
        Case $msg = $Button
            Local $Random, $Count = 0

            ; Contrôle du nombre de joueur :
            For $i = 1 To 4
                If StringStripWS(GUICtrlRead(Eval("Input" & $i)), 8) <> "" Then $Count += 1
            Next

            ; Si pas assez de joueurs => Erreur
            If $Count < 2 Then
                MsgBox(16, "Erreur", "Il n'y à pas assez de joueurs pour un tirage au sort (2 au minimum)" & @TAB)
                ContinueCase
            EndIf

            Local $Pool = 1
            ; Boucle sur le nombre de joueur
            For $i = 1 To $Count
                Do ; Boucle d'exécution
                    $Random = Random(1, 4, 1) ; tirage au sort de 1 à 4
                Until GUICtrlRead(Eval("Input" & $Random)) <> "" ; on vérifie que l'input correspondant ne soit pas vide.

                GUICtrlSetData(Eval("Equipe" & $Pool), GUICtrlRead(Eval("Input" & $Random))) ; On ajoute le joueur à la liste $Pool
                GUICtrlSetData(Eval("Input" & $Random), "") ; On efface l'input tiré au sort.
                If $Pool = 1 Then
                    $Pool = 2
                Else
                    $Pool = 1
                EndIf
            Next
            $Count = 0

        Case Else
            ; Ne sert que pour le ContinueCase précédent.

    EndSelect
WEnd

[mikell]

Bon, pour faire 2 équipes de 2 joueurs, y aurait aussi ça (à fignoler bien sûr)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#Include <Array.au3>

$gui = GUICreate("Tirage au sort", 390, 160)
$player1 = GUICtrlCreateInput("marcel", 10, 30, 120, 20)
$player2 = GUICtrlCreateInput("paul", 10, 60, 120, 20)
$player3 = GUICtrlCreateInput("jean", 10, 90, 120, 20)
$player4 = GUICtrlCreateInput("pierre", 10, 120, 120, 20)
$Button = GUICtrlCreateButton("Tirage", 150, 70, 80, 25)
GuiCtrlCreateLabel("Equipe 1", 280, 30, 70, 20)
GuiCtrlCreateLabel("Equipe 2", 280, 90, 70, 20)
GuiCtrlSetState($Button, $GUI_FOCUS)
GUISetState(@SW_SHOW)

While 1
$msg = GUIGetMsg()
Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case $msg = $Button
        Dim $array[4]
        For $i = 1 to 4
            $array[$i-1] = GUICtrlRead(Eval("player" & $i))
        Next        
        $equipe1 = GUICtrlCreateList("", 250, 50, 120, 20)
        $equipe2 = GUICtrlCreateList("", 250, 110, 120, 20)
        GUICtrlSetData ($equipe1, _Choix() & ", " & _Choix())
        GUICtrlSetData ($equipe2, _Choix() & ", " & _Choix())
        GuiCtrlSetState($Button, $GUI_FOCUS)
EndSelect
WEnd

Func _Choix()
$index = Random(0, UBound($array)-1, 1)
$equipier = $array[$index]
_ArrayDelete($array, $index)
Return $equipier
EndFunc

L'abord est complètement différent
ça fait des tirages complets et on peut refaire des tirages en recliquant le bouton

[tomasomalley]

UN super grand merci à vous tous !!! quelle rapidité...
Je regarde tous ça et je vous dit qui est le Winner !!

merci encore,

[tomasomalley]

pour te repondre Mikell..
je dois obtenir 2 équipes de 2 joueurs donc c'est tout bon ce que tu as fait...

[mikell]

je vous dit qui est le Winner

C'est pas le problème, ya pas un script "meilleur" que l'autre
Ce sont 2 manières totalement différentes d'arriver au même résultat, après le choix se fait en général en fonction de l'usage particulier qu'on fait du script (intégration dans un gros script par exemple)

Tu remarqueras que dans les 2 modèles de script, une infime modification permet de construire des 2 équipes de 2 joueurs à partir de n'importe quel nombre d'inscrits

Si on devait quand même définir un "meilleur", techniquement c'est celui de Tlem parce qu'il y a fait des gestions d'erreur

[tomasomalley]

Bonjour à vous...
Je rigolais pour le winner, bien sûr il n'y a pas de script meilleur, le principal étant qu'il fonctionne.
Et qu'il s'adapte bien dans ton projet comme tu l'as très bien dit.
Donc merci à vous tous en tout cas, je vais pouvoir justement avancé dans mon projet car cela faisait quelques jours que je m'échinais la dessus...
voici ce que j'ai retenu, j'ai plutôt choisi le script de Mikell mais j'ai un peu adapté et pris un peu de celui de Tlem quand même...
encore merci à vous

► Afficher le texte

#include <GUIConstantsEx.au3>
#Include <Array.au3>

$gui = GUICreate("Tirage au sort ( Six joueurs )", 390, 220)

GuiCtrlCreateLabel("Indiquez les prénoms ou surnoms des joueurs, puis cliquez sur ""tirage""", 10, 6, 330, 15)

$player1 = GUICtrlCreateInput("Joueur 1", 10, 30, 120, 20)
$player2 = GUICtrlCreateInput("Joueur 2", 10, 60, 120, 20)
$player3 = GUICtrlCreateInput("Joueur 3", 10, 90, 120, 20)
$player4 = GUICtrlCreateInput("Joueur 4", 10, 120, 120, 20)
$player5 = GUICtrlCreateInput("Joueur 5", 10, 150, 120, 20)
$player6 = GUICtrlCreateInput("Joueur 6", 10, 180, 120, 20)

$Button = GUICtrlCreateButton("Tirage", 200, 30, 80, 25)

GuiCtrlCreateLabel("Equipe n°1", 160, 80, 70, 20)
GuiCtrlCreateLabel("Equipe n°2", 160, 130, 70, 20)
GuiCtrlSetState($Button, $GUI_FOCUS)
GUISetState(@SW_SHOW)

While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
ExitLoop
Case $msg = $Button
Dim $array[6]
For $i = 1 to 6
$array[$i-1] = GUICtrlRead(Eval("player" & $i))
Next
$equipe1 = GUICtrlCreateList("", 160, 100, 200, 20)
$equipe2 = GUICtrlCreateList("", 160, 150, 200, 20)
GUICtrlSetData ($equipe1, _Choix() & " _ " & _Choix() & " _ " & _Choix())
GUICtrlSetData ($equipe2, _Choix() & " _ " & _Choix() & " _ " & _Choix())
GuiCtrlSetState($Button, $GUI_FOCUS)
EndSelect
WEnd

Func _Choix()
$index = Random(0, UBound($array)-1, 1)
Sleep (500)
$equipier = $array[$index]
_ArrayDelete($array, $index)
;GUICtrlSetData(Eval("player" & $index), "")
Sleep (500)
Return $equipier
EndFunc

[mikell]

ça marche mais par pitié vire ces Sleep, ou au moins mets juste des Sleep(10)
Sinon il faut 6 secondes pour afficher le résultat ^^