[R] Ouvrir plusieurs fichiers en même temp

[pierrotm777]

Bonjour,

Je souhaiterais pouvoir sélectionner plusieurs fichiers listés dans une liste et le ouvrir en même temps que ce soit des fichiers txt ou images avec dans mon example mspaint.exe et à terme aussi avec paint.net ou photoshop .

Voici mon script actuel:

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <File.au3>
#include <GuiListBox.au3>
#include <ListBoxConstants.au3>

Dim $PaintEditor = "mspaint.exe"
;Dim $Path = "D:\Program Files\TipTop software\iCar DS\skins\CFStyle"
Dim $Path = @ScriptDir

;Gui All skin files
$AllSkinFilesGUI = GUICreate("", 490, 350, -1,-1)
GUICtrlCreateLabel("Select the file that you want to edit !!!",100, 5, 300, 20)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$AllSkinList = GUICtrlCreateList("",2, 22, 488, 300, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
GUICtrlSetFont(-1, 10, 450, 0, "MS Sans Serif")
$PaintEditorPic = GUICtrlCreateButton("Paint", 2, 325, 25, 25, $BS_ICON)
GUICtrlSetTip(-1,"Paint editor")
GUICtrlSetImage(-1, @SystemDir & '\mspaint.exe', 1, 0)
$PaintEditorName = GUICtrlCreateLabel("MsPaint",35,329,100,25)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$EditSelectedFile = GUICtrlCreateButton("Edit", 150, 325, 168, 25)
GUICtrlCreateLabel("Filter :",370,327,45,25)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$EditSelectedFilter = GUICtrlCreateCombo("", 420, 325, 60, 25)
Opt("GUIDataSeparatorChar","|")
GUICtrlSetData(-1, "*.skin|*.txt|*.ini|*.bmp|*.gif|*.jpg|*.png|*.*", "*.jpg")
GUICtrlSetFont(-1, 10, 450, 0, "MS Sans Serif")
GUISetState()
$AllSkinFilesGUIStatus = False
_GUICtrlListBox_Dir($AllSkinList,$Path & "\"&GUICtrlRead($EditSelectedFilter))

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $EditSelectedFile;edition du fichier choisi
            $testthis = _GUICtrlListBox_GetSelItems($AllSkinList)
            $sItems = ''
            For $iI = 1 To $testthis[0]
                $sItems &=  _GUICtrlListBox_GetText($AllSkinList,$testthis[$iI])
            Next
            Local $szDrive, $szDir, $szFName, $szExt
            $Ext = _PathSplit($Path & "\"& $sItems, $szDrive, $szDir, $szFName, $szExt)
            If $sItems <> '' Then
                Switch $szExt
                    Case ".txt"
                        ShellExecute($sItems, "", $Path & "\" , "edit")
                    Case ".ini",".skin"
                        Run("notepad.exe " & $Path & "\" & $sItems)
                    Case ".bmp", ".gif", ".jpg", ".png"
    ;                   run($PaintEditor&" "&@ScriptDir & "\"&$sItems,"",@SW_MAXIMIZE)
                        ShellExecute($PaintEditor, "", $Path & "\" & $sItems, "open")
                EndSwitch
            Else
                SplashTextOn("Info","Choose a file please !",200,40,-1, -1,32,"",10,800)
                sleep(2000)
                SplashOff()
            EndIf

        Case $EditSelectedFilter;filtrage selon l'extension du fichier
            _GUICtrlListBox_ResetContent($AllSkinList)
            _GUICtrlListBox_BeginUpdate($AllSkinList)
            _GUICtrlListBox_Dir($AllSkinList,$Path & "\"&GUICtrlRead($EditSelectedFilter))
            _GUICtrlListBox_EndUpdate($AllSkinList)
    EndSwitch
wend

Merci par avance de votre aide !

[Tlem]

Et donc ...
Quel est votre problème ?

[pierrotm777]

Et bien, choisir un fichier dont l'extension est , par exemple .jpg et l'ouvrir avec le bouton edit automatiquement avec mspaint ici .
Pour l'instant , je n'arrive pas à dire à mspaint d'éditer le fichier sélectionné. Mspaint s'ouvre mais vide !

[sksbir]

Bonjour

1/ Il faudrait déja vérifier "à la main" que mspaint accepte bien un argument en ligne de commande. A priori oui, mais bon, c'est à vérifier.

2/ Si il y a des espaces dans le chemin de l'argument, alors il faut encapsuler l'argument dans des quotes. On peut d'ailleurs le faire de façon systématique ce qui évite de se poser la question.

run($PaintEditor&" """&@ScriptDir & "\"&$sItems & """","",@SW_MAXIMIZE)

[pierrotm777]

Merci de votre aide!
Cet example fonctionne trés bien effectivement pour un seul fichier sélectionné.
Si je souhaite en sélectionner plusieurs afin de les ouvrir en même temps, il cherche un fichier du genre 'select1.jpgslect2.jpg' .

[zeshrek]

Je te met juste la section de code modifiée
En gros tu faisait une concaténation de la sélection qu'ensuite tu éssayais d'ouvrir, alors qu'il suffit simplement de parser la liste de la selection en ouvrant les fichiers choisis.
Bref ta boucle for/next n'était pas tout a fait au bon endroit.
J'en ai aussi priofité pour modifier la ligne qui lance le notepad pour utiliser aussi un shellexecute plutot qu'un run, histoire d'etre cohérent avec les autres lignes
Et je t'ai aussi fait tester l'extension en stringlower, parceque tu ne teste que les minuscules, or une extenson peut aussi etre mise en majuscules...

Code : Tout sélectionner

        Case $EditSelectedFile;edition du fichier choisi
            $testthis = _GUICtrlListBox_GetSelItems($AllSkinList)
            $sItems = ''
            For $iI = 1 To $testthis[0]
                $sItems = _GUICtrlListBox_GetText($AllSkinList, $testthis[$iI])
                Local $szDrive, $szDir, $szFName, $szExt
                $Ext = _PathSplit($Path & "\" & $sItems, $szDrive, $szDir, $szFName, $szExt)
                If $sItems <> '' Then
                    Switch StringLower($szExt)
                        Case ".txt"
                            ShellExecute("notepad.exe", Chr(34) & $Path & "\" & $sItems & Chr(34), $Path & "\", "edit")
                        Case ".ini", ".skin"
                            ShellExecute("notepad.exe",Chr(34) & $Path & "\" & $sItems & Chr(34) & $Path & "\" & $sItems)
                        Case ".bmp", ".gif", ".jpg", ".png"
                            ShellExecute($PaintEditor, Chr(34) & $Path & "\" & $sItems & Chr(34), $Path, "open")
                    EndSwitch
                Else
                    SplashTextOn("Info", "Choose a file please !", 200, 40, -1, -1, 32, "", 10, 800)
                    Sleep(2000)
                    SplashOff()
                EndIf
            Next
 

[pierrotm777]

Entre temps , j'avais un peu travaillé et obtenu mon besoin mais que pour les fichiers images .

Merci de votre aide encore une fois !

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <File.au3>
#include <GuiListBox.au3>
#include <ListBoxConstants.au3>

;Dim $PaintEditor = "mspaint.exe"
Dim $PaintEditor = "D:\Program Files\Paint.NET\PaintDotNet.exe"
Dim $Path = "D:\Program Files\TipTop software\iCar DS\skins\CFStyle"
;Dim $Path = @ScriptDir

;Gui All skin files
$AllSkinFilesGUI = GUICreate("", 490, 350, -1,-1)
GUICtrlCreateLabel("Select the file that you want to edit !!!",100, 5, 300, 20)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$AllSkinList = GUICtrlCreateList("",2, 22, 488, 300, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
GUICtrlSetFont(-1, 10, 450, 0, "MS Sans Serif")
$PaintEditorPic = GUICtrlCreateButton("Paint", 2, 325, 25, 25, $BS_ICON)
GUICtrlSetTip(-1,"Paint editor")
GUICtrlSetImage(-1, @SystemDir & '\mspaint.exe', 1, 0)
$PaintEditorName = GUICtrlCreateLabel("MsPaint",35,329,100,25)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$EditSelectedFile = GUICtrlCreateButton("Edit", 150, 325, 168, 25)
GUICtrlCreateLabel("Filter :",370,327,45,25)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
$EditSelectedFilter = GUICtrlCreateCombo("", 420, 325, 60, 25)
Opt("GUIDataSeparatorChar","|")
GUICtrlSetData(-1, "*.skin|*.txt|*.ini|*.bmp|*.gif|*.jpg|*.png|*.*", "*.jpg")
GUICtrlSetFont(-1, 10, 450, 0, "MS Sans Serif")
GUISetState()
$AllSkinFilesGUIStatus = False
_GUICtrlListBox_Dir($AllSkinList,$Path & "\"&GUICtrlRead($EditSelectedFilter))

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $EditSelectedFile;edition du fichier choisi
            $testthis = _GUICtrlListBox_GetSelItems($AllSkinList)
            $sItems = ''
            For $iI = 1 To $testthis[0]
                $sItems &=  _GUICtrlListBox_GetText($AllSkinList,$testthis[$iI])
            Next
            Local $szDrive, $szDir, $szFName, $szExt
            $Ext = _PathSplit($Path & "\"& $sItems, $szDrive, $szDir, $szFName, $szExt)
            If $sItems <> '' Then
                Switch $szExt
                    Case ".txt"
                        ShellExecute($sItems, "", $Path & "\" , "edit")
                    Case ".ini",".skin"
                        Run("notepad.exe " & $Path & "\" & $sItems)
                    Case ".bmp", ".gif", ".jpg", ".png"
                        $sItems = StringSplit($sItems,$szExt,1)
                        For $i = 1 to UBound($sItems)-2
                            run($PaintEditor&" """&$Path & "\"&$sItems[$i]&$szExt & """","",@SW_MAXIMIZE)
;                           msgbox(0,"",$sItems[$i])
                        Next
                EndSwitch
            Else
                SplashTextOn("Info","Choose a file please !",200,40,-1, -1,32,"",10,800)
                sleep(2000)
                SplashOff()
            EndIf

        Case $EditSelectedFilter;filtrage selon l'extension du fichier
            _GUICtrlListBox_ResetContent($AllSkinList)
            _GUICtrlListBox_BeginUpdate($AllSkinList)
            _GUICtrlListBox_Dir($AllSkinList,$Path & "\"&GUICtrlRead($EditSelectedFilter))
            _GUICtrlListBox_EndUpdate($AllSkinList)
    EndSwitch
wend

[pierrotm777]

J'ai un problème d'association avec les fichiers texte !

J'ai donc remplacé:

Code : Tout sélectionner

ShellExecute("notepad.exe", Chr(34) & $SkinPath & "\" & $sItems & Chr(34), $SkinPath & "\", $sItems)

par:

Code : Tout sélectionner

Run("notepad.exe " & Chr(34) & $SkinPath & "\" & $sItems & Chr(34))

Je ne peux pas utiliser la molette de la souris telle que ma liste est définie!
Si j'enlève les options (bitor), je n'ai plus la possibilité du choix multiple !
J'ai pourtant regardé l'aide , mais je ne trouve pas !

Une petite remarque au sujet de mspaint. Il ne peux pas ouvrir plusieurs fichiers en même temps.
En remplaçant donc :

Code : Tout sélectionner

Dim $PaintEditor = "mspaint.exe"

par

Code : Tout sélectionner

Dim $PaintEditor = "C:\Program Files\Paint.NET\PaintDotNet.exe"

cela fonctionne parfaitement

Merci encore

[Tlem]

Concernant votre problème avec notepad, avez vous lu le deuxième chapitre de la section Remarks de la commande ShellExecute ?

Pour ce qui est de Paint, vous pouvez ouvrir plusieurs images en même temps, mais il vous faudra le lancer autant de fois que vous avez d'images.