[..] Quitter une application mais dans barre des tâches

[jamesst20]

Bonjours, J'aimerais faire de sorte que lorsque je quitte sur le bouton quitter, le script ce minimize dans la barre des tâche. et que si je clique sur l'icone dans la barre des tâches la fenêtre du script réouvre.

Aussi lorsque on fait un clique droit sur le trayicon bien il aurait tu moyen d'enlever de la liste le "Exit" et le "script paused" ?

Merci!

[SagePourpre]

Code : Tout sélectionner

Opt("TrayMenuMode",1)

Tu peux regarder dans l'aide pour les autres paramètres de "TrayMenuMode" mais
en ajoutant ce code au début de ton script, tu enlèves le menu par défaut.

Il te suffit donc de créer ton propre menu à l'aide des fonctions
commençant par "Tray" ( TrayCreateItem, TrayCreateMenu, etc... ) et
de leur associer des fonctions

[jamesst20]

Oui mais le probleme est que CreateItem créé une chose qui peut ce cocher et ce décocher.. Moi J'aimerais juste quelque chose du genre "Ouvrir" "Option" "Quitter" mais qui n'apparait pas de crochet à coté..

Sinon une idée pour la barre des tâche?

Merci

[SagePourpre]

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>
Opt("TrayMenuMode",1) ; Default tray menu items (Script Paused/Exit) will not be shown.


$onitem = TrayCreateItem("On")
$offitem = TrayCreateItem("Off")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")
;TraySetState()

While 1
$msg = TrayGetMsg()
If $msg <> 0 Then TrayItemSetState($msg,$TRAY_UNCHECKED)

Switch $msg
    Case $onitem

    Case $offitem

    Case $exititem
        Exit
EndSwitch
WEnd

 

ou encore

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>
Opt("TrayMenuMode",1) ; Default tray menu items (Script Paused/Exit) will not be shown.
Opt("TrayOnEventMode",1)

$onitem = TrayCreateItem("On")
TrayItemSetOnEvent(-1,"tray")

$offitem = TrayCreateItem("Off")
TrayItemSetOnEvent(-1,"tray")

TrayCreateItem("")

$exititem = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1,"tray")




While 1
Sleep(1000)
WEnd



Func tray()

$msg = @TRAY_ID
TrayItemSetState($msg,$TRAY_UNCHECKED)

Switch $msg
    Case $onitem
        MsgBox(0,"","")

    Case $offitem

    Case $exititem
        Exit
EndSwitch



EndFunc
 

Pour la barre des tâches...

Les fonctions TraysetClick et TraySetOnEvent sont ce que tu cherches.

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>
Opt("TrayMenuMode",1) ; Default tray menu items (Script Paused/Exit) will not be shown.
Opt("GuiOnEventMode",1)
Opt("TrayOnEventMode",1)
TraySetClick(16)
TraySetOnEvent(-7,"guishow")
$gui = GUICreate("test")
GUISetState()
GUISetOnEvent(-3,"quitter")
TrayCreateItem("Quitter")
TrayItemSetOnEvent(-1,"quitter")

While 1
    Sleep(1000)
WEnd


Func quitter()
    Exit
EndFunc

Func guishow()
     GUISetState(@SW_RESTORE,$gui)
EndFunc