[R] Nombre de version de fichiers

[Davyly]

Bonsoir,
Je cherche à réaliser un système de gestion, de nombre de versions de fichiers. Je m'explique, je zip un dossier dont le format de sortie est "Backup_20090226.zip". Le souci c'est que maintenant je me retrouve avec 26Go et plus d'une centaine de fichiers zip. Comment garder les x derniers fichiers de backup ? Un backup n'est pas réalisé tous les jours. J'ai cherché sur le forum mais j'ai pas trouvé, peut-être mal cherché. Avez-vous une idée ? moi pas du tout. Merci d'avance.

[Tlem]

Peut être une piste par ici.

[FernandG]

Bonsoir,

En supposant que tes fichiers "Backup" sont stockés dans un dossier dédié, ce code devrait correspondre à ta demande :

Code : Tout sélectionner

#Include <File.au3>
#Include <Array.au3>
;-------------
$backup_path = @DesktopDir & "\Backup"
$nb_version = 7
;-----------------------
$FileList=_FileListToArray($backup_path, "*.zip", 1)
If @Error = 1 Then
    MsgBox(16, "Erreur", "Aucun fichier correspondant à la structure de la recherche.")
    Exit
EndIf
If $FileList[0] > $nb_version Then
    For $i = $FileList[0] - $nb_version To 1 Step -1
        ;MsgBox(64, "Info", $backup_path & "\" & $FileList[$i])
        FileDelete($backup_path & "\" & $FileList[$i])
    Next
EndIf
Exit

Voilà.
Tiens nous au courant.

Bonne soirée, nuit.
AutoITement.

[Davyly]

bonsoir, aujourd'hui j'ai testé le code de FernandG en l'adaptant un peu à mes besoins et c'est parfait. Cela fonctionne à merveille, rien à dire ou plutôt merci beaucoup pour votre aide. A bientôt.

[FernandG]

Bonsoir,

Dans un autre registre et beaucoup plus complet, tu trouveras ci dessous un autre type de code écrit fin de semaine dernière. A la différence de celui donné plus haut, celui là est beaucoup plus complet et ne s'appuie pas que sur le nom du fichier mais surtout sur la date de création de ce dernier, de ton "backup". A toi maintenant de changer la variable du nombre de fichier et si besoin de la structure de recherche de tes fichiers "backup".

► Afficher le texte

Code : Tout sélectionner

; --------------------------
Dim $i = 0, $val
Local $array[1][2]
; --------------------------
$nb_version = 2
$path_backup  = @DesktopDir & "\Backup\" 
; --------------------------
$search = FileFindFirstFile($path_backup & "Backup_20*.zip")
If $search = -1 Then
    MsgBox(16, "Erreur", "Aucun fichier et/ou de répertoires correspondant à la structure de recherche.")
    Exit
EndIf
; --------------------------
While 1
    $file = FileFindNextFile($search) 
    If @error Then ExitLoop
    $date = FileGetTime($path_backup & $file)
    If $i >= 1 Then ReDim $array[$i+1][2]
    $array[$i][0] = $file
    $array[$i][1] = $date[0] & $date[1] & $date[2] & $date[3] & $date[4] & $date[5] 
    $i += 1
WEnd
; --------------------------
;  Algorithme "Tri bulle" de Strofe
For $t=0 To UBound($array, 1) -1
    For $u=$t To UBound($array, 1) -1   
        If $array[$t][1] > $array[$u][1] Then
                $tmp1 = $array[$t][0]
                $tmp2 = $array[$t][1]
                $array[$t][0] = $array[$u][0]
                $array[$t][1] = $array[$u][1]
                $array[$u][0] = $tmp1
                $array[$u][1] = $tmp2
        EndIf
    Next
Next
; Fin de l'algo et merci.
; --------------------------
If UBound($array, 1) + 1 >= $nb_version Then
    For $t = 0 To UBound($array, 1) - $nb_version
        ;MsgBox(64, "Info", $path_backup & $array[$t][0])
        FileDelete($path_backup & $array[$t][0])
    Next
EndIf
; --------------------------
FileClose($search)
Exit
; --------------------------

Je tiens à remercier tout particulièrement Strofe pour l'écriture du noyau de ce code, l'algorithme de type "Tri bulle".

Un code qui peux servir à nombreux d'entre nous, à vous de me le dire.

Bonne soirée, bonne nuit.
AutoItement.

[Tlem]

L'approche est intéressante.

Voici une alternative qui me parait plus simple bien que le code soit approximativement de la même longueur.
Cette solution ce verra plus rapide sur un nombre plus ou moins important de révision de fichier, car la commande Redim à la fâcheuse tendance à ralentir un code.

► Afficher le texteCode

Code : Tout sélectionner

#include <Array.au3>
; --------------------------
Dim $Search, $i, $File, $Filelst, $aFilelst, $Date
; --------------------------
$nb_version = 2
$path_backup = @DesktopDir & "\Backup\"
; --------------------------
$Search = FileFindFirstFile($path_backup & "Backup_20*.zip")
If $Search = -1 Then
    MsgBox(16, "Erreur", "Aucun fichier et/ou de répertoires correspondant à la structure de recherche.")
    Exit
EndIf
; --------------------------
While 1
    $File = FileFindNextFile($Search)
    If @error Then ExitLoop
    $Date = FileGetTime($path_backup & $File, 0, 1)
    $Filelst = $Filelst & $Date & "#" & $path_backup & $File & @CR
WEnd

$Filelst = StringLeft($Filelst, StringLen($Filelst) - 1)
$aFilelst = StringSplit($Filelst, @CR)
_ArraySort($aFilelst, 1, 1)

If $aFilelst[0] > $nb_version Then
    For $i = $nb_version + 1 To $aFilelst[0]
        $File = StringSplit($aFilelst[$i],"#")
        FileDelete($File[2])
    Next
EndIf
; --------------------------
FileClose($search)
Exit
; --------------------------

[FernandG]

Idem, ton approche est aussi intéressante. Tout regrouper dans une "colonne" unique, fallait y penser. Le FileGetTime permettant le sort et à coup de StringSplit, j'aime bien.

Aller, histoire de trouver quelque chose à dire, je remplacerais la ligne :

Code : Tout sélectionner

$Filelst = $Filelst & $Date & "#" & $path_backup & $File & @CR

Par

Code : Tout sélectionner

$Filelst &= $Date & "#" & $path_backup & $File & @CR

Comment ça j'abuse ... ?!?! Bon ok je retourne à un autre "post"

Bonne soirée, bonne nuit.
AutoITement.