[..] Ecrire sur un bloc-note non actif

[Utilisateur 3643 supprimé]

Bonjour tout le monde je voudrait faire un scriptqui me permetrait par exemple d'écrire des choses sur un bloc note ou autre sans avoir besoin d'être sur le bloc note par exemple: je voudrait qu'il écrive "bonjour" pendant que moi je suis sur internet.
Et (je n'est pas tout à fait fini ...) si il y a plusieurs bloc note je voudrait que l'on choisisse UN bloc-note en particulier à l'aide d'un combo (les sortes d'input avec un fleche qui dessend sur le côté )
Merci d'avance pour vos réponse =D
ps je vous demande pour le bloc-note mais j'espère que c'et compatible pour toute autre sortes de chose

[matwachich]

Ton bonheur se trouve dans l'aide: Section Using AutoIt
Regarde en particulier
- AutoIt Window Info Tool (AU3Info)
- Window Titles and Text (Advanced)
- Controls

[Utilisateur 3643 supprimé]

je vais regarder merci mais au cas où je ne trouve pas (juste au cas où) tu peux me dire comment faire

[jchd]

Oui : l'aide c'est F1.

[Utilisateur 3643 supprimé]

Oui je sais que c'est F1 l'aide mais je trouve pas la solution à mon problème désolé et encore moins pour la solution du combo ...

[Strofe]

Bonjour

Bon je sais, ils vont encore me tirer les oreilles.. .. mais cela me permet de découvrir des fonctions...

PS : l'aide est très bien faite

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Process.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Tout est dans l'aide Autoit -- Encore faut-il l'ouvrir", 491, 156, 192, 124)
$Combo1 = GUICtrlCreateCombo("", 16, 16, 145, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL,$CBS_SORT))
$LstNotePad = LstBlocNote()
If $LstNotePad="" Then
        MsgBox(0,"","Merci d'ouvrir au moins un bloc note....")
        Exit
    Else
        GUICtrlSetData($Combo1, $LstNotePad, "")                
EndIf
$Input1 = GUICtrlCreateInput("", 16, 72, 241, 21)
$Btn1 = GUICtrlCreateButton("Écrit", 184, 112, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Btn1
            ControlSend(GUICtrlRead($Combo1), "", "Edit1", GUICtrlRead($Input1) & @CR)
    EndSwitch
WEnd

Func LstBlocNote()
    $var = WinList()
    $BlocNote=""
    For $i = 1 to $var[0][0]
        If StringInStr($var[$i][0],"Bloc-notes") <> 0 Then
            If $BlocNote <> "" Then 
                    $BlocNote &= "|" & $var[$i][0]      
                Else    
                    $BlocNote &= $var[$i][0] 
            EndIf       
        EndIf
    Next
    Return $BlocNote
EndFunc 
 

[matwachich]

Oui : l'aide c'est F1.

MDR!

En tout cas, j'allai donner une solution mais j'ai été devancé!