[R] Outils à installer sur les PC --> Script Installation

[Strofe]

Bonjour

Clos pas le posteur par manque d'intérêt.
Je fait mes débuts en tant qu'administrateur d'un réseau d'entreprise et je souhaite faire un script pour installer des mises à jours sur les machines des utilisateurs.

Voici le début

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
titre = "Installation"
; ------------------------------------------------------------------------------------------------
If WinExists ($titre) Then Quitter()
AutoItWinSetTitle ($titre)
HotKeySet("^!{F10}", "Quitter")
; ------------------------------------------------------------------------------------------------
Dim $message = ""

$Form1 = GUICreate("Société -- Installation ou mise à jour des programmes", 623, 442, ( @DesktopWidth-623)/2 , ( @DesktopHeight-442)/2,0 , BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
$Label1 = GUICtrlCreateLabel("", 8, 16, 604, 417)
GUISetState(@SW_SHOW)

PdfCreator()

Sleep(5000)
Quitter()

; ------------------------------------------------------------------------------------------------
Func PdfCreator() ;PDF Creator V1.2.1
    If RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\PDFCreator\Program", "ApplicationVersion") <> "1.2.1" Then
            $message &= "Mise à jour de PDF Creator en version 1.2.1" & @CRLF
            GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
            DirCreate("C:\temp\pdfcreator")
            FileInstall( @ScriptDir & "\PDFCreator-1_2_1_setup.exe","C:\temp\pdfcreator\PDFCreator-1_2_1_setup.exe")
            FileInstall( @ScriptDir & "\PDFCreator.inf","C:\temp\pdfcreator\PDFCreator.inf")

            Local $sUserName = "Administrateur"
            Local $sPassword = "[color=#BF4000]mot de passe[/color]"

            Local $pid = RunAsWait($sUserName, "[color=#BF4000]domaine[/color]", $sPassword, 0, 'C:\temp\pdfcreator\PDFCreator-1_2_1_setup.exe /LOADINF="C:\temp\pdfcreator\PDFCreator.inf" /VERYSILENT /FORCEINSTALL')

            ; Wait for the process to close.
            ProcessWaitClose($pid)

            if FileExists ("C:\temp\pdfcreator") then 
                DirRemove("C:\temp\pdfcreator", 1)
                Beep(300, 50)
                Beep(400, 50)
                Beep(500, 50)
                Beep(400, 50)
                Beep(500, 50)
            EndIf
            $message &= "PDF Creator est maintenant en version 1.2.1" & @CRLF
            GUICtrlSetData ($Label1,$message & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
        Else
            $message &= "PDF Creator est déjà en version 1.2.1" & @CRLF 
            GUICtrlSetData ($Label1,$message & @CRLF & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
    EndIf
EndFunc ; ==> PdfCreator
; ------------------------------------------------------------------------------------------------
Func Quitter()
    Exit
EndFunc ; ==> Quitter
; ------------------------------------------------------------------------------------------------
 

Quels sont les autres programmes gratuits et indispensables que je devrai mettre à jour et installer ??

Merci de votre contribution

Christophe

[Tlem]

Quels sont les autres programmes gratuits et indispensables que je devrai mettre à jour et installer ??

Je sent que ce sujet va finir par troller un maximum.

[Strofe]

Bonjour

Je viens de refaire mon code, j'ai un peu honte de la première version. (J'assume je la laisse présente sur le forum)

Voici une version plus légère et évolutive selon moi.

► Afficher le texte

Code : Tout sélectionner

; ------------------------------------------------------------------------------------------------
; 1 : Intégration des chemins UNC et préparation du script pour les autres installations 
; 2 : Ajout d'un fichier log sur le serveur --> Date, nom de la machine, nom de l'utilisateur, programmes installés 
; ------------------------------------------------------------------------------------------------

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; ------------------------------------------------------------------------------------------------
$titre = "Install"
If WinExists ($titre) Then Quitter()
AutoItWinSetTitle ($titre)
HotKeySet("^!{F10}", "Quitter") ;Ctrl + Alt + F10

Global $message = ""
Global $sUserName = "Administrateur"
Global $sPassword = "[color=#804000]mot de passe[/color]"
Global $domaine = "[color=#804000]domaine[/color]"
Global $UNC = "\\Win-eye92sdepke\data"
Global $PrgInst = ""    ; Programmes installés
; ------------------------------------------------------------------------------------------------
Global $Form1 = GUICreate("Société -- Installation ou mise à jour des programmes", 623, 442, ( @DesktopWidth-623)/2 , ( @DesktopHeight-442)/2,0 , BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
Global $Label1 = GUICtrlCreateLabel("", 8, 16, 604, 417)

GUISetState(@SW_SHOW)

; ------------------------------------------------------------------------------------------------
; Lancement des installations
;   @OSversion  :   "WIN_2008R2", "WIN_7", "WIN_2008", "WIN_VISTA", "WIN_2003", "WIN_XP", "WIN_XPe", "WIN_2000".
;   @OSArch     :   "X86", "IA64", "X64"
; ------------------------------------------------------------------------------------------------

PdfCreator()

; ------------------------------------------------------------------------------------------------
; Fin des mises à jour
; ------------------------------------------------------------------------------------------------

Sleep(5000)
Quitter()

; ------------------------------------------------------------------------------------------------
; Functions d'installations
; ------------------------------------------------------------------------------------------------
Func PdfCreator() ;PDF Creator V1.2.1
    ; http://wiki.ocsinventory-ng.org/index.php/Admin_center:Deploiement_PDFCreator
    If RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\PDFCreator\Program", "ApplicationVersion") <> "1.2.1" Then
            $message &= "PDF Creator version 1.2.1 --> Mise à jour" & @CRLF
            GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
            
            ;~ Désisntallation de l'ancienne version
            RunAsWait($sUserName, $domaine, $sPassword, 0, @comspec & ' /c "C:\Program Files\PDFCreator\unins000.exe" /verysilent', @WorkingDir, @SW_HIDE)
            ;~ Installation de la nouvelle version
            RunAsWait($sUserName, $domaine, $sPassword, 0, $UNC & '\PdfCreator\PDFCreator-1_2_1_setup.exe /LOADINF="' & $UNC & '\PdfCreator\PDFCreator.inf" /VERYSILENT /FORCEINSTALL', @ScriptDir, @SW_HIDE )
            ;~ Ajout de la clé de registre UpdateInterval à 0 pour interdire la mise à jour automatique
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\PDFCreator\Program","UpdateInterval","REG_SZ","0")

            $message &= "PDF Creator version 1.2.1 --> Installé" & @CRLF
            GUICtrlSetData ($Label1,$message & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
            $PrgInst &= "PDFCreator 1.2.1, "
        Else
            $message &= "PDF Creator version 1.2.1 --> Déjà Installé" & @CRLF 
            GUICtrlSetData ($Label1,$message & @CRLF & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
    EndIf
EndFunc ; ==> PdfCreator
; ------------------------------------------------------------------------------------------------
Func Quitter()
;~  Sauve Log
    $file = FileOpen($UNC & "\install.log", 1 + 8 )
    If $file<> -1 Then
        ; Ajoute la chaine
        FileWriteLine($file, @YEAR & "-" & @MON & "-" & @MDAY & "; " & @ComputerName & "; " & @UserName & "; (" & $PrgInst & ")" & @CRLF)
        FileClose($file)
    EndIf
    Exit
EndFunc ; ==> Quitter
; ------------------------------------------------------------------------------------------------
 

Si vous avez des remarques, je suis preneur

Bonne journée

[Strofe]

Bonsoir

Bonne nouvelle, j'ai déployé mon premier script en production.

Voici les correctifs apportés à cause de seven 64Bit. Grrr faut réapprendre à travaiiler.

► Afficher le texte

Code : Tout sélectionner

; ------------------------------------------------------------------------------------------------
; 1 : Intégration des chemins UNC et préparation du script pour les autres installations 
; 2 : Ajout d'un fichier log sur le serveur --> Date, nom de la machine, nom de l'utilisateur, programmes installés 
; ------------------------------------------------------------------------------------------------
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; ------------------------------------------------------------------------------------------------
Dim $titre = "Installation"
Global $message = ""
Global $sUserName = "Administrateur"
Global $sPassword = "mot de passe "
Global $domaine = "domaine"
Global $UNC = "\\chemin\script"
Global $PrgInst = ""    ; Programmes installés
Global $Form1 = GUICreate("Installation ou mise à jour des programmes", 623, 442, ( @DesktopWidth-623)/2 , ( @DesktopHeight-442)/2,0 , BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
Global $Label1 = GUICtrlCreateLabel("", 8, 16, 604, 417)
; ------------------------------------------------------------------------------------------------
If WinExists ($titre) Then Quitter()
AutoItWinSetTitle ($titre)
HotKeySet("^!{F10}", "Quitter") ;Ctrl + Alt + F10
GUISetState(@SW_SHOW)
; ------------------------------------------------------------------------------------------------
; Lancement des installations
;   @OSversion  :   "WIN_2008R2", "WIN_7", "WIN_2008", "WIN_VISTA", "WIN_2003", "WIN_XP", "WIN_XPe", "WIN_2000".
;   @OSArch     :   "X86", "IA64", "X64"
If @OSArch = "X64" Then
        $HKML = "HKLM64"
    Else
        $HKML = "HKLM"
EndIf 

; ------------------------------------------------------------------------------------------------
CCleaner()
PdfCreator()
$message &= @CRLF & "Demain mise à jour de ??? je ne sais pas encore..." & @CRLF & "Bonne journée"
GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
; ------------------------------------------------------------------------------------------------
; Fin des mises à jour
; ------------------------------------------------------------------------------------------------
Sleep(5000)
Quitter()
; ------------------------------------------------------------------------------------------------
; Fonctions d'installations
; ------------------------------------------------------------------------------------------------
Func CCleaner() ;3.06
    ;http://www.piriform.com/ccleaner/download/slim
    If RegRead($HKML & "\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\CCleaner","DisplayVersion")<>"3.06" Then
            $message &= "CCleaner version 3.06 --> Mise à jour" & @CRLF
            GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
            RunAsWait($sUserName, $domaine, $sPassword, 0, $UNC & '\CCleaner\ccsetup306_slim.exe /S',@WorkingDir,@SW_HIDE)
            If @OSArch="X64" Then
                    FileCreateShortcut($arcdir & "\CCleaner\CCleaner64.exe", @DesktopDir & "\Nettoyage.lnk",$arcdir & "\CCleaner", "/AUTO")
                    $PrgInst &= "CCleaner 3.06 X64, "
                Else
                    FileCreateShortcut(@ProgramFilesDir & "\CCleaner\CCleaner.exe", @DesktopDir & "\Nettoyage.lnk",@ProgramFilesDir & "\CCleaner", "/AUTO")
                    $PrgInst &= "CCleaner 3.06 X86, "
            EndIf
            If FileExists (@DesktopCommonDir & "\CCleaner.lnk") then FileDelete(@DesktopCommonDir & "\CCleaner.lnk")
            If FileExists (@DesktopCommonDir & "\CCleaner.lnk") then RunAsWait($sUserName, $domaine, $sPassword, 0, @comspec & ' /c del "' & @DesktopCommonDir & '\CCleaner.lnk"',@SystemDir , @SW_HIDE)
            If FileExists (@DesktopDir & "\CCleaner.lnk") then FileDelete(@DesktopDir & "\CCleaner.lnk")
            $message &= "CCleaner version 3.06 --> Installé" & @CRLF
            GUICtrlSetData ($Label1,$message & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")             
        Else
            $message &= "CCleaner version 3.06 --> Déjà Installé" & @CRLF 
            GUICtrlSetData ($Label1,$message & @CRLF & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
EndIf
EndFunc  ; ==> CCleaner
; ------------------------------------------------------------------------------------------------
Func PdfCreator() ;1.2.1
    ; http://wiki.ocsinventory-ng.org/index.php/Admin_center:Deploiement_PDFCreator
    If @OSArch="X64" Then
            If RegRead("HKEY_LOCAL_MACHINE64\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{0001B4FD-9EA3-4D90-A79E-FD14BA3AB01D}","DisplayVersion") <> "1.2.1" then 
                $message &= "PDF Creator version 1.2.1 X64--> Mise à jour" & @CRLF
                GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
                ;~ Désisntallation de l'ancienne version
                RunAsWait($sUserName, $domaine, $sPassword, 0, @comspec & ' /c "C:\Program Files (x86)\PDFCreator\unins000.exe" /verysilent', @WorkingDir, @SW_HIDE)
                ;~ Installation de la nouvelle version
                RunAsWait($sUserName, $domaine, $sPassword, 0, $UNC & '\PdfCreator\PDFCreator-1_2_1_setup.exe /LOADINF="' & $UNC & '\PdfCreator\PDFCreator.inf" /VERYSILENT /FORCEINSTALL', @ScriptDir, @SW_HIDE )
                $message &= "PDF Creator version 1.2.1 X64 --> Installé" & @CRLF
                GUICtrlSetData ($Label1,$message & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
                $PrgInst &= "PDFCreator 1.2.1 X64, "
            Else
                $message &= "PDF Creator version 1.2.1 X64--> Déjà Installé" & @CRLF 
                GUICtrlSetData ($Label1,$message & @CRLF & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
            EndIf
        Else    
            If RegRead($HKML & "\SOFTWARE\PDFCreator\Program", "ApplicationVersion") <> "1.2.1" Then
                $message &= "PDF Creator version 1.2.1 X86--> Mise à jour" & @CRLF
                GUICtrlSetData ($Label1, $message & @CRLF & "Merci de patienter" & @CRLF & @CRLF & "Christophe")
                ;~ Désisntallation de l'ancienne version
                RunAsWait($sUserName, $domaine, $sPassword, 0, @comspec & ' /c "C:\Program Files\PDFCreator\unins000.exe" /verysilent', @WorkingDir, @SW_HIDE)
                ;~ Installation de la nouvelle version
                RunAsWait($sUserName, $domaine, $sPassword, 0, $UNC & '\PdfCreator\PDFCreator-1_2_1_setup.exe /LOADINF="' & $UNC & '\PdfCreator\PDFCreator.inf" /VERYSILENT /FORCEINSTALL', @ScriptDir, @SW_HIDE )
        
                $message &= "PDF Creator version 1.2.1 --> Installé" & @CRLF
                GUICtrlSetData ($Label1,$message & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
                $PrgInst &= "PDFCreator 1.2.1 X86, "
            Else
                $message &= "PDF Creator version 1.2.1 X86 --> Déjà Installé" & @CRLF 
                GUICtrlSetData ($Label1,$message & @CRLF & @CRLF & "Bonne journée" & @CRLF & @CRLF & "Christophe")
            EndIf
        EndIf
EndFunc ; ==> PdfCreator
; ------------------------------------------------------------------------------------------------
Func Quitter()
;~  Sauve Log
    Dim $Admin="Non Administrateur"
    $ie = RegRead($HKML & "\SOFTWARE\Microsoft\Internet Explorer","Version")
    If IsAdmin() Then $Admin = "Administrateur"
    $file = FileOpen($UNC & "\install.log", 1 + 8 )
    If $file<> -1 Then
        ; Ajoute la chaine
        FileWriteLine($file, @YEAR & "-" & @MON & "-" & @MDAY & "; " & @ComputerName & "; " & @UserName & "; " & $Admin & "; " & @OSVersion & "; " & @OSServicePack &  "; " & $ie & "; (" & $PrgInst & ")" & @CRLF)
        FileClose($file)
    EndIf
    Exit
EndFunc ; ==> Quitter
; ------------------------------------------------------------------------------------------------

 

A+