#include <APIGdiConstants.au3>
#include <APISysConstants.au3>
#include <WindowsConstants.au3>

Global Const $CDS_TEST =				0x00000002
Global Const $CDS_UPDATEREGISTRY =		0x00000001
Global Const $CDS_FULLSCREEN =			0x00000004
Global Const $CDS_RESET =				0x40000000
Global Const $DISP_CHANGE_SUCCESSFUL =	0
Global Const $DISP_CHANGE_RESTART =		1
Global Const $DISP_CHANGE_FAILED =		-1
Global Const $DISP_CHANGE_BADMODE =		-2
Global Const $DISP_CHANGE_NOTUPDATED =	-3
Global Const $DISP_CHANGE_BADFLAGS =	-4
Global Const $DISP_CHANGE_BADPARAM =	-5

;===============================================================================
;
; Function Name: _ChangeScreenRes()
; Description: Changes the current screen geometry, colour and refresh rate.
; Version: 1.0.0.1
; Parameter(s): $i_Width - Width of the desktop screen in pixels. (horizontal resolution)
; $i_Height - Height of the desktop screen in pixels. (vertical resolution)
; $i_BitsPP - Depth of the desktop screen in bits per pixel.
; $i_RefreshRate - Refresh rate of the desktop screen in hertz.
; Requirement(s): AutoIt Beta > 3.1
; Return Value(s): On Success - Screen is adjusted, @ERROR = 0
; On Failure - sets @ERROR = 1
; Forum(s): <a href='http://www.autoitscript.com/forum/index.php?showtopic=20121' class='bbc_url' title=''>http://www.autoitscript.com/forum/index.php?showtopic=20121</a>
; Author(s): Original code - psandu.ro
; Modifications - PartyPooper
;
;===============================================================================

Func _ChangeScreenRes($i_Width = @DesktopWidth, $i_Height = @DesktopHeight, $i_BitsPP = @DesktopDepth, $i_RefreshRate = @DesktopRefresh, $mode = $CDS_UPDATEREGISTRY, $reset = False)
    If $i_Width = "" Or $i_Width = -1 Then $i_Width = @DesktopWidth ; default to current setting
    If $i_Height = "" Or $i_Height = -1 Then $i_Height = @DesktopHeight ; default to current setting
    If $i_BitsPP = "" Or $i_BitsPP = -1 Then $i_BitsPP = @DesktopDepth ; default to current setting
    If $i_RefreshRate = "" Or $i_RefreshRate = -1 Then $i_RefreshRate = @DesktopRefresh ; default to current setting
	Local $DEVMODE = DllStructCreate(	"char dmDeviceName[32];ushort dmSpecVersion;ushort dmDriverVersion;short dmSize;" & _
										"ushort dmDriverExtra;dword dmFields;short dmOrientation;short dmPaperSize;short dmPaperLength;" & _
										"short dmPaperWidth;short dmScale;short dmCopies;short dmDefaultSource;short dmPrintQuality;" & _
										"short dmColor;short dmDuplex;short dmYResolution;short dmTTOption;short dmCollate;" & _
										"byte dmFormName[32];dword dmBitsPerPel;int dmPelsWidth;dword dmPelsHeight;" & _
										"dword dmDisplayFlags;dword dmDisplayFrequency")
    Local $B = DllCall("user32.dll", "int", "EnumDisplaySettings", "ptr", 0, "long", 0, "ptr", DllStructGetPtr($DEVMODE))
    If @error Then
        $B = 0
        SetError(1)
        Return $B
    Else
        $B = $B[0]
    EndIf
    If $B <> 0 Then
		If($reset) Then
			$DEVMODE = Null
			$mode = 0
		Else
			DllStructSetData($DEVMODE, "dmSize", DllStructGetSize($DEVMODE))
			   DllStructSetData($DEVMODE, "dmPelsWidth", $i_Width)
			DllStructSetData($DEVMODE, "dmPelsHeight", $i_Height)
			DllStructSetData($DEVMODE, "dmBitsPerPel", $i_BitsPP)
			DllStructSetData($DEVMODE, "dmDisplayFrequency", $i_RefreshRate)
			DllStructSetData($DEVMODE, "dmFields", BitOR($DM_PELSWIDTH, $DM_PELSHEIGHT, $DM_BITSPERPEL, $DM_DISPLAYFREQUENCY))
		EndIf
        $B = DllCall("user32.dll", "int", "ChangeDisplaySettings", "ptr", DllStructGetPtr($DEVMODE), "int", $CDS_TEST)
        If @error Then
            $B = -1
        Else
            $B = $B[0]
        EndIf
        Select
            Case $B = $DISP_CHANGE_RESTART
                $DEVMODE = ""
                Return 2
            Case $B = $DISP_CHANGE_SUCCESSFUL
                DllCall("user32.dll", "int", "ChangeDisplaySettings", "ptr", DllStructGetPtr($DEVMODE), "int", $mode)
                DllCall("user32.dll", "int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_DISPLAYCHANGE, _
                        "int", $i_BitsPP, "int", $i_Height * 2 ^ 16 + $i_Width)
                $DEVMODE = ""
                Return 1
            Case Else
                $DEVMODE = ""
                SetError(1)
                Return $B
        EndSelect
    EndIf
EndFunc   ;==>_ChangeScreenRes