[R] Problème _ScreenCapture_SaveImage

[scorp84]

Bonjour,

J'ai un souci avec la fonction _ScreenCapture_SaveImage qui me permet d'enregistrer sur le disque dur une image de la capture écran.

J'ai un résultat à "False" et un code erreur à 1.

J'ai regardé dans la doc et sur le forum mais je n'ai pas trouvé les codes erreurs pour cette fonction et je n'arrive pas à voir ce qui coince.

Quelqu'un pourrait-il m'aider ?

Voici mon code :

► Afficher le texte

Code : Tout sélectionner

#include <Clipboard.au3>
#include <ScreenCapture.au3>

; Création répertoire bugs si n'existe pas
$bug_rep="c:\BUGS"
$bug_retour= DirGetSize ($bug_rep)

if $bug_retour==-1 Then
    DirCreate($bug_rep)
EndIf

; Créé le nom du fichier
$local_jour = @YEAR & "_" & @MON & "_" & @MDAY
$local_heure = @HOUR & "_" & @MIN & "_" & @SEC

$bug_img = @ComputerName  & "_" & $local_jour & "_" & $local_heure
$bug_img = StringRegExpReplace($bug_img, " ", "") & ".gif"
$bug_img = $bug_rep & "\" & $bug_img

Send("{PRINTSCREEN}")


$hGUI=GUICreate("WW")

_ClipBoard_Open ($hGUI)

$presse_papier=ClipGet()

if @error = 2 Then
    $hBitmap=_ClipBoard_GetData ($CF_BITMAP)
    $test=_ScreenCapture_SaveImage($bug_img, $hBitmap)
    MsgBox(0,"Test",$test & @LF & @error)
EndIf
 

Merci d'avance pour votre aide.

Amicalement.

BM

[Tlem]

A première vue, vous n'utilisez pas correctement la fonction _ScreenCapture_SaveImage().
Regardez l'aide de celle-ci afin de rentrer correctement les d'arguments.

[GaRydelaMer]

Bonjour

voila un exemple avec une GUI et 1 bouton. Tu clique sur le bouton et la fonction Capture s'exécute.
La capture te prends tout l'écran et le curseur. tu peux modifier ca en changeant les paramètres de la fonction:
_ScreenCapture_Capture($bug_rep & "\" & $bug_img, 0, 0, @DesktopWidth, @DesktopHeight, True)
Regarde la doc pour leurs explications.

Je t'ai mis en commentaire différent format d'image et leur utilisation (GIF BMP, PNG, JPG), et corriger ta fonction pour créer le dossier si il existe pas.

A toi de faire des essais en fonction de ce que tu veux quand au format, choisie le bien en fonction de la taille de l'image et la lisibilité. Je prendrais plutôt du JPG pas trop lourd et tu peux ajuster la qualité du JPG. A 60 j'ai la même taille de fichier que le Gif avec une plus belle image.
154 Ko pour du 1680X1050.

La dernière ligne de la fonction t'afficheras dans le programme par défaut ton image.

Voila un copier coller de ce code dans Scite puis F5 et regarde.

► Afficher le texteLe code

Code : Tout sélectionner

#Region ;**** Options AutoIt                            ****
Opt("MustDeclareVars", 1)
Opt("GUICloseOnESC", 1)
Opt("GUIOnEventMode", 1)
#EndRegion ;**** Options AutoIt                         ****
#Include <ButtonConstants.au3>
#Include <GUIConstantsEx.au3>

#Include <ScreenCapture.au3>

Global $Form1, $Button1
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 192, 124)
$Button1 = GUICtrlCreateButton("Button1", 64, 40, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlSetOnEvent($Button1, "Capture")

While 1
    Sleep(100)
WEnd

Func _Exit()
    Exit 0
EndFunc   ;==>_Exit

Func Capture()
    Local $bug_rep = "C:\BUGS"
    If Not FileExists($bug_rep) Then DirCreate($bug_rep)

    Local $local_jour = @Year & "_" & @Mon & "_" & @MDay
    Local $local_heure = @Hour & "_" & @Min & "_" & @Sec
    Local $bug_img = @ComputerName & "_" & $local_jour & "_" & $local_heure
    $bug_img = StringRegExpReplace($bug_img, " ", "")

;~  $bug_img &= ".gif"

;~  $bug_img &= ".png"

    $bug_img &= ".jpg"
    _ScreenCapture_SetJPGQuality(60)

;~  $bug_img &= ".bmp"
;~  _ScreenCapture_SetBMPFormat(0)

    _ScreenCapture_Capture($bug_rep & "\" & $bug_img, 0, 0, @DesktopWidth, @DesktopHeight, True)
    ShellExecute($bug_rep & "\" & $bug_img)
EndFunc   ;==>Capture

[scorp84]

Bonjour,

Nickel !

Merci à Tlem : effectivement mes arguments n'étaient pas corrects

Merci à GaRydelaMer : ta fonction va plus loin que ce que j'avais fait et c'est super.

La seule chose que je n'arrive pas à faire et de faire une capture par écran (c'est pour mon boulot et on bosse en double écran). Mais c'est pas grave, ça aurait été la cerise sur le gâteau hi hi hi

Amicalement.

BM

[GaRydelaMer]

Re

pour le double écran je peux pas t'aider car j'en ai qu'1

Par contre, pour avancer et gouter la cerise:
Tu dois pouvoir choisir l'écran sur lequel tu travailles et modifier les paramètres de la fonction _ScreenCapture peut être taille est dimension ??

Je pense qu'elle prend l'écran ou est exécuter la fenêtre principale de ton appli. Mais avec des valeurs négative ou > a la taille de l'écran elle changera d'écran teste avec plusieurs valeurs. Mon exemple est facile a modifier pour y arriver.

[scorp84]

Pour le double écran, j'avais essayer de chercher du côté de Windows et de la base de registre mais je n'avais pas trouvé la solution

Par contre j'avais pas eu l'idée d'essayer des valeurs négatives. Bien vu

Je teste et te tiens au jus.

On va finir par y arriver à la bouffer la cerise

Merci pour ton aide.

Amicalement.

BM