[R] A quoi sert le mot de passe ?

[Wardow]

Bonjour j'ai un problème avec mon crypteur :

J'entre un texte , je ne met pas de mot de passe je clique sur crypter j'ai un résultat

J'entre le même texte , je met un mot de passe bidon je crypte j'ai le même résultat

j'entre encore une fois le même texte je met un bon mot de passe avec majuscule minuscules chiffres caractères spéciaux j'ai encore le même résultat

Donc que j’écris ce résultat , je ne met pas de mot de passe je clique sur décrypter j'ai mon texte d'origine, et ce avec nimporte quel mot de passe même un qui n'as pas servis au cryptage

pouvez vous m'aider car c'est vraiment problématique

Si vous voulez mon code le voici :

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=logoff-icone-5767.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#Include <Crypt.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <String.au3>

Global $SourceFile = ''

#Region ### START Koda GUI section ### Form=c:\users\[size=50]william.pc-de-jmi-et-pa[/size]\desktop\autoit3\scite\koda\forms\chiffreur.kxf
Global $GUI = GUICreate("Chiffreur", 820, 506, 189, 132)
GUISetBkColor(0x0066CC)
Global $EditText = GUICtrlCreateEdit("", 56, 144, 729, 217)
GUICtrlSetBkColor(-1, 0xFFFFE1)
GUICtrlSetCursor (-1, 5)
Global $EncryptButton = GUICtrlCreateButton("Crypter", 520, 48, 105, 41, $WS_GROUP)
GUICtrlSetCursor (-1, 0)
Global $DecryptButton = GUICtrlCreateButton("Décrypter", 664, 48, 105, 41, $WS_GROUP)
GUICtrlSetCursor (-1, 0)
Global $InputPass = GUICtrlCreateInput("", 280, 56, 145, 21, BitOR($ES_CENTER,$ES_PASSWORD,$ES_AUTOHSCROLL))
GUICtrlSetCursor (-1, 5)
Global $Group1 = GUICtrlCreateGroup("Mot de passe", 256, 16, 193, 97)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Group2 = GUICtrlCreateGroup("Mode", 496, 16, 297, 97)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Radio2 = GUICtrlCreateRadio("Texte", 112, 48, 65, 17)
GUICtrlSetCursor (-1, 0)
GUICtrlSetState(-1, $GUI_CHECKED)
Global $Radio1 = GUICtrlCreateRadio("Fichier", 112, 72, 65, 17)
GUICtrlSetCursor (-1, 0)
Global $Group3 = GUICtrlCreateGroup("Que voulez vous crypter ?", 64, 16, 153, 97)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $Button1 = GUICtrlCreateButton("Parcourir", 104, 408, 105, 41, $WS_GROUP)
GUICtrlSetCursor (-1, 0)
Global $Label1 = GUICtrlCreateLabel("Chemin du fichier : vide", 232, 408, 400, 300)
GUICtrlSetFont(-1, 10, 400, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###




$msg = GUIGetMsg()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
            ; si on clique sur la croix rouge sa ferme la fenetre
        Case $Radio1 ; Si on crypte un fichier

                        GUICtrlSetState($EditText,$GUI_DISABLE)
                        GUICtrlSetState($Button1,$GUI_ENABLE)
        Case $Radio2

                        GUICtrlSetState($EditText,$GUI_ENABLE)
                        GUICtrlSetState($Button1,$GUI_DISABLE)
        Case $Button1
                        $SourceFile = FileOpenDialog("Crypteur",@DesktopDir&'\',"Tous (*.*)",9)
                        GUICtrlSetData($Label1,"Chemin du fichier : " & $SourceFile)
        Case $EncryptButton

            If  GUICtrlRead($radio1) = $GUI_CHECKED Then
                If $SourceFile = '' Then
                        MsgBox(0,"Crypteur",'Veuillez selectionner un fichier')
                ElseIf $InputPass = '' Then
                        MsgBox(0,"Crypteur","veuillez entrer un mot de passe")
                ElseIf _Crypt_EncryptFile($SourceFile,$SourceFile&".crypt",GuiCtrlRead($InputPass),$CALG_RC2) Then
                        MsgBox(0,"Crypteur",'OK ! , Votre fichier a été crypté')
                EndIf
            ElseIf GUICtrlRead($radio2) = $GUI_CHECKED Then

                 $CryptData = _Crypt_EncryptData(GuiCtrlRead($EditText), $InputPass, $CALG_RC2)
                GUICtrlSetData($EditText,BinaryToString($CryptData))
            EndIf

        Case $DecryptButton
            If  GUICtrlRead($radio1) = $GUI_CHECKED Then
                If $SourceFile = '' Then
                        MsgBox(0,"Crypteur",'Veuillez selectionner un fichier')
                ElseIf StringRight($SourceFile,6) <> '.crypt' Then
                        MsgBox(0,"Crypteur",'Veuillez selectionner un fichier crypté.')
                ElseIf _Crypt_DecryptFile($SourceFile,StringLeft($SourceFile,StringLen($SourceFile)-6),GuiCtrlRead($InputPass),$CALG_RC2) Then
                        MsgBox(0,"Crypteur",'Votre fichier a été décrypté')
                Else
                        MsgBox(0,"Crypteur"," Votre fichier n'a pas pu être decrypté.")
                EndIf
            ElseIf GUICtrlRead($radio2) = $GUI_CHECKED Then
                    $CryptData = _Crypt_DecryptData(GuiCtrlRead($EditText),($InputPass),$CALG_RC2)
                    GUICtrlSetData($EditText,BinaryToString($CryptData))
            EndIf
     EndSwitch
WEnd

Je pence que sa viens de la variable du mot de passe : $InputPass

Merci d'avoir lu et de m'aider

[bloodwolff]

$CryptData = _Crypt_EncryptData(GuiCtrlRead($EditText), $InputPass, $CALG_RC2)

Remplace cette ligne par

$CryptData = _Crypt_EncryptData(GuiCtrlRead($EditText), GuiCtrlRead($InputPass), $CALG_RC2)

[Wardow]

Merci je viens de le voir en cherchant un peut et je suis tomber sur votre réponse juste après désolé de vous avoir déranger