Référence UDF - Traduction Google

_Date_Time_SystemTimeToArray

Décoder une heure du système à un tableau

 #include <Date.au3>
_Date_Time_SystemTimeToArray ( ByRef $tSystemTime )

Paramètre

$tSystemTime la structure $tagSYSTEMTIME

Valeur de retour

Retourne un tableau avec le format suivant :
    [ 0] - Mois
    [ 1] - Jour
    [ 2] - Année
    [ 3] - Heure
    [ 4] - Minutes
    [ 5] - secondes
    [ 6] - millisecondes
    [ 7] - Jour de la semaine

Remarque

Aucune.

Lien

$tagSYSTEMTIME()

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tTime, $aTime

    ; Créer GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtenez heure actuelle du système
    $tTime = _Date_Time_GetSystemTime()
    $aTime = _Date_Time_SystemTimeToArray($tTime)
    MemoWrite("Month ........: " & $aTime[0])
    MemoWrite("Day ..........: " & $aTime[1])
    MemoWrite("Year .........: " & $aTime[2])
    MemoWrite("Hour .........: " & $aTime[3])
    MemoWrite("Minute .......: " & $aTime[4])
    MemoWrite("Second .......: " & $aTime[5])
    MemoWrite("Milliseconds .: " & $aTime[6])
    MemoWrite("Day of week ..: " & $aTime[7])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==> Example

; Écrire une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==> MemoWrite