[R] Mélanger un packet de 52 cartes

[jkiller19du13]

bonjour,
je tente de creer un script qui melange un packet de cartes prédefini et les met dans un fichier ini mais je n'y arrive pas des cartes deja utiliser sont reprise donc voila mon brouillon , n'esiter pas conseille info amelioration etc ...

► Afficher le texte

If Not FileExists("carte.conf") Then
creecartes()
EndIf
;^definition du packet
Global $cartn = 0
Global $cart_force = 0
Global $couleur = "pique"
Global $carte_random = 1
Global $read = ""
;^quelques variables

While $cartn < 53

$carte_random = Random(1, 52, 1)
$read=IniRead("carte.conf", "52_cartes", $carte_random, @error)
If $read == "pris" Then
While $read <> "pris"
$carte_random = $carte_random + 1
If $carte_random = 53 Then
$carte_random = 1
EndIf
$read = IniRead("carte.conf", "52_cartes", $carte_random, @error)
WEnd
EndIf
;^ on génére une carte depuis un registre puis is elle est pas prise on la garde si non on prend la suivente
$read = IniRead("carte.conf", "52_cartes", $carte_random, @error)
IniWrite("carte.conf", "52_cartes_melanger", $cartn, $read)
IniWrite("carte.conf", "52_cartes", $cartn, "pris")
$cartn = $cartn + 1

WEnd
;^on ecrit la carte et on recommence
creecartes()
;^remise à zero du packet
Func creecartes()
$cartn = 0
$cc = 0
$c = "pique"
While $cartn < 52
$cartn = $cartn + 1
$cc = $cc + 1
If $cc == 14 And $c == "pique" Then
$cc = 1
$c = "trefle"
ElseIf $cc == 14 And $c == "trefle" Then
$cc = 1
$c = "carreau"
ElseIf $cc == 14 And $c == "carreau" Then
$cc = 1
$c = "coeur"
ElseIf $cc == 14 And $c == "coeur" Then
MsgBox(0, "", "")
EndIf

IniWrite("carte.conf", "52_cartes", $cartn, $cc & "," & $c)
WEnd
EndFunc

merci

[GaRydelaMer]

Bonsoir

alors j'ai pas encore bien regarder ton code mais voila mon idée.

Tu créer un tableau de a 2 dimensions

$Cartes[53][2]

tu as ainssi le moyen de stocker les infos sur les cartes

$Cartes[1][0] = la couleur (Pique)
$Cartes[1][1] = la Valeur (valet)

Donc de 1 à 52 tu as toutes tes cartes.

Ensuite le mélange, tu vas créer un 2eme tableau à 1 dimension pour contenir seulement l'index la référence à ta carte, tu mélanges ce tableaux.

Pour mélanger, Random ( 1, 52, 1), et tu vérifie dans le tableaux si tu as déja une carte attribué sinon tu refais un tirage. Ceci dans une boucle.

Code : Tout sélectionner

#Include <Array.au3>
Local $Couleurs[5] = [4, "Pique", "Coeur", "Carreau", "Trèfle"]
Local $Valeurs[14] = [13, "As", "Deux", "trois", "Quatre", "Cinq", _
        "Six", "Sept", "Huit", "Neuf", "Dix", "Valet", "Dame", "Roi"]
Local $Cartes[53][2]
$Cartes[0][0] = 52

Local $k = 1
For $j = 1 To $Couleurs[0]
    For $i = 1 To $Valeurs[0]
        $Cartes[$k][0] = $Valeurs[$i]
        $Cartes[$k][1] = $Couleurs[$j]
        $k += 1
    Next
Next

Local $Melange[52], $IndexCarte, $i = 0
While $i < UBound($Melange)
    $IndexCarte = Random (1, 52, 1)
    If _ArraySearch($Melange, $IndexCarte) = -1 Then
        $Melange[$i] = $IndexCarte
        $i += 1
    EndIf
WEnd

For $i = 0 To 51
    $IndexCarte = $Melange[$i]
    ConsoleWrite("Tirage Carte mélangée = " & $i + 1 & " -> " & _
            $Cartes[$IndexCarte][0] & " " & $Cartes[$IndexCarte][1] & @LF)
Next

[jkiller19du13]

merci ^^

[GaRydelaMer]

De rien ca m'a fait plaisir de le faire en 5 mn.
Je passais par la