[R] Detecter un double clic sur un controle

[TommyDDR]

Bonjour,

J'aimerais savoir s'il était possible de détecter un double clic sur un control.

J'ai essayé :

Code : Tout sélectionner

GUIRegisterMsg($WM_LBUTTONDBLCLK, "Fonction")

Mais ca ne détecte le double clic QUE sur la fenêtre et non sur le contrôle que je veux.

Si quelqu'un sait comment faire, je suis tout ouïe.

Merci.

[Tlem]

Ce contrôle est-il dans votre GUI ?

[TommyDDR]

Je suis vraiment désolé pour mon retard...

Oui, mon contrôl est dans ma GUI.

[ZDS]

Bonjour.

Personnellement je me suis heurté aux même problèmes que toi, et j'ai fait ma propre tambouille pour ça. Je crois qu'il est possible de gérer les double-clics sur des contrôles en OnEventMode, mais n'étant pas fan d'un traitement par OEM (le fonctionnement n'apparait pas aussi clairement qu'avec un GuiGetMsg) je n'ai jamais eu envie de connaitre la réponse ^^
Voila mon script d'exemple :

► Afficher le textedoubleclic

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

Global Const $DELAI_DU_DOUBLECLIC = 300

Example()

Func Example()
    
    $GUI = GUICreate("", 300, 200)

    $Bouton = GUICtrlCreateButton("", 90, 50, 120, 30)
    $Bouton_timer = "STOP"

    GUISetState()

    While 1
        $GUIMsg = GUIGetMsg()
        
        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
                
            Case $Bouton
                If $Bouton_timer <> "STOP" Then
                    If TimerDiff($Bouton_timer) <= $DELAI_DU_DOUBLECLIC Then
                        MsgBox(0,"","Double clic")
                        $Bouton_timer = "STOP"
                    EndIf
                Else
                    $Bouton_timer = TimerInit()
                EndIf
            Case Else
                If $Bouton_timer <> "STOP" Then
                    If TimerDiff($Bouton_timer) > $DELAI_DU_DOUBLECLIC Then
                        MsgBox(0,"","Simple clic")
                        $Bouton_timer = "STOP"
                    EndIf
                EndIf
        EndSwitch
    WEnd
EndFunc

Bonne lecture, et à bientôt!

[Tlem]

Puisque le contrôle est bien dans votre fenêtre, GUIRegisterMsg devrait fonctionner pour cette détection.

Comme vous le souligné dans votre premier message, ça fonctionne sur la fenêtre GUI, mais dans la fonction GUIRegisterMsg, vous devez rajouter un test sur le contrôle en question.

[TommyDDR]

En effet tlem votre proposition est intelligente sauf que le problème est que le RegistrerMsg ne marche QUE sur la fenêtre, pas sur les contrôles, si je double clic sur la fenêtre, ca marche (la fonction se lance) mais si je clic sur un contrôle la fonction ne se lance même pas.

Vous pouvez tester le code suivant (j'ai mis le label en rouge pour bien voir où il est) :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <windowsconstants.au3>

Opt("GUIOnEventMode", 1)

Dim $Gui

$Gui = GUICreate("test", 300, 300)
GUIRegisterMsg($WM_LBUTTONDBLCLK, "Fonction")
GUICtrlCreateLabel("", 5, 5, 290, 20)
GUICtrlSetBkColor(-1, 0xFF0000)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
GUISetState()

Func Fonction($hWnd, $Msg, $wParam, $lParam)
    MsgBox(0, "", $hWnd & @CRLF & $Msg & @CRLF & $wParam & @CRLF & $lParam)
EndFunc

While(True)
    Sleep(10)
WEnd

Func quit()
    Exit
EndFunc
 

Ps : ZDS, ta "technique" marche mais est trop bidouille pour être appliquée à des dizaines de contrôles ^^ désolé.

[Tlem]

En reprenant votre code, et en ajoutant quelques contrôles pour que ce soit plus parlant :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <windowsconstants.au3>
#include <StaticConstants.au3>

Opt("GUIOnEventMode", 1)

Global $Form1 = GUICreate("Form1", 226, 131, 192, 124)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")

Global $Label1 = GUICtrlCreateLabel("Label1", 8, 16, 210, 24, $SS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0xFF0000)
Global $Label2 = GUICtrlCreateLabel("Label2", 8, 56, 210, 24, $SS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0x00FF00)
Global $Label3 = GUICtrlCreateLabel("Label3", 8, 96, 210, 24, $SS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0xFFFF00)


GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)


Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    Local $iIDFrom, $iCode
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
    $iCode = BitShift($iwParam, 16) ; Hi Word


    Switch $iCode ; Controle du iCode
        Case 1  ; <= Double clic
            Switch $iIDFrom
                Case $Label1
                    MsgBox(0, '', 'Double Clic sur label 1 ...')

                Case $Label2
                    MsgBox(0, '', 'Double Clic sur label 2 ...')

                Case $Label3
                    MsgBox(0, '', 'Double Clic sur label 3 ...')
        EndSwitch
    EndSwitch
EndFunc   ;==>WM_COMMAND

While (True)
    Sleep(10)
WEnd

Func quit()
    Exit
EndFunc   ;==>quit

[TommyDDR]

C'était donc $WM_COMMAND et non $WM_LBUTTONDBLCLK.

Merci.

Résolu... ou pas ^^'

Autre problème : Appliquer le même principe à une ListeView, je me suis renseigné sur msdn et j'ai trouvé "WM_MENUCOMMAND" qui aurait du m'intéresser.

Mais ca ne marche pas :

"The WM_MENUCOMMAND message is sent only for menus that are defined with the MNS_NOTIFYBYPOS flag set in the dwStyle member of the MENUINFO structure." Comment définir le "MNS_NOTIFYBYPOS" ?

[Tlem]

Regardez l'exemple de _GUICtrlListBox_Create().
Je pense que le code devrait s'adapter à la ListeView.

[TommyDDR]

En effet, c'est ce que je recherche, mais il n'est pas possible de l'appliquer sur une simple GUICtrlCreateListView ?

[Tlem]

Ma réponse est dans la deuxième partie de mon message.

[TommyDDR]

Je me suis peut être mal exprimé ^^ :

"J'ai essayer avec une simple GUICtrlCreateListView mais sans effet, la fonction ne se lance pas."

Voila.

[Tlem]

Et vous avez essayé comment ?

[TommyDDR]

Et bien j'ai repris texto le code de l'exemple en remplacant par GUICtrlCreateListViexItem :

► Afficher le textecode

Code : Tout sélectionner

#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIListBox.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_LB = False ; Check ClassName being passed to ListBox functions, set to True and use a handle to another control to see it work

Global $hListBox

_Main()

Func _Main()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("(UDF Created) List Box Create", 400, 296)
    $hListBox = GUICtrlCreateListView("Test", 2, 2, 396, 296)
    GUISetState()

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Add files
    GUICtrlCreateListViewItem("test1", $hListBox)
    GUICtrlCreateListViewItem("test2", $hListBox)
    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    ToolTip("Fonction")
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode, $hWndListBox
    If Not IsHWnd($hListBox) Then $hWndListBox = GUICtrlGetHandle($hListBox)
    $hWndFrom = $ilParam
    $iIDFrom = BitAND($iwParam, 0xFFFF) ; Low Word
    $iCode = BitShift($iwParam, 16) ; Hi Word

    Switch $hWndFrom
        Case $hListBox, $hWndListBox
            Switch $iCode
                Case $LBN_DBLCLK ; Sent when the user double-clicks a string in a list box
                    _DebugPrint("$LBN_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
                Case $LBN_ERRSPACE ; Sent when a list box cannot allocate enough memory to meet a specific request
                    _DebugPrint("$LBN_ERRSPACE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
                Case $LBN_KILLFOCUS ; Sent when a list box loses the keyboard focus
                    _DebugPrint("$LBN_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
                Case $LBN_SELCANCEL ; Sent when the user cancels the selection in a list box
                    _DebugPrint("$LBN_SELCANCEL" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
                Case $LBN_SELCHANGE ; Sent when the selection in a list box has changed
                    _DebugPrint("$LBN_SELCHANGE" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
                Case $LBN_SETFOCUS ; Sent when a list box receives the keyboard focus
                    _DebugPrint("$LBN_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; no return value
            EndSwitch
    EndSwitch
    ; Proceed the default Autoit3 internal message commands.
    ; You also can complete let the line out.
    ; !!! But only 'Return' (without any value) will not proceed
    ; the default Autoit3-message in the future !!!
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _DebugPrint($s_text)
    $s_text = StringReplace($s_text, @LF, @LF & "-->")
    ConsoleWrite("!===========================================================" & @LF & _
            "+===========================================================" & @LF & _
            "-->" & $s_text & @LF & _
            "+===========================================================" & @LF)
EndFunc   ;==>_DebugPrint
 

Le ToolTip n'est jamais affiché.

[Tlem]

Vous cherchez sans doute à faire quelque chose dans ce genre :

► Afficher le texte

Code : Tout sélectionner

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Global $fDblClk = False

$Frm_Main = GUICreate("GUI", 200, 210, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
$Lst_Values = GUICtrlCreateListView("Items", 15, 15, 170, 175)
$Lst_Handle = GUICtrlGetHandle(-1)
_GUICtrlListView_AddItem($Lst_Handle, "item1")
_GUICtrlListView_AddItem($Lst_Handle, "item2")
_GUICtrlListView_AddItem($Lst_Handle, "item3")
_GUICtrlListView_AddItem($Lst_Handle, "item4")
_GUICtrlListView_AddItem($Lst_Handle, "item5")
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_ListView_DoubleClick")

While 1
    Sleep(10)

    If $fDblClk = True Then
        $fDblClk = False
        Lst_ValuesClick()
    EndIf

WEnd


Func Close()
    Exit
EndFunc

Func Lst_ValuesClick()
    $SelIndex =  _GUICtrlListView_GetSelectedIndices($Lst_Values)
    MsgBox(0, "$SelIndex: ", $SelIndex)
    MsgBox(0, "$SelItemTxt", _GUICtrlListView_GetItemText($Lst_Handle, $SelIndex))

EndFunc

; React to double clicks on recent ListView
Func WM_ListView_DoubleClick($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return
    If DllStructGetData($tNMHDR, 1) = $Lst_Handle Then
        If DllStructGetData($tNMHDR, 3) = $NM_DBLCLK Then $fDblClk = True
    EndIf
    $tNMHDR = 0
    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_ListView_DoubleClick

[TommyDDR]

Oui c'est bien ca, ce n'est donc pas possible avec un traditionnel "GUICtrlCreateListView" + "GUICtrlCreateListViewItem, il faut passer par un "_GUICtrlListView_AddItem".

Merci.

[Tlem]

Voici un autre code qui contrôle l'utilisation du double clic. Ceci sera sans doute utile plus tard pour d'autres utilisateurs.

► Afficher le texte

Code par Melba23
http://www.autoitscript.com/forum/index ... t&p=807686

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>

Global Const $iDoubleClickTime = _GetDoubleClickTime()

Global $iDoubleClicked = 0, $iClicked = 0

$hGUI = GUICreate("Test", 500, 500)

$hPic = GUICtrlCreatePic("Your_Pic_Path", 0, 0, 500, 250)
ConsoleWrite("CID = " & $hPic & @CRLF)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    Switch $iClicked
        Case $hPic
            $Begin = TimerInit()
            Do
                Switch $iDoubleClicked
                    Case $hPic
                        MsgBox(0, "", "DBLCLK on Pic")
                        $iDoubleClicked = 0
                        $iClicked = 0
                EndSwitch
            Until TimerDiff($Begin) > $iDoubleClickTime
            If $iClicked Then MsgBox(0, "", "CLK on Pic")
            $iClicked = 0
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $nID = BitAND($wParam, 0xFFFF)

    Switch BitShift($wParam, 16) ; message code
        Case 0 ; $STN_CLICKED
            $iClicked = $nID
        Case 1 ; $STN_DBLCLK
            $iDoubleClicked = $nID
    EndSwitch

    Return $GUI_RUNDEFMSG

EndFunc ;==>WM_COMMAND

Func _GetDoubleClickTime()
    Local $aResult = DllCall("user32.dll", "uint", "GetDoubleClickTime")
    If @error Then Return SetError(1,0,100)
    Return $aResult[0]
EndFunc