Référence UDF - Traduction Google

_Date_Time_CompareFileTime

Compare deux fois de fichiers

 #include <Date.au3>
_Date_Time_CompareFileTime ( $pFileTime1, $pFileTime2 )

Paramètres

$pFileTime1 Pointeur à la première structure de $tagFILETIME
$pFileTime2 Pointeur deuxième structure $tagFILETIME

Valeur de retour

Renvoie l'une des valeurs suivantes :
    -1 - Temps d'abord de fichier est antérieure à la deuxième heure de fichier
    0 - temps d'abord de fichier est égale à la deuxième heure de fichier
    1 - Premier temps de fichier est plus tard que la deuxième fois de fichiers

Remarque

Aucune.

Lien

$tagFILETIME()

Exemple

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $pFileTime1, $tFileTime1, $pFileTime2, $tFileTime2

    ; Créer GUI
    GUICreate("Time", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Comparer FAT dates / heures
    $tFileTime1 = _Date_Time_DOSDateTimeToFileTime(0x3621, 0x11EF) ; 01/01/2007 2:15:30
    $tFileTime2 = _Date_Time_DOSDateTimeToFileTime(0x379F, 0x944A) ; 12/31/2007 18:34:20
    $pFileTime1 = DllStructGetPtr($tFileTime1)
    $pFileTime2 = DllStructGetPtr($tFileTime2)

    MemoWrite("Result 1: " & _Date_Time_CompareFileTime($pFileTime1, $pFileTime2))
    MemoWrite("Result 2: " & _Date_Time_CompareFileTime($pFileTime1, $pFileTime1))
    MemoWrite("Result 3: " & _Date_Time_CompareFileTime($pFileTime2, $pFileTime1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==> Example

; Écrire une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==> MemoWrite