[..] Renseigner une URL sur un clic droit

[gasquy]

Bonjour.

Je cherche une solution à mon petit programme qui doit afficher 4 caméras.
Je souhaite faire un clic droit sur la caméra en question et me permettre de renseigner une "URL" et ensuite visualiser.

► Afficher le texteVoir le code

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

$titre = "IP caméra Net" ; titre du programme
$width = "800"; largeur
$height = "595" ; hauteur

SplashTextOn($titre, "Chargement en cours...", 220, 40, -1, -1, 32)

GUICreate($titre, $width,$height,-1,-1, $WS_MAXIMIZEBOX + $WS_MINIMIZEBOX + $WS_SIZEBOX) ; will create a dialog box that when displayed is centered

; camera 1
$group1 = GUICtrlCreateGroup("Caméra 1", 10, 5, 385, 275)
$ie_cam1 = _IECreateEmbedded()
$Obj_cam1 = GUICtrlCreateObj($ie_cam1, 20, 20, 365, 250)
ObjEvent($Obj_cam1, "IEEvent_", "DWebBrowserEvents")
; camera 2
$group2 = GUICtrlCreateGroup("Caméra 2", 405, 5, 385, 275)
$ie_cam2 = _IECreateEmbedded()
$Obj_cam2 = GUICtrlCreateObj($ie_cam2, 415, 20, 365, 250)
ObjEvent($Obj_cam2, "IEEvent_", "DWebBrowserEvents")
$group3 = GUICtrlCreateGroup("Caméra 3", 10, 285, 385, 275)
$ie_cam3 = _IECreateEmbedded()
$Obj_cam3 = GUICtrlCreateObj($ie_cam3, 20, 300, 365, 250)
ObjEvent($Obj_cam1, "IEEvent_", "DWebBrowserEvents")
$group4 = GUICtrlCreateGroup("Caméra 4", 405, 285, 385, 275)
$ie_cam4 = _IECreateEmbedded()
$Obj_cam4 = GUICtrlCreateObj($ie_cam4, 415, 300, 365, 250)
ObjEvent($Obj_cam4, "IEEvent_", "DWebBrowserEvents")

;Informations sur le Redimentionnement
GUICtrlSetResizing($group1, $GUI_DOCKAUTO)
GUICtrlSetResizing($group2, $GUI_DOCKAUTO)
GUICtrlSetResizing($group3, $GUI_DOCKAUTO)
GUICtrlSetResizing($group4, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam1, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam2, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam3, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam4, $GUI_DOCKAUTO)


;;; fin de l'affichage du texte
SplashOff()


GUISetState(@SW_SHOW) ; will display an empty dialog box

; Run the GUI until the dialog is closed
 While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

[ZDS]

Bonjour,

Très légère modification de ton code, et en cliquant droit sur les cases, un menu apparait, un clic sur "Url n°X" te permet de la modifier, un clic sur "Connexion" te permet de voir que l'url a bien été prise en compte. A toi de réarranger ça à ta sauce maintenant

► Afficher le texteScript 4 webcams

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

Local _
    $titre = "IP caméra Net",  _ ; Titre du programme
    $size[2] = [800,595],      _ ; Taille de la fenêtre
    $urls[5] = [4,"","","",""]

SplashTextOn($titre, "Chargement en cours...", 220, 40, -1, -1, 32)

GUICreate($titre, $size[0],$size[1],-1,-1, $WS_MAXIMIZEBOX + $WS_MINIMIZEBOX + $WS_SIZEBOX) ; will create a dialog box that when displayed is centered

; camera 1
$group1 = GUICtrlCreateGroup("Caméra 1", 10, 5, 385, 275)
$ie_cam1 = _IECreateEmbedded()
$Obj_cam1 = GUICtrlCreateObj($ie_cam1, 20, 20, 365, 250)
ObjEvent($Obj_cam1, "IEEvent_", "DWebBrowserEvents")
; camera 2
$group2 = GUICtrlCreateGroup("Caméra 2", 405, 5, 385, 275)
$ie_cam2 = _IECreateEmbedded()
$Obj_cam2 = GUICtrlCreateObj($ie_cam2, 415, 20, 365, 250)
ObjEvent($Obj_cam2, "IEEvent_", "DWebBrowserEvents")
$group3 = GUICtrlCreateGroup("Caméra 3", 10, 285, 385, 275)
$ie_cam3 = _IECreateEmbedded()
$Obj_cam3 = GUICtrlCreateObj($ie_cam3, 20, 300, 365, 250)
ObjEvent($Obj_cam1, "IEEvent_", "DWebBrowserEvents")
$group4 = GUICtrlCreateGroup("Caméra 4", 405, 285, 385, 275)
$ie_cam4 = _IECreateEmbedded()
$Obj_cam4 = GUICtrlCreateObj($ie_cam4, 415, 300, 365, 250)
ObjEvent($Obj_cam4, "IEEvent_", "DWebBrowserEvents")
;Informations sur le Redimentionnement
GUICtrlSetResizing($group1, $GUI_DOCKAUTO)
GUICtrlSetResizing($group2, $GUI_DOCKAUTO)
GUICtrlSetResizing($group3, $GUI_DOCKAUTO)
GUICtrlSetResizing($group4, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam1, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam2, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam3, $GUI_DOCKAUTO)
GUICtrlSetResizing($Obj_cam4, $GUI_DOCKAUTO)
; Menus de chaque fenêtres
Local $menu_cam1 = GUICtrlCreateContextMenu($Obj_cam1)
Local $url_cam1 = GUICtrlCreateMenuItem("URL n°1", $menu_cam1)
Local $launch_cam1 = GUICtrlCreateMenuItem("Connexion", $menu_cam1)
Local $menu_cam2 = GUICtrlCreateContextMenu($Obj_cam2)
Local $url_cam2 = GUICtrlCreateMenuItem("URL n°2", $menu_cam2)
Local $launch_cam2 = GUICtrlCreateMenuItem("Connexion", $menu_cam2)
Local $menu_cam3 = GUICtrlCreateContextMenu($Obj_cam3)
Local $url_cam3 = GUICtrlCreateMenuItem("URL n°3", $menu_cam3)
Local $launch_cam3 = GUICtrlCreateMenuItem("Connexion", $menu_cam3)
Local $menu_cam4 = GUICtrlCreateContextMenu($Obj_cam4)
Local $url_cam4 = GUICtrlCreateMenuItem("URL n°4", $menu_cam4)
Local $launch_cam4 = GUICtrlCreateMenuItem("Connexion", $menu_cam4)

;;; fin de l'affichage du texte
SplashOff()


GUISetState(@SW_SHOW) ; will display an empty dialog box

; Run the GUI until the dialog is closed
 While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    #Region changer les urls
    If $msg = $url_cam1 Then changeUrl($urls, 1)
    If $msg = $url_cam2 Then changeUrl($urls, 2)
    If $msg = $url_cam3 Then changeUrl($urls, 3)
    If $msg = $url_cam4 Then changeUrl($urls, 4)
    #EndRegion
    #Region Vérifier les urls
    If $msg = $launch_cam1 Then connectCam($urls, 1)
    If $msg = $launch_cam2 Then connectCam($urls, 2)
    If $msg = $launch_cam3 Then connectCam($urls, 3)
    If $msg = $launch_cam4 Then connectCam($urls, 4)
    #EndRegion
WEnd

Func changeUrl(ByRef $tableau, $numero)
    Local $url = InputBox("Changer l'url de la caméra n°"&$numero, _
        "Tapez la nouvelle URL pour la caméra n°"&$numero&@CRLF & _
        "Ancienne url:'"&$tableau[$numero]&"'", _
        $tableau[$numero] _
    )
    If @error = 0 Then $tableau[$numero] = $url
EndFunc

Func connectCam($tableau, $numero)
    MsgBox(0, "Camera n°"&$numero, "Connexion de la caméra n°"&$numero&" à l'adresse suivante:"&@CRLF&$tableau[$numero])
EndFunc

A bientôt !

EDIT: Je n'ai pas de webcam pour tester, mais le script fonctionne : tu fais un clic droit sur chaque caméra, tu vois bien l'adresse correspondante, que ce soit la n°1,2,3 ou 4. Après, si tu as un soucis, ça vient sans doute de ta config coté webcam.
Donne moi plus de détails, parce que là, ta question reste hyper floue... Et si tu veux vraiment qqchose de fonctionnel, fournis aussi le code que tu utilises ainsi que des adresses de cam à tester (sinon, comment on peut développer/débugguer? ^^).

[gasquy]

Bonjour.

Merci pour ce premier jet.

Un truc bizar, il m'est impossible d'afficher une page web sur les autres fenêtres, elle reste toujours sur la 1.

Bon Dev