[..] Éditer fichier texte, retour arriere si pas 0-9

[networe]

Sauriez-vous comment faire un retour de caracteres (Le supprimer avec le fleche sur le clavier) pour chaque ligne ne commencant pas par un chiffre ? O.o


J'ai un document de 20000 ligne comme ceci :

1,sdgdasddad,asdasdasd,
asddasd,
asdasaqwe,
qeqeeqqqqqqqq
qeqwe,
2,sajdkaskdd
djaskdasd

J'aimerai que le résultat soit du genre :


1,sdgdasddad,asdasdasd,asddasd,asdasaqwe,qeqeeqqqqqqqqqeqwe,
2,sajdkaskdddjaskdasd

J'aimerai qu'il lise le fichier lesinstru.txt et qu'il corrige ca automatiquement

Merci d'avance

[Tlem]

Le plus simple, sera de lire votre fichier ligne par ligne et d'en re-créer un sans les lignes qui ne vous intéresse pas.
Une fois le nouveau fichier créé, vous remplacez l'ancien par le nouveaux.

Pour vérifier en début de ligne si le caractère est numérique, utilisez StringRegExp (il y a des exemples sur le forum).

[networe]

Il a 27 000 lignes

[Tlem]

Et alors !!!
Ou est le problème ?
Quelle est la taille moyenne de ce fichier ?

[networe]

8 Mo , Je ne vais pas me taper ca ligne par ligne...

[Tlem]

Heuu ben non, AutoIt est là pour lire le fichier ligne par ligne à votre place !!!
Sinon, ça servirait à quoi d'utiliser AutoIt ????

Regardez l'exemple fournit dans FileReadLine. Ça vous fera une bonne base.

[networe]

Ca fait 7h que je me casse la tête en VBS sans trouver de résultat...Alors en Autoit j'ai plus dénergie .. C'est pour cela que j'ai poster dans demande de script...

Je dois fournir ce fichier très bientot et à ce rythme c'est l'échec à coup sur ..

[Strofe]

Bonsoir

Je pense à un truc comme ça

► Afficher le texte

Code : Tout sélectionner

Dim $resultat = ""
Dim $trouve = False

$file_R = FileOpen("test..txt",0)
; Check if file opened for reading OK
If $file_R = -1 Then
    MsgBox(0, "Erreur", "Il est où ton fichier ?")
    Exit
EndIf

$file_E = FileOpen("fichier2.txt",  2 + 8) ;Ecrase l'existant et créé le répertoire si nécessaire

; Read in lines of text until the EOF is reached
While 1
    
    $line = FileReadLine($file_R)
    
    If @error = -1 Then ExitLoop
    If StringRegExp($line, "^[0-9]",0) = 1 Then
            ConsoleWrite($resultat & @CRLF)
            If $resultat<>"" Then
                FileWriteLine($file_E,StringReplace($resultat,@CRLF,""))
            EndIf
            $resultat = $line
        Else
            $resultat &= $line
    EndIf
    
Wend
FileWriteLine($file_E,StringReplace($resultat,@CRLF,""))            

FileClose($file_R)
FileClose($file_E)
 

Tiens nous au courant.

Amicalement

[jchd]

Est-ce que quelque comme ça conviendrait ?

► Afficher le texte

Code : Tout sélectionner

#include <File.au3>

Local Const $fichierEntree = "lesintru.txt"             ; compléter le chemin si besoin
Local Const $fichierSortie = "lesintru_filtré.txt"     ; compléter le chemin si besoin
Local $lignes, $hSortie, $chaine

_FileReadToArray($fichierEntree, $lignes)
$hSortie = FileOpen($fichierSortie, 2+8)
For $i = 1 To $lignes[0]
    If StringIsDigit(StringLeft($lignes[$i], 1)) And $i > 1 Then
        FileWriteLine($hSortie, $chaine)
        $chaine = ""
    EndIf
    $chaine &= $lignes[$i]
Next
FileWriteLine($hSortie, $chaine)
FileClose($hSortie)

[networe]

Oh mon dieu ! Merci ! Ça marche parfaitement !!!!

2150 ligne de créer en quelques secondes !!!! Merci !!!!!!

Les 2 script marche #1

[jchd]

C'est magique un ordinateur !

[networe]

Oui ^^

J'ai un dernier soucis :

Je dois mettre entre " " des phrases se trouvant entre les deux premiere , ,

exemple :

1,Data cinq et huit,1,70,2,0,1,1,1,1,1,1,1,1,0,0,0,0,1,8,83,0,0,0,0,0,0,"Data validée"
2,Data neuf et quatre,1,70,2,0,1,1,1,1,1,1,1,1,1,0,0,0,1,8,83,0,0,0,0,0,0,"Data validée"

Pour un résultat de :
1,"Data cinq et huit",1,70,2,0,1,1,1,1,1,1,1,1,0,0,0,0,1,8,83,0,0,0,0,0,0,"Data validée"
2,"Data neuf et quatre",1,70,2,0,1,1,1,1,1,1,1,1,1,0,0,0,1,8,83,0,0,0,0,0,0,"Data validée"

Mes 2150 lignes doivent avoir les phrases entre guillemets :X

Auriez-vous un tour de magie?

[jchd]

J'adoôOÔOôore les cibles mouvantes et les spécifications qui changent à chaque message. Comme ça on a le plaisir de passer trois fois plus de temps avant de "tomber" sur le bout de code qui va bien (à un temps T). Enfin...

Kézako une "phrase" ?

Pouvez-vous poster un exemple réel de la tronche de 10 entrées complètes (avec plusieurs lignes chacune) et ce qu'il est souhaité en sortie. On va tenter d'en pifométrer les règles de transformation (jusqu'au contre-exemple). Pas de données sensibles SVP.

Le CSV, c'est la bouteille à l'encre.

[ZDS]

Bonjour,

Entièrement d'accord avec jchd, tu aurais pu dire du premier coup ce que tu voulais, ça éviterait les ajustements de dernière minute...

Bref, j'ai repris le code de jchd pour repartir depuis le fichier "filtré", et obtenir le fichier "filtré_encore" :

► Afficher le texteFiltrage bis

Code : Tout sélectionner

#include <File.au3>

Local Const $fichierEntree = "lesintru_filtré.txt"        ; compléter le chemin si besoin
Local Const $fichierSortie = "lesintru_filtré_encore.txt" ; compléter le chemin si besoin
Local $lignes, $hSortie

_FileReadToArray($fichierEntree, $lignes)
$hSortie = FileOpen($fichierSortie, 2+8)
For $i = 1 To $lignes[0]
    FileWriteLine($hSortie, StringRegExpReplace($lignes[$i], "^(\d+),([^,]+),","$1,""$2"","))
Next
FileClose($hSortie)

Avec les Regexps, on peut refaire le monde

A bientôt !

[jchd]

Berci beaucoup pour notre OP, ZDS. Désolé, c'est le pollen qui me bouche le dez.

[networe]

Merci ZDS ça marche

Désolé je ne savais pas que j'aurai à faire cette manip en plus de l'autre

[Jerome]

Coucou,



Merci de ne pas oublier la balise [R] dans le titre de votre premier message si votre sujet est résolu.



Jérôme

[jchd]

Pas sûr que "ça marche", à défaut d'autres précisions.
Avec le pattern de ZDS, on verrait :
3,chaîne n°1,5,chaîne n°2,11,43,chaîne n°3,4,dernière chaîne
devenir :
3,"chaîne n°1",5,chaîne n°2,11,43,chaîne n°3,4,dernière chaîne

Si c'est un format "à la" CSV, cela devrait être :
3,"chaîne n°1",5,"chaîne n°2",11,43,"chaîne n°3",4,"dernière chaîne"

C'est pour ça que les exemples donnés successifs ne sont pas probants ni intuitifs (par rapport aux formats CSV souvent rencontrés).

Si ça convient au posteur, tant mieux, mais encore une fois, le CSV est bien souvent une boîte de Pandore.