[R] Déplacement d'un GuiCtrlCreateList

[Alexward]

Bonjour à tous, quand je clique sur un bouton, le GUI s'agrandit progressivement grâce à une boucle For. Mes puisque que le GUI s'agrandit , tout les boutons et tout les edit et list ont besoin d'etre replacé. Voila ou est mon probleme :

J'ai une fonctionne qui va chercher l'ordre des news (RSS) sur un site web et est inséré dans un GuiCtrlCreateList. Lorsque je clique sur la News 2 par exemple et que je clique sur info, il doit me donner l'info de la news 2. Moi dans mon code je procede par sa:


Exemple en fonction que ces la 2e News de la liste qui est sélectionné:

Code : Tout sélectionner

$CombientièmeNewsSélectionné = _GUICtrlListBox_GetCurSel($GuiCtrlCreateList)
If $CombientièmeNewsSélectionné = 2 Then GUICtrlSetData($EditAyantLesInfosDeLaNews, $DescriptionDeLaNews[2], 1)

Donc mes problèmes commence: Pour replacé mon GuiCtrlCreateList à sa place une fois l'agrandissement terminé, J'utilise GuiCtrlDelete($GuiCtrlCreateList) et je la recrée avec les bonne dimensions. Mais la news que j'avait choisi dans la liste n'est plus sélectionné puisque je les supprimé et recréé :S De plus, en la supprimant et en la recréant je suis obligé de réinsérer tout les news récupéré en RSS ce qui ralentit un peu mon script.

Donc je me demandais si il y aurait pas moyens de replacer le GuiCtrlCreateList sans l'effacer et le recréer et si possible ne pas effacer les informations qu'elle contient déjà.

Merci

[Tlem]

Si vous utilisez les styles correctement, les contrôles s’adapteront à la GUI :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 288, 406, 192, 124, BitOR($GUI_SS_DEFAULT_GUI,$WS_MAXIMIZEBOX,$WS_SIZEBOX,$WS_THICKFRAME,$WS_TABSTOP))
Global $List1 = GUICtrlCreateList("", 16, 16, 257, 331)
Global $Button1 = GUICtrlCreateButton("Boutton 1", 8, 368, 75, 25)
Global $Button2 = GUICtrlCreateButton("Boutton 2", 200, 368, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd

Sinon, rajoutez dans votre boucle de redimensionnement de votre GUI, le redimensionnement de la liste avec la commande : GUICtrlSetPos

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>

$Width = 290
$Height = 410

Global $Form1 = GUICreate("Form1", $Width, $Height, -1, -1)
Global $List1 = GUICtrlCreateList("", 16, 16, $Width - 30, $Height - 200)
Global $Button1 = GUICtrlCreateButton("Plus", 8, 368, 75, 25)
Global $Button2 = GUICtrlCreateButton("Moins", 200, 368, 75, 25)
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            $WinPos = WinGetPos($Form1)
            For $i = 1 To 100
                WinMove($Form1, "", $WinPos[0], $WinPos[1], $WinPos[2] + $i, $WinPos[3], 5)
                GUICtrlSetPos($List1, 16, 16, $WinPos[2] - 30 + $i, $WinPos[3] - 200)
            Next

        Case $Button2
            $WinPos = WinGetPos($Form1)
            For $i = 1 To 100
                WinMove($Form1, "", $WinPos[0], $WinPos[1], $WinPos[2] - $i, $WinPos[3], 5)
                GUICtrlSetPos($List1, 16, 16, $WinPos[2] - 30 - $i, $WinPos[3] - 200)
            Next

    EndSwitch
WEnd

[Alexward]

Merci. Je vais tout essayer sa ce soir. Par contre moi ma boucle For fonctionne comme ca.

Code : Tout sélectionner

for $i = 1 to 100
$longeur = longeur +5
Winmove($Gui, 50, $longeur, 50, 50

Next

Je suis sur mon iPod Touch en ce moment donc je ne connais plus par coeur le code. Il me semble que sa ressemblait à sa.

Donc je pourrais utiliser le GuiCtrlSetPos pour replacer mon GuictrlCreateList dans ma boucle For?

Merci

[Alexward]

Sa fonctionne ! Merci Beaucoup!