[R] Execution script au Shutdown sous Seven/Vista

[ferrierd]

Bonjour,

Je cherche à exécuter un script lors du shutdown de la machine.
Je sais que ce thème a été abordé maintes fois.
J'ai déjà exploré plusieurs pistes (console gpedit.msc, Fonction OnAutoitExitRegister,...)

Je suis arrivé au code suivant qui m'est pleinement fonctionnel

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_outfile=l:\sauvegarde\shutdown_AbortsystelShutdown.exe
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
;There were several "intercept shutdown" examples in the forum.
;This is one of them:
$WM_QUERYENDSESSION = 0x0011
GUIRegisterMsg($WM_QUERYENDSESSION, "Cancel_Shutdown")
GUICreate("PreventShutdownGUI")
GUISetSTate(@SW_HIDE)

; set highest notification level
If Not _SetProcessShutdownParameters(0xFFF) Then ; MSDN says maximum is 0x4FF, but it worked for me
    If Not _SetProcessShutdownParameters(0x4FF) Then ; MSDN says this is reserved for System, but worked for me
        _SetProcessShutdownParameters(0x3FF) ; highest not reserved number, if everything else does not work
    EndIf
EndIf

Global $b_ShutdownInitiated = False

While 1
    If $b_ShutdownInitiated = True then
        $b_ShutdownInitiated = False
        MsgBox(48 + 8192 + 262144, "Installer", "Ending your user session has been disabled to allow the installation to complete." _
        & @CRLF & @CRLF & "You will be able to shutdown/reboot/logoff once the installation process has completed." , 8)
    EndIf
    sleep(10)
WEnd

Func Cancel_Shutdown($hWndGUI, $MsgID, $WParam, $LParam)
    $b_ShutdownInitiated = True
    shellExecute("shutdown","-a",Default,Default,@SW_SHOW)
    ; DO NOT ADD A MSGBOX HERE
    ; Windows shows a not responding box after ~5 secs and allows to kill your app.
    Return False
EndFunc


Func _SetProcessShutdownParameters($dwLevel, $dwFlags=0)
    ; http://msdn.microsoft.com/en-us/library/ms686227%28VS.85%29.aspx
    ; Prog@ndy
    Local $aResult = DllCall("Kernel32.dll", "int", "SetProcessShutdownParameters", "dword", $dwLevel, "dword", $dwFlags)
    If @error Then Return SetError(1,0,0)
    Return $aResult[0]
EndFunc

Si une demande de shutdown est faite, alors celle-ci est désactivée.
Ce qui me permet donc de pouvoir exécuter mon script et de Shutdown le Pc après.

Le seul souci actuellement c'est que cela ne fonctionne pas sur un Vista ou un Seven.

Sur le forum Anglais j'ai trouvé l'utilisation des fonctions

Code : Tout sélectionner

Func _ShutdownBlockReasonCreate($Hwnd, $wStr)
    ; http://msdn.microsoft.com/en-us/library/ms...28VS.85%29.aspx
    ; Prog@ndy
    Local $aResult = DllCall("User32.dll", "int", "ShutdownBlockReasonCreate", "hwnd", $Hwnd, "wstr", $wStr)
    If @error Then Return SetError(1,0,0)
    Return $aResult[0]
EndFunc

Func _ShutdownBlockReasonDestroy($Hwnd)
    Local $aResult = DllCall("User32.dll", "int", "ShutdownBlockReasonDestroy", "hwnd", $Hwnd)
    If @error Then Return SetError(1,0,0)
    Return $aResult[0]
EndFunc

Mais cela redonne la main à l'utilisateur.
Je souhaite pour ma part avoir le même focntionnement que sous un Xp, c'est à dire differer la demande de shutdown, pour pouvoir lancer un script de sauvegarde, et reprendre le Shutdown de manière transparente pour l'utilisateur.

Si vous avez une expérience dans ce domaine...
Par avance Merci

[ZDS]

Hello!

Si tu vois que le shutdown a été interrompu, il te suffit de relancer le shutdown toi même, non?

Use case que je pense avoir saisi :
- Tu lances ton script et ton install
- Le script boucle tranquillement
- Un arrêt de l'ordi est demandé (peux tu détecter si c'est un arrêt, une mise en veille ou un redémarrage?)
- Ton script l'intercepte et le met en attente
- L'install continue
[... Pendant ce temps, à Vera Cruz]
- L'install se finit
- Ton script reprend la main et relance l'extinction <== C'est là que ça plante?
- Windows s'autodétruit dans un final à la "Portal 2" et de magnifiques effets spéciaux dignes de "Plan 9 from Outer Space"
- Le héros embrasse la princesse
Fin

Dans ce cas, sur la fin du script (après ta boucle While), fais un sleep de 5 secondes, et force toi même l'extinction avec la commande Shutdown (code [, reason]), si une demande d'extinction était demandée pendant l'exécution. (code : 0=déconnexion, 1=arrêt, 2=redémarrage).

C'est une façon de shunter le problème, même si ça ne donne aucune réponse à ton souci premier, pourquoi Vista et Seven se vautrent comme des loutres bourrées dans le brouillard? (y a pas un pléonasme là dedans? ^^). Plus sérieusement, je pense que ça vient de l'UAC, essaye avec un #RequireAdmin au pire (même si ça règle quasiment jamais les problèmes).

A bientôt !

[ferrierd]

Bonjour à tous,

Ca pourrait être ca ZDS

Entre temps j'ai posé la même question sur le forum anglais.
Je vous livre une réponse (pas encore testé)

► Afficher le texte

Code : Tout sélectionner

#Include <ButtonConstants.au3>
#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

If _WinAPI_GetVersion() < '6.0' Then
    MsgBox(16, 'Error', 'Require Windows Vista or later.')
    Exit
EndIf

Global $hForm, $Msg, $Button, $Check

$hForm = GUICreate('MyGUI', 200, 200)
$Button = GUICtrlCreateButton('', 73, 62, 54, 54, $BS_ICON)
GUICtrlSetImage(-1, @SystemDir & '\shell32.dll', 45)
GUICtrlSetTip(-1, 'Log off ' & @UserName)
$Check = GUICtrlCreateCheckBox('Block Windows shutdown', 10, 173, 144, 21)
GUIRegisterMsg(0x0011, 'WM_QUERYENDSESSION')
GUISetState()

; Set the highest shutdown priority for the current process to prevent closure the other processes.
_WinAPI_SetProcessShutdownParameters(0x03FF)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button
            Shutdown(0)
        Case $Check
            If GUICtrlRead($Check) = $GUI_CHECKED Then
                _WinAPI_ShutdownBlockReasonCreate($hForm, 'This application is blocking system shutdown because the saving critical data is in progress.')
            Else
                _WinAPI_ShutdownBlockReasonDestroy($hForm)
            EndIf
    EndSwitch
WEnd

Func WM_QUERYENDSESSION($hWnd, $Msg, $wParam, $lParam)
    Switch $hWnd
        Case $hForm
            If _WinAPI_ShutdownBlockReasonQuery($hForm) Then
                Return 0
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_QUERYENDSESSION

Et un Second exemple:

► Afficher le texte

Code : Tout sélectionner

#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>

Global $Shutdown = False

$hForm = GUICreate('MyGUI', 400, 200)
$Label = GUICtrlCreateLabel('Saving data in progress...', 20, 74, 160, 14)
$Progress = GUICtrlCreateProgress(20, 90, 360, 20)
GUIRegisterMsg($WM_QUERYENDSESSION, 'WM_QUERYENDSESSION')
GUIRegisterMsg($WM_ENDSESSION, 'WM_ENDSESSION')
GUISetState()

_WinAPI_SetProcessShutdownParameters(0x03FF)

For $i = 0 To 100
    _WinAPI_ShutdownBlockReasonCreate($hForm, 'This application is blocking system shutdown because saving critical data is in progress... ' & $i & '%')
    GUICtrlSetData($Label, 'Saving data in progress... ' & $i & '%')
    GUICtrlSetData($Progress, $i)
    Sleep(500)
Next
_WinAPI_ShutdownBlockReasonDestroy($hForm)

If $Shutdown Then
    Exit
EndIf

Do
Until GUIGetMsg() = -3

Func WM_QUERYENDSESSION($hWnd, $Msg, $wParam, $lParam)
    Switch $hWnd
        Case $hForm
            If _WinAPI_ShutdownBlockReasonQuery($hForm) Then
                $Shutdown = True
                Return 0
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_QUERYENDSESSION

Func WM_ENDSESSION($hWnd, $Msg, $wParam, $lParam)
    Switch $hWnd
        Case $hForm
            If Not $wParam Then
                $Shutdown = False
                Return 0
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_ENDSESSION

[Piloupilou]

Bonsoir, petite question, j'ai un peu lu le code mais trop compris encore grandchose

Mais : quelle est la fonction qui detecte le shutdown ? et comment ca marche en gros ?

Est ce qu'il y en de la meme maniere qui peuvent detecter d'autres evenements, comme des processus qui se lancent par exemple ?

[ferrierd]

Bonjour,

Je ne suis pas un spécialiste de la question.
Mais pour autant et d'après ce que j'ai pu comprendre à la fermeture de l'OS, Windows envoie une requête (WM_QUERYENDSESSION) à tous les programmes actifs, demandant de se fermer de manière propre.

Le script intercepte cette requete et annule la demande de fermeture de Windows, le temps d'executer son propre script.