[R] TCP qui ne fonctionne que dans un sens

[RL77LUC]

Bonjour à tous !

Désolé de vous importuner avec mes problèmes, mais je débute en TCP et là, je dois dire que je coince :/. En fait, je réalise une application pour mon serveur, qui me permettra de l'administrer facilement à distance depuis mon PC. Le système pour transmettre des commandes au serveur fonctionne, grâce à un exemple de script que j'ai modifié à ma guise. Seulement, quand j'essaie d'envoyer des infos via TCP depuis le serveur sur le client, eh bien rien du tout, aucune réponse ...

Voici mes codes :

Client

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("IntraServeur CLIENT", 390, 222, 192, 124)
Global $Group1 = GUICtrlCreateGroup("Contrôle machine", 8, 8, 161, 89)
Global $Button1 = GUICtrlCreateButton("Extinction", 24, 32, 129, 25, $WS_GROUP)
Global $Button2 = GUICtrlCreateButton("Redémarrage", 24, 64, 129, 25, $WS_GROUP)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global Const $maxClients = 10
Global $__Sockets[$maxClients]
Local $ipserveur = @IPAddress1
Local $PORT = 8080
TCPStartup()
$ConnectedSocket = -1
$ConnectedSocket = TCPConnect($ipserveur, $PORT)
If @error Then
    MsgBox(16,"Erreur","Impossible de se connecter au serveur distant !")
    Exit
EndIf
$__MainSocket = TCPListen($ipserveur, 8090) ; Creating server
If @error Then Exit MsgBox(16, "Erreur", "Impossible de créer un socket d'écoute (" & @error & " - " & @extended & ")")

AdLibRegister("ReplyFromServ",10)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            TCPSend($ConnectedSocket,"shutdown")

        Case $Button2
            TCPSend($ConnectedSocket,"reboot")

 EndSwitch
WEnd

Func ReplyFromServ()
    $iNewSocket = TCPAccept($__MainSocket)
        If $iNewSocket <> -1 Then
        ; try to stor the connected socket in the sockets array
        For $i = 0 To $maxClients - 1
            If $__Sockets[$i] = -1 Then
                $__Sockets[$i] = $iNewSocket

                ExitLoop ; New connection stored, exiting loop
            EndIf
        Next
    EndIf

    For $i = 0 To $maxClients - 1
        $sRecv = TCPRecv($__Sockets[$i], 1024)

        ; Invalid socket (either client disconnect, or already invalid)
        If @error Then
            ; If it was previously connected (a valide socket)
            If $__Sockets[$i] <> -1 Then

            EndIf
            $__Sockets[$i] = -1 ; Reset the array's element to -1
            ContinueLoop
        EndIf

        ; If data received
        If $sRecv Then
            MsgBox(64,"Réponse du serveur",$sRecv)
        EndIf
    Next
EndFunc
 

Serveur

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=Serveur.exe
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("IntraServeur SERVEUR", 274, 107, @DesktopWidth-280, 5,BitOR($WS_CLIPSIBLINGS, $WS_Border),$WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
Global $Label1 = GUICtrlCreateLabel("IntraServeur SERVEUR - Lancé.", 8, 30, 260, 81, $SS_CENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


Global Const $maxClients = 10
Global $__Sockets[$maxClients] ; Array of connected sockets
Global $__IP = @IPAddress1, $__PORT = 8080
Global $__MainSocket, $iNewSocket, $sRecv
Global $ConnectedSocket

$p = PluginOpen("extendcmd.dll")

For $i = 0 To $maxClients - 1 ; Init the array (-1 => Invalid socket)
    $__Sockets[$i] = -1
Next

TCPStartup()
Local $ipserveur = @IPAddress1
Local $PORT = 8090
; ---

$__MainSocket = TCPListen($__IP, $__PORT) ; Creating server
If @error Then Exit MsgBox(16, "Erreur", "Impossible de créer un socket d'écoute (" & @error & " - " & @extended & ")")
setconsolecolor(10)
ConsoleWrite("+> Serveur cr‚‚ : " & $__IP & ":" & $__PORT & @CRLF)
WinSetTitle(@ScriptFullPath,"","IntraServeur CONSOLE SERVEUR [" & $__IP & ":" & $__PORT & "]")
; ---

HotKeySet("+{esc}", "_terminate")
Global $terminate = 0
While Not $terminate
    ; Try to catch a connection
    $iNewSocket = TCPAccept($__MainSocket)

    ; If new connection
    If $iNewSocket <> -1 Then
        ; try to stor the connected socket in the sockets array
        For $i = 0 To $maxClients - 1
            If $__Sockets[$i] = -1 Then
                $__Sockets[$i] = $iNewSocket
                _TCP_NewClientFunc($iNewSocket) ; Triger the new client function
                ExitLoop ; New connection stored, exiting loop
            EndIf
        Next
    EndIf

    For $i = 0 To $maxClients - 1
        $sRecv = TCPRecv($__Sockets[$i], 1024)

        ; Invalid socket (either client disconnect, or already invalid)
        If @error Then
            ; If it was previously connected (a valide socket)
            If $__Sockets[$i] <> -1 Then
                _TCP_ClientDisconnectFunc($__Sockets[$i]) ; Triger client disconnect function
            EndIf
            $__Sockets[$i] = -1 ; Reset the array's element to -1
            ContinueLoop
        EndIf

        ; If data received
        If $sRecv Then
            _TCP_ReceiveFunc($__Sockets[$i], $sRecv)
        EndIf
    Next
Wend

; ---
; Trigered when new client connects
Func _TCP_NewClientFunc($hSocket)
    setconsolecolor(11)
    ConsoleWrite(">>> Nouveau client : " & _SocketToIP($hSocket) & @CRLF)
    $ConnectedSocket = -1
    $ConnectedSocket = TCPConnect($ipserveur, $PORT)
    If @error Then
        MsgBox(16,"Erreur","Impossible de se connecter au client !")
    EndIf
    TCPSend($ConnectedSocket,"Serveur connecté au client !")
EndFunc

; Trigered when some data received
Func _TCP_ReceiveFunc($hSocket, $sData)
    If _IPAuth($hSocket) Then
        If ($sData = "reboot") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Red‚marrage" & @CRLF)
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Redémarrage" & @CRLF)
            TCPSend($ConnectedSocket,"Commande de redémarrage exécutée avec succès !")
        EndIf
        If ($sData = "shutdown") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Extinction" & @CRLF)
            TCPSend($ConnectedSocket,"Commande d'extinction exécutée avec succès !")
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Extinction" & @CRLF)
        EndIf
        If (StringLeft($sData,4) = "au3:") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande Autoit : "& StringMid($sData,5) & @CRLF)
            Execute(StringMid($sData,5))
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande Autoit : "& StringMid($sData,5) & @CRLF)
        EndIf
        If (StringLeft($sData,4) = "dos:") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande DOS : "& StringMid($sData,5) & @CRLF)
            Run(StringMid($sData,5))
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande DOS : "& StringMid($sData,5) & @CRLF)
        EndIf
    Else
        setconsolecolor(12)
        ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande bloqu‚e. IP non autoris‚e." & @CRLF)
        TCPSend($ConnectedSocket,"Commande non exécutée. IP non autorisée.")
        FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande bloquée. IP non autorisée." & @CRLF)
    EndIf
EndFunc

; Trigered when client disconnects
Func _TCP_ClientDisconnectFunc($hSocket)
    setconsolecolor(11)
    ConsoleWrite(">>> Client d‚connect‚ : " & _SocketToIP($hSocket) & @CRLF)
EndFunc

; ---
TCPShutdown()

; ---
; Used to send data to all connected (valid) sockets
; NB: $iExeptionSocket used for example to not re-send data for the sender
;       in a chat program for example
Func _TCP_Broadcast($sData, $iExeptionSocket = -1)
    For $i = 0 To $maxClients - 1
        If $__Sockets[$i] <> -1 And $__Sockets[$i] <> $iExeptionSocket Then
            TCPSend($__Sockets[$i], $sData)
        EndIf
    Next
EndFunc

Func _terminate()
;~  If MsgBox(36, "Confirmation", "Quit?") = 7 Then Return
    $terminate = 1
EndFunc

Func _SocketToIP($SHOCKET)
    Local $sockaddr, $aRet

    $sockaddr = DllStructCreate("short;ushort;uint;char[8]")

    $aRet = DllCall("Ws2_32.dll", "int", "getpeername", "int", $SHOCKET, _
            "ptr", DllStructGetPtr($sockaddr), "int*", DllStructGetSize($sockaddr))

    If Not @error And $aRet[0] = 0 Then
        $aRet = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", DllStructGetData($sockaddr, 3))
        If Not @error Then $aRet = $aRet[0]
    Else
        $aRet = 0
    EndIf

    $sockaddr = 0

    Return $aRet
EndFunc   ;==>SocketToIP

Func _ResolutionIP($ip)
    $ippure = _SocketToIP($ip)
    $name = INIRead("clients_res.ini","Names",$ippure,"")
    If $name <> "" Then
        Return $name
    Else
        Return $ippure
    EndIf
EndFunc

Func _IPAuth($ip)
    $ippure = _SocketToIP($ip)
    $name = INIRead("clients_auth.ini","Names",$ippure,"")
    If $name == "Allow" Then
        Return True
    Else
        Return False
    EndIf
EndFunc

PluginClose($p)

Archive complète : Archive Client + Serveur + Config et couleur

Voilà. Merci d'avance pour votre aide.

[Strofe]

Bonjour

As-tu pensé au Pare Feu ??

[RL77LUC]

Oui, tout est au point niveau pare-feu . Et pour l'instant tout tourne sur la même machine ...

Autres idées ? ^^

[ZDS]

Bonjour,

Avant de pouvoir tester ton code, peux tu envoyer une version "correcte" en premier lieu? Juste les erreurs de syntaxe, c'est la moindre des choses, non? ^^ Désolé un peu flemmard de corriger des trucs comme :

Code : Tout sélectionner

Func _TCP_NewClientFunc($hSocket)
    ConsoleWrite(">>> Nouveau client : " & _SocketToIP($hSocket) & @CRLF)
[color=#FF0000]EndIf[/color]
EndFunc

A bientôt.

PS: Sinon tu as pensé à initialiser la connexion avant de faire une tentative de TCPConnect ? Notamment au niveau du serveur :

Code : Tout sélectionner

[...]
; ---

HotKeySet("+{esc}", "_terminate")
[color=#FF0000]Global $terminate = 0, $ok = False
$ConnectedSocket = -1
While $ok = False
    $ConnectedSocket = TCPConnect($ipserveur, $PORT)
    If Not @error Then $ok = True
WEnd[/color]

While Not $terminate
[...]

[RL77LUC]

Désolé, j'avais envoyé une ancienne version et oublié de mettre à jour. J'ai fait comme ça, dans la fonction de nouveau client, mais ça ne fonctionne pas plus :/.

[ZDS]

Bonjour,

Il y a un modèle client/serveur dans les exemples avancés d'AutoIt (attends que je le retrouve), justement conçu pour transmettre des commandes. C'est là dessus que tu t'es basé ou pas du tout? Si ce n'est pas le cas, je te le conseille, il est très bien construit.

A plus tard.

[RL77LUC]

Je me suis basé sur le serveur TCP Multi-Clients, je ne sais pas si c'est de celui-là que tu parles.

EDIT: Personne ne voit ce qui cloche ? :S

[ZDS]

Bonjour,

Je n'ai pas trop le temps de me pencher sur ce script dans la semaine (boulot oblige), par contre dès ce soir ou demain je vais regarder ça en détail. D'ici là peut-être que quelqu'un t'aura aidé, tiens moi au courant.

A bientôt!

[RL77LUC]

Merci beaucoup pour tout !

[timmalos]

Merci de rajouter la balise Résolu à votre sujet.

[ZDS]

Bonjour,

@timmalos: Je pense que son problème n'est pas résolu. Le dernier message de RL77LUC est peut-être un merci par avance.

@RL77LUC: J'ai bossé un peu sur ton script, et mise à part des modifications mineures coté serveur (aucune modif coté client), je n'ai rien eu à faire pour faire fonctionner ton script : J'ai bien un retour coté client "Réponse du serveur". Par contre, pour m'éviter de créer des fichiers à tire-larigot, j'ai shunté ta fonction _IPAuth($ip) qui retourne toujours vrai dans mon script (toute machine autorisée). La grosse flemme de faire des fichiers de config surtout quand tu donnes aucune spèc ^^

Bref, j'ai bien fait d'être fainéant, car dans le cas d'une machine authentifiée ça fonctionne nickel; et par contre dans le cas d'une machine répondant False à la fonction _IPAuth, je n'ai même pas de réponse de blocage. Donc le problème se situe là.

Désolé de ne pas être d'une plus grande aide pour le moment, je t'envoye ma version un peu remaniée du serveur (shuntage de _IPAuth, sortie en console des valeurs de retour de TCPSend, etc...). Mais ça serait bien de fournir dans une archive en pj de ton premier message (pour cette fois et les prochaines) TOUS LES FICHIERS NÉCESSAIRES pour qu'on puisse t'apporter de l'aide :
- Script serveur => FONCTIONNEL ! (genre setconsolecolor qui manque, comment veux-tu qu'on avance si il y a des trous...)
- Script client
- Exemple de fichier clients_res.ini
- Exemple de fichier clients_auth.ini
- Exemple de fichier log.txt
- etc...

► Afficher le texteServeur

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=Serveur.exe
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("IntraServeur SERVEUR", 274, 107, @DesktopWidth-280, 5,BitOR($WS_CLIPSIBLINGS, $WS_Border),$WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
Global $Label1 = GUICtrlCreateLabel("IntraServeur SERVEUR - Lancé.", 8, 30, 260, 81, $SS_CENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


Global Const $maxClients = 10
Global $__Sockets[$maxClients] ; Array of connected sockets
Global $__IP = @IPAddress1, $__PORT = 8080
Global $__MainSocket, $iNewSocket, $sRecv
Global $ConnectedSocket

$p = PluginOpen("extendcmd.dll")

For $i = 0 To $maxClients - 1 ; Init the array (-1 => Invalid socket)
    $__Sockets[$i] = -1
Next

TCPStartup()
Local $ipserveur = @IPAddress1
Local $PORT = 8090
; ---

$__MainSocket = TCPListen($__IP, $__PORT) ; Creating server
If @error Then Exit MsgBox(16, "Erreur", "Impossible de créer un socket d'écoute (" & @error & " - " & @extended & ")")
setconsolecolor(10)
ConsoleWrite("+> Serveur cr‚‚ : " & $__IP & ":" & $__PORT & @CRLF)
WinSetTitle(@ScriptFullPath,"","IntraServeur CONSOLE SERVEUR [" & $__IP & ":" & $__PORT & "]")
; ---

HotKeySet("+{esc}", "_terminate")
Global $terminate = 0
While Not $terminate
    ; Try to catch a connection
    $iNewSocket = TCPAccept($__MainSocket)

    ; If new connection
    If $iNewSocket <> -1 Then
        ; try to stor the connected socket in the sockets array
        For $i = 0 To $maxClients - 1
            If $__Sockets[$i] = -1 Then
                $__Sockets[$i] = $iNewSocket
                _TCP_NewClientFunc($iNewSocket) ; Triger the new client function
                ExitLoop ; New connection stored, exiting loop
            EndIf
        Next
    EndIf

    For $i = 0 To $maxClients - 1
        $sRecv = TCPRecv($__Sockets[$i], 1024)

        ; Invalid socket (either client disconnect, or already invalid)
        If @error Then
            ; If it was previously connected (a valide socket)
            If $__Sockets[$i] <> -1 Then
                _TCP_ClientDisconnectFunc($__Sockets[$i]) ; Triger client disconnect function
            EndIf
            $__Sockets[$i] = -1 ; Reset the array's element to -1
            ContinueLoop
        EndIf

        ; If data received
        If $sRecv Then
            _TCP_ReceiveFunc($__Sockets[$i], $sRecv)
        EndIf
    Next
Wend

; ---
; Trigered when new client connects
Func _TCP_NewClientFunc($hSocket)
    setconsolecolor(11)
    ConsoleWrite(">>> Nouveau client : " & _SocketToIP($hSocket) & @CRLF)
    $ConnectedSocket = -1
    $ConnectedSocket = TCPConnect($ipserveur, $PORT)
    If @error Then
        MsgBox(16,"Erreur","Impossible de se connecter au client !")
    EndIf
    TCPSend($ConnectedSocket,"Serveur connecté au client !")
EndFunc

; Trigered when some data received
Func _TCP_ReceiveFunc($hSocket, $sData)
    ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] : " & $sData & "" & @CRLF)
    If _IPAuth($hSocket) Then
        If ($sData = "reboot") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Red‚marrage" & @CRLF)
            ConsoleWrite(">>> Code de retour : '" & TCPSend($ConnectedSocket,"Commande de redémarrage exécutée avec succès !") & "'" & @CRLF)
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Redémarrage" & @CRLF)
        EndIf
        If ($sData = "shutdown") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Extinction" & @CRLF)
            ConsoleWrite(">>> Code de retour : '" & TCPSend($ConnectedSocket,"Commande d'extinction exécutée avec succès !") & "'" & @CRLF)
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande machine : Extinction" & @CRLF)
        EndIf
        If (StringLeft($sData,4) = "au3:") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande Autoit : "& StringMid($sData,5) & @CRLF)
            ConsoleWrite(">>> Code de retour : '" & Execute(StringMid($sData,5)) & "'" & @CRLF)
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande Autoit : "& StringMid($sData,5) & @CRLF)
        EndIf
        If (StringLeft($sData,4) = "dos:") Then
            setconsolecolor(7)
            ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande DOS : "& StringMid($sData,5) & @CRLF)
            ConsoleWrite(">>> Code de retour : '" & Run(StringMid($sData,5)) & "'" & @CRLF)
            FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande DOS : "& StringMid($sData,5) & @CRLF)
        EndIf
    Else
        setconsolecolor(12)
        ConsoleWrite(">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande bloqu‚e. IP non autoris‚e." & @CRLF)
        ConsoleWrite(">>> Code de retour : '" & TCPSend($ConnectedSocket,"Commande non exécutée. IP non autorisée.") & "'" & @CRLF)
        FileWriteLine("log.txt",">>> [" & @MDAY & "/" & @MON & " " & @HOUR & "h" & @MIN & "m" & @SEC & "s] [" & _ResolutionIP($hSocket) & "] Commande bloquée. IP non autorisée." & @CRLF)
    EndIf
EndFunc

; Trigered when client disconnects
Func _TCP_ClientDisconnectFunc($hSocket)
    setconsolecolor(11)
    ConsoleWrite(">>> Client d‚connect‚ : " & _SocketToIP($hSocket) & @CRLF)
EndFunc

; ---
TCPShutdown()

; ---
; Used to send data to all connected (valid) sockets
; NB: $iExeptionSocket used for example to not re-send data for the sender
;       in a chat program for example
Func _TCP_Broadcast($sData, $iExeptionSocket = -1)
    For $i = 0 To $maxClients - 1
        If $__Sockets[$i] <> -1 And $__Sockets[$i] <> $iExeptionSocket Then
            TCPSend($__Sockets[$i], $sData)
        EndIf
    Next
EndFunc

Func _terminate()
;~  If MsgBox(36, "Confirmation", "Quit?") = 7 Then Return
    $terminate = 1
EndFunc

Func _SocketToIP($SHOCKET)
    Local $sockaddr, $aRet

    $sockaddr = DllStructCreate("short;ushort;uint;char[8]")

    $aRet = DllCall("Ws2_32.dll", "int", "getpeername", "int", $SHOCKET, _
            "ptr", DllStructGetPtr($sockaddr), "int*", DllStructGetSize($sockaddr))

    If Not @error And $aRet[0] = 0 Then
        $aRet = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", DllStructGetData($sockaddr, 3))
        If Not @error Then $aRet = $aRet[0]
    Else
        $aRet = 0
    EndIf

    $sockaddr = 0

    Return $aRet
EndFunc   ;==>SocketToIP

Func _ResolutionIP($ip)
    $ippure = _SocketToIP($ip)
    $name = INIRead("clients_res.ini","Names",$ippure,"")
    If $name <> "" Then
        Return $name
    Else
        Return $ippure
    EndIf
EndFunc

Func _IPAuth($ip)
    Return True
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    $ippure = _SocketToIP($ip)
    $name = INIRead("clients_auth.ini","Names",$ippure,"")
    If $name == "Allow" Then
        Return True
    Else
        Return False
    EndIf
EndFunc

Func setconsolecolor($val)
    ; ???
EndFunc

PluginClose($p)

A bientôt !

[RL77LUC]

Et pourquoi ça ? Ce n'est pas résolu ...

EDIT: Merci ZDS, je mets tout dans une archive et j'édite le premier topic .
EDIT 2: Lien ajouté au 1e topic.

Petites précisions : setcolor est déclaré comme manquant, mais est bien présent, c'est parce que la fonction est dans la DLL que ça fait ça, et il faut impérativement compiler le script pour que tout fonctionne bien.

J'ai mis à jour l'archive, mais mon problème subsiste, le message de refus de connexion ne s'affiche pas à tous les coups, environ 1 fois sur 10. D'autres idées ?

[timmalos]

Désolé pour mon message précédant, j'ai en effet pris votre 'Merci pour tout' comme une marque de résolution

[RL77LUC]

Ce n'est pas grave, l'erreur est humaine .

[Iste]

Mais ya un truc qui me chagrine depuis le debut, pourquoi le server se connecte au client ?

Utilisez la socket ouverte par le client si vous avez besoin de renvoyer des informations.

[RL77LUC]

Ah oui mais ça dépasse mes compétence x). J'ai adapté l'exemple TCP multi-clients étant donné que je suis loin d'être un expert dans ce domaine ^^'.

[Iste]

Bah c'est bien plus simple ainsi justement ! une fois la socket ouverte par le client on la recup pour travailler, au lieu d'en ouvrir une autre

[RL77LUC]

Vous n'auriez pas un exemple ? Parce que très franchement, je n'ai aucune idée de comment procéder ... :/

[Iste]

Ouais ouais... voila...

► Afficher le texteclient

Code : Tout sélectionner

Global $ConnectedSocket

Example()

Func Example()
    Local $szData
    Local $szIPADDRESS = @IPAddress1
    Local $nPORT = 33891

    TCPStartup()

    $ConnectedSocket = -1

    $ConnectedSocket = TCPConnect($szIPADDRESS, $nPORT)

    If @error Then
        MsgBox(4112, "Error", "TCPConnect failed with WSA error: " & @error)
    Else

        [color=#FF0000]AdlibRegister('recv')[/color]


        While 1
            $szData = InputBox("Data for Server", @LF & @LF & "Enter data to transmit to the SERVER:")
            If @error Or $szData = "" Then ExitLoop
            TCPSend($ConnectedSocket, $szData)
            If @error Then ExitLoop
        WEnd
    EndIf
EndFunc   ;==>Example

[color=#FF0000]Func recv()
    $total = ''
    While 1
        $var = TCPRecv($ConnectedSocket, 1000)
        $total &= $var
        If $var = '' Then ExitLoop
    WEnd

    If $total <> '' Then MsgBox('','','Server say : ' & $total)
EndFunc[/color]

 

► Afficher le texteserver

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

;==============================================
;==============================================
;SERVER!! Start Me First !!!!!!!!!!!!!!!
;==============================================
;==============================================

Example()

Func Example()
    Local $szIPADDRESS = @IPAddress1
    Local $nPORT = 33891
    Local $MainSocket, $GOOEY, $edit, $ConnectedSocket, $szIP_Accepted
    Local $msg, $recv

    TCPStartup()

    $MainSocket = TCPListen($szIPADDRESS, $nPORT)

    If $MainSocket = -1 Then Exit

    $GOOEY = GUICreate("My Server (IP: " & $szIPADDRESS & ")", 300, 200)
    $edit = GUICtrlCreateEdit("", 10, 10, 280, 180)
    GUISetState()

    $ConnectedSocket = -1

    Do
        $ConnectedSocket = TCPAccept($MainSocket)
    Until $ConnectedSocket <> -1

    $szIP_Accepted = SocketToIP($ConnectedSocket)

    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop

        $recv = TCPRecv($ConnectedSocket, 2048)

        If @error Then ExitLoop

        If $recv <> "" Then GUICtrlSetData($edit, _
                $szIP_Accepted & " > " & $recv & @CRLF & GUICtrlRead($edit))

        [color=#FF0000]If $recv = 'test' Then TCPSend($ConnectedSocket, 'test ok')[/color]
    WEnd


    If $ConnectedSocket <> -1 Then TCPCloseSocket($ConnectedSocket)

    TCPShutdown()
EndFunc   ;==>Example

; Function to return IP Address from a connected socket.
;----------------------------------------------------------------------
Func SocketToIP($SHOCKET)
    Local $sockaddr, $aRet

    $sockaddr = DllStructCreate("short;ushort;uint;char[8]")

    $aRet = DllCall("Ws2_32.dll", "int", "getpeername", "int", $SHOCKET, _
            "ptr", DllStructGetPtr($sockaddr), "int*", DllStructGetSize($sockaddr))
    If Not @error And $aRet[0] = 0 Then
        $aRet = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", DllStructGetData($sockaddr, 3))
        If Not @error Then $aRet = $aRet[0]
    Else
        $aRet = 0
    EndIf

    $sockaddr = 0

    Return $aRet
EndFunc   ;==>SocketToIP
 

J'ai repris l'exemple de la doc et j'ai rajouté deux choses :
Une fonction en boucle chez le client qui écoute la socket ouverte (ca bug un peu car l'inputbox stop le script)
Une condition au server pour répondre quand il reçoit "test"

[RL77LUC]

J'ai adapté mon script, et ça fonctionne parfaitement bien ! ! Merci beaucoup, beaucoup à ZDS et Iste ! Je passe en résolu ...