Référence UDF - Traduction Google

_Date_Time_FileTimeToSystemTime

Convertit une heure de fichier de format de l'heure du système

 #include <Date.au3>
_Date_Time_FileTimeToSystemTime ( $pFileTime )

Paramètre

$pFileTime Pointeur vers une structure de dollars tagFILETIME contenant la durée de fichier à convertir à la date et l'heure système
le format.

Valeur de retour

Retourne une structure $tagSYSTEMTIME qui contient le temps de fichier converti.

Remarque

Aucune.

Liens

$tagFILETIME(), $tagSYSTEMTIME(), _Date_Time_FileTimeToDOSDateTime(), _Date_Time_FileTimeToLocalFileTime()

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $tFile, $tSystem

    ; Créer GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Coder une heure de fichier
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $tSystem = _Date_Time_FileTimeToSystemTime(DllStructGetPtr($tFile))
    MemoWrite("System file time .: " & _Date_Time_SystemTimeToDateTimeStr($tSystem))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==> Example

; Écrire une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==> MemoWrite