#cs -----------------------------------------------------------------------------------------------
	Définition de mots dans un dictionnaire sur internet
	Script AutoIt Version 3.3.8.0
	Auteur : Ahbadiane
	Version du 17 Janvier 2012

	Fonction : _DicoDefinition($sStrategieDico, $sMot, $hForm, $bStopPossible = True, $bDebug = False)

#ce -----------------------------------------------------------------------------------------------
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
AutoItSetOption("MustDeclareVars", 1)
#include-once
#include <Misc.au3>
#include <String.au3>

Global $oErreur, $iNbErreur = 0, $bErreur = False

;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot dans les dictionnaires sur internet
;
; IN  $sStrategieDico : Contient la liste des dicos à parcourir : C-a-d "L"="Larousse.fr", "D"="Diconnaire.net", "T"="dictionnaire.Tv5.org" ou "X"="dictionnaire.eXionnaire.com"
;						 Peut-être terminé par un /x (x=L,D,T ou X) pour obliger à revoir avec un nouveau mot dans ces derniers dictionnaires
;						 Exemples
;							"DL" = rechercher en premier sur Diconnaire.net et si pas trouvé alors rechercher sur Larousse.fr
;							"LD/L" = rechercher en premier Larousse.fr et si pas trouvé alors rehercher sur Diconnaire.net et si trouvé rechercher avec un mot différent sur Larousse.fr
;	  $sMot			  : Mot à rechercher
;	  $hForm		  : Handle de la fenêtre qui appel cette fonction (utilisé pour l'arrêt di traiatement pour voir si la fenêtre est active)
;	  $bStopPossible  : Pour tester l'appui de la touche Echap pour arrêter le traitement
;     $bDebug		  : True => création dans le spous-répertoire debug, d'un fichier HTML et TXT par mot et par définition
;
; OUT Retour d'un tableau 2D
;	  Si OK 		: [0][0] = Nb de définitions
;					  [0][1] = Dico utilisé (remis ici mais idem que $sStrategieDico)
;					  [1][0] = Le Mot 1
;					  [1][1] = Catégorie du Mot 1 (Verbe, Nom ...)
;					  [1][2] = La définition du Mot 1
;					  [2][0] = Le Mot 2
;					  ...
;     Si arrêt user : [0][0] = -2, [0][1] = Arrêt par l'utilisateur
;	  Si une erreur : [0][0] = -1, [0][1] = Texte de l'erreur
;------------------------------------------------------------------------------
Func _DicoDefinition($sStrategieDico, $sMot, $hForm, $bStopPossible = True, $bDebug = False)
	Local $i, $j, $k, $sDico1, $sDico2, $sDicoDebut, $sDicoFin = "", $aReturn[1][3] = [[-1, "Pas de dictionnaire reconnu !", ""]]
	$i = StringInStr($sStrategieDico, "/")
	If $i > 0 Then
		$sDicoDebut = StringLeft($sStrategieDico, $i -1)
		$sDicoFin = StringMid($sStrategieDico, $i +1)
	Else
		$sDicoDebut = $sStrategieDico
	EndIf
	For $i = 1 To StringLen($sDicoDebut)
		$sDico1 = StringMid($sDicoDebut, $i, 1)
		$aReturn = _DicoDefinitionUnDico($sDico1, $sMot, $hForm, $bStopPossible, $bDebug)
		If $aReturn[0][0] >= 1 Then
			For $j = 1 To StringLen($sDicoFin)
				$sDico2 = StringMid($sDicoFin, $j, 1)
				If $sDico2 = $sDico1 Then ExitLoop
				For $k = 1 To $aReturn[0][0]
					; Mot différent ou dictionnaire pas utilisé
					If ($sMot <> $aReturn[$k][0]) Or Not StringInStr(StringLeft($sDicoDebut, $i), $sDico2) Then
						Local $aReturn2 = _DicoDefinitionUnDico($sDico2, $aReturn[$k][0], $hForm, $bStopPossible, $bDebug)
						If $aReturn2[0][0] >= 1 Then Return $aReturn2
						If $aReturn2[0][0] = -2 Then ; Arrêt utilisateur
							Local $aErreur[1][3] = [[-2, "Arrêt par l'utilisateur", ""]]
							Return $aErreur
						EndIf
					EndIf
				Next
			Next
			ExitLoop
		ElseIf $aReturn[0][0] = -2 Then ; Arrêt utilisateur
			ExitLoop
		EndIf
	Next
	Return $aReturn
EndFunc


;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot dans un dictionnaire sur internet
;
; IN  Idem _DicoDefinition()
;
; OUT Idem _DicoDefinition()
;------------------------------------------------------------------------------
Func _DicoDefinitionUnDico($sDico, $sMot, $hForm, $bStopPossible, $bDebug)
	Local $aReturn
	; Mise en place de la gestion des erreurs
	$oErreur = ObjEvent("AutoIt.Error", "FuncErreur")
	$iNbErreur = 0
	GUISetCursor(15, 1) ; Curseur WAIT
	Switch StringUpper($sDico)
		Case "L"
			$aReturn = _DicoDefinitionLarousse($sMot, $hForm, $bStopPossible, $bDebug)
			$sDico = "Larousse.fr"
		Case "D"
			$aReturn = _DicoDefinitionDictionnaireNet($sMot, $hForm, $bStopPossible, $bDebug)
			$sDico = "Dictonnaire.net"
		Case "T"
			$aReturn = _DicoDefinitionDictionnaireTv5Org($sMot, $hForm, $bStopPossible, $bDebug)
			$sDico = "Dictionnaire.TV5.org"
		Case "X"
			$aReturn = _DicoDefinitionDictionnaireExionnaireCom($sMot, $hForm, $bStopPossible, $bDebug)
			$sDico = "Dictionnaire.eXionnaire.com"
		Case Else
			$aReturn = "Quel dictionnaire ?"
	EndSwitch
	GUISetCursor(2, 1)
	; Désactivation de la gestion des erreurs
	$oErreur = 0
	If IsArray($aReturn) Then
		$aReturn[0][1] = $sDico
		Return $aReturn
	Else
		If $aReturn = "Stop" Then
			Local $aErreur[1][3] = [[-2, "Arrêt par l'utilisateur", ""]]
		Else
			Local $aErreur[1][3] = [[-1, $aReturn, ""]]
		EndIf
		Return $aErreur
	EndIf
EndFunc


;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot du dictionnaire sur Dictionnaire.eXionnaire.com
;
; IN  Idem _DicoDefinition()
;
; OUT Idem _DicoDefinition()
;
; REM : Mots à tester : bridgee, graderaient, remesurer, manger, Lysat, Voir, table, titrisas
;------------------------------------------------------------------------------
Func _DicoDefinitionDictionnaireExionnaireCom($sMot, $hForm, $bStopPossible, $bDebug)
	Local $aReturn[2][3], $as, $asBody, $i, $j
	; Mode debug
	_DicoDefinitionModeDebug(0, $sMot, "X", $aReturn, $bDebug)
	; Corps de la page HTML du mot trouvé sur dictionnaire.tv5.org
	Local $sBody = _DicoDefinitionBody("X", $sMot, $hForm, $bStopPossible, $bDebug)
	; Erreur remontée ?
	If StringLen($sBody) < 200 Then Return $sBody
	; Trouvé ?
	If StringInStr($sBody, "</u> n'a pas été trouvé dans notre dictionnaire") Then Return "Mot non trouvé !"
	$as = _StringBetween($sBody, "href='#sommaire'>1.", "href='#sommaire'")
	If @error Then Return "Mot non trouvé !"
	$sBody = $as[0]
	; $aReturn[0][0] : Nombre de définitions (Nb d'articles)
	StringReplace($sBody, "id='divEntreeDico'", "")
	$i = @extended
	If $i < 1 Then Return "Mot non trouvé !"
	Dim $aReturn[$i +1][3]
	$aReturn[0][0] = $i
	; Nettoyer les <div style='margin:20px;vertical:align:middle'>
	$sBody = StringReplace($sBody, "</div>     <div style='margin:20px;vertical:align:middle'>", "")
	; Découpage par bloc <div id='divEntreeDico
	$asBody = _StringBetween($sBody, "<div id='divEntreeDico'", "</div>")
	If @error Then Return "Erreur (1) sur la structure de la page"
	; Mot
	For $i = 1 To $aReturn[0][0]
		$as = _StringBetween($asBody[$i -1], "<font color='#777777'>", "</font>")
		If @error Then Return "Erreur (2) sur la structure de la page"
		$aReturn[$i][0] = $as[0]
	Next
	; Catégorie
	For $i = 1 To $aReturn[0][0]
		$as = _StringBetween($asBody[$i -1], "<font class='dicoStatiqueNature'>", "</font>")
		If @error Then Return "Erreur (3) sur la structure de la page"
		$aReturn[$i][1] = $as[0]
	Next
	; Définition
	For $i = 1 To $aReturn[0][0]
		$as = _StringBetween($asBody[$i -1], "<font color='#000055'>", "</font>")
		If @error Then
			$j = StringInStr($asBody[$i -1], "border='0'>")
			If $j > 0 Then $aReturn[$i][2] = _RemplaceEntre(StringMid($asBody[$i -1], $j +11), "<", ">", "")
		Else
			$aReturn[$i][2] = _RemplaceEntre($as[0], "<", ">", "")
		EndIf
	Next
	Return $aReturn
EndFunc


;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot du dictionnaire sur Dictionnaire.tv5.org
;
; IN  Idem _DicoDefinition()
;
; OUT Idem _DicoDefinition()
;------------------------------------------------------------------------------
Func _DicoDefinitionDictionnaireTv5Org($sMot, $hForm, $bStopPossible, $bDebug)
	Local $i, $sa, $s, $aReturn[2][3], $saMot, $saDef, $saCat
	; Mode debug
	_DicoDefinitionModeDebug(0, $sMot, "T", $aReturn, $bDebug)
	; Corps de la page HTML du mot trouvé sur dictionnaire.tv5.org
	Local $sBody = _DicoDefinitionBody("T", $sMot, $hForm, $bStopPossible, $bDebug)
	; Erreur remontée ?
	If StringLen($sBody) < 200 Then Return $sBody
	; Trouvé ?
	If StringInStr($sBody, "<b>" & $sMot & "</b> n'est pas une entrée du dictionnaire") Then Return "Mot non trouvé !"
	; $aReturn[0][0] : Nombre de définitions (Nb d'articles)
	StringReplace($sBody, '<font color=red>(', "")
	$aReturn[0][0] = @extended
	If $aReturn[0][0] = 0 Then Return "Mot non trouvé !"
	; Bloc recherché
	$sa = _StringBetween($sBody, '<table><tr><td>', ' </td></tr></table>')
	If @error <> 0 Then Return "Erreur (1) sur la structure de la page"
	$s = _RemplaceEntre($sa[0], '<a href="dictionnaires.asp?', '>', '')
	; Mot
	$saMot = _StringBetween($s, '<font color=black><b>', '<font color=red>')
	If @error <> 0 Then Dim $saMot[$aReturn[0][0]]
	If UBound($saMot) <> $aReturn[0][0] Then ReDim $saMot[$aReturn[0][0]]
	; Catégorie
	$saCat = _StringBetween($s, '<font color=red>(', ')</font>')
	If @error <> 0 Then Dim $saCat[$aReturn[0][0]]
	If UBound($saCat) <> $aReturn[0][0] Then ReDim $saCat[$aReturn[0][0]]
	; Définition
	$saDef = _StringBetween($s & '<font color=>', ')</font>', '<font color=')
	If @error <> 0 Then
		$saDef = _StringBetween($s, ')</font>', '</small>')
		If @error <> 0 Then Dim $saDef[$aReturn[0][0]]
	EndIf
	If UBound($saDef) <> $aReturn[0][0] Then ReDim $saDef[$aReturn[0][0]]
	ReDim $aReturn[$aReturn[0][0] +1][3]
	For $i = 1 To $aReturn[0][0]
		$aReturn[$i][0] = _RemplaceEntre(StringStripWS($saMot[$i -1], 7), "<", ">", "")
		$aReturn[$i][0] = StringReplace($aReturn[$i][0], "> ", "")
		$aReturn[$i][1] = _RemplaceEntre(StringStripWS($saCat[$i -1], 7), "<", ">", "")
		$aReturn[$i][2] = StringReplace($saDef[$i -1], '<br> ', @CRLF)
		$aReturn[$i][2] = StringReplace($aReturn[$i][2], @CRLF, "", 1)
		$aReturn[$i][2] = StringReplace($aReturn[$i][2], @CRLF, "", -2)
		$aReturn[$i][2] = _RemplaceEntre($aReturn[$i][2], '<', '>', '')
	Next
	_DicoDefinitionModeDebug(1, $sMot, "T", $aReturn, $bDebug)
	Return $aReturn
EndFunc


;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot du dictionnaire sur http://www.dictionnaire.net et http://www.conjugaison.net
;
; IN  Idem _DicoDefinition()
;
; OUT Idem _DicoDefinition()
;------------------------------------------------------------------------------
Func _DicoDefinitionDictionnaireNet($sMot, $hForm, $bStopPossible, $bDebug)
	Local $i, $sa, $sMotTrouve, $aReturn[2][3], $saDef, $bTrouve
	; Mode debug
	_DicoDefinitionModeDebug(0, $sMot, "D", $aReturn, $bDebug)
	; Corps de la page HTML du mot trouvé sur Dictionnaire.net
	Local $sBody = _DicoDefinitionBody("DMot", $sMot, $hForm, $bStopPossible, $bDebug)
	; Erreur remontée ?
	If StringLen($sBody) < 200 Then Return $sBody
	; Trouvé ?
	$bTrouve = False
	If Not StringInStr($sBody, 'finition "' & $sMot & '" non disponible') Then
		$bTrouve = True
	ElseIf StringRight($sMot, 1) = "s" Then ; => Pluriel ?
		$sMot = StringTrimRight($sMot, 1)
		$sBody = _DicoDefinitionBody("DMot", $sMot, $hForm, $bStopPossible, $bDebug)
		; Erreur remontée ?
		If StringLen($sBody) < 200 Then Return $sBody
		; Trouvé ?
		If StringInStr($sBody, 'finition "' & $sMot & '" non disponible') Then
			$sMot &= "s"
		Else
			$bTrouve = True
		EndIf
	EndIf
	If Not $bTrouve Then ; => Conjugaison
		$sBody = _DicoDefinitionBody("DVerbe", $sMot, $hForm, $bStopPossible, $bDebug)
		; Erreur remontée ?
		If StringLen($sBody) < 200 Then Return $sBody
		; Trouvé ?
		If StringInStr($sBody, '<title>CONJUGAISON - Conjugaison française & grammaire des verbes</title>') Then Return "Mot non trouvé !"
		; Verbe de référence
		$sa = _StringBetween($sBody, '<H1 id="nopadding">Conjugaison ', '</H1>')
		If @error <> 0 Then Return "Mot non trouvé !"
		$sMot = $sa[0]
		$sBody = _DicoDefinitionBody("DMot", $sMot, $hForm, $bStopPossible, $bDebug)
		; Erreur remontée ?
		If StringLen($sBody) < 200 Then Return $sBody
		; Trouvé ?
		If StringInStr($sBody, 'finition "' & $sMot & '" non disponible') Then Return "Mot non trouvé !!!"
	EndIf
	; $aReturn[0][0] : Nombre de définitions (Nb d'articles)
	$sa = _StringBetween($sBody, 'class="container-bloc1"> <strong>', '</strong>')
	If @error <> 0 Then Return "Mot non trouvé !"
	$aReturn[0][0] = UBound($sa)
	; $sMotTrouve : Mot trouvé
	$sa = _StringBetween($sBody, '<h1>Définition', '</h1>')
	If @error <> 0 Then Return "Erreur (1) sur la structure de la page"
	$sMotTrouve = StringStripWS($sa[0], 7)
	; Définition
	$saDef = _StringBetween($sBody, 'class="container-bloc1"> <strong>', '</div>')
	If @error <> 0 Then Return "Erreur (2) sur la structure de la page"
	ReDim $aReturn[$aReturn[0][0] +1][3]
	For $i = 1 To $aReturn[0][0]
		$aReturn[$i][0] = $sMotTrouve
		$saDef[$i -1] = StringStripWS($saDef[$i -1], 7)
		$aReturn[$i][1] = StringLeft($saDef[$i -1], StringInStr($saDef[$i -1], "</strong>") -1)
		$saDef[$i -1] = StringMid($saDef[$i -1], StringInStr($saDef[$i -1], "</strong><br />") +16)
		$saDef[$i -1] = _RemplaceEntre($saDef[$i -1], "<", ">", "")
		$aReturn[$i][2] = StringReplace($saDef[$i -1], "-" & @LF, "- ")
	Next
	_DicoDefinitionModeDebug(1, $sMot, "D", $aReturn, $bDebug)
	Return $aReturn
EndFunc


;------------------------------------------------------------------------------
; Retourne le ou les définitions d'un mot du dictionnaire sur http://www.larousse.f
;
; IN  Idem _DicoDefinition()
;
; OUT Idem _DicoDefinition()
;------------------------------------------------------------------------------
Func _DicoDefinitionLarousse($sMot, $hForm, $bStopPossible, $bDebug)
	Local $i, $j, $k, $n, $s, $sRef0, $saRef, $sa, $saDef, $aReturn[2][3]
	; Mode debug
	_DicoDefinitionModeDebug(0, $sMot, "L", $aReturn, $bDebug)
	; Corps de la page HTML du mot trouvé sur Larousse.fr
	Local $sBody = _DicoDefinitionBody("L", $sMot, $hForm, $bStopPossible, $bDebug)
	; Erreur remontée ?
	If StringLen($sBody) < 200 Then Return $sBody
	; $aReturn[0][0] : Nombre de définitions (Nb d'articles)
	$sa = _StringBetween($sBody, 'class="heading">Articles [', ']<')
	If @error <> 0 Then Return "Mot non trouvé !"
	$aReturn[0][0] = Number($sa[0])
	; $sRef0 : La référence de la définition actuelle, sous la forme Mot/xxxxx
	$sa = _StringBetween($sBody, 'clearfix">', '>Définitions')
	If @error <> 0 Then	Dim $sa[1] = [$sBody]
	$sa = _StringBetween($sa[0], 'href="/dictionnaires/francais/', '"')
	If @error <> 0 Then Return "Erreur (1) sur la structure de la page"
	$sRef0 = $sMot & "/" & StringMid($sa[0], StringInStr($sa[0], "/") +1)
	; $saRef[] : Liste des références des N définitions, sous la forme Mot/xxxxx
	$sa = _StringBetween($sBody, 'class="heading">Articles [', '<script type="text/javascript">')
	If @error <> 0 Then Return "Erreur (2) sur la structure de la page"
	$saRef = _StringBetween($sa[0], 'dictionnaires/francais/', '"')
	If @error <> 0 Then Return "Erreur (3) sur la structure de la page"
	; Mot, Catégorie, définition
	If UBound($saRef) < $aReturn[0][0] Then $aReturn[0][0] =  UBound($saRef)
	ReDim $aReturn[$aReturn[0][0] +1][3]
	For $i = 1 To $aReturn[0][0]
		$j = StringInStr($saRef[$i -1], "#")
		If $j > 0 Then $saRef[$i -1] = StringMid($saRef[$i -1], 1, $j -1)
		If ($i <> 1) Or ($sRef0 <> $saRef[$i -1]) Then $sBody = _DicoDefinitionBody("L", $saRef[$i -1], $hForm, $bStopPossible, $bDebug)
		 ; Erreur remontée ?
		If StringLen($sBody) < 200 Then Return $sBody
		; Supprimer des éléments parasites
		$sBody = StringReplace($sBody, "<SUP>", "")
		$sBody = StringReplace($sBody, "</SUP>", "")
		$sBody = StringReplace($sBody, @TAB, "")
		$sBody = StringReplace($sBody, '<br>', " ")
		$sBody = StringReplace($sBody, '&nbsp;', " ")
		; Mot
		$sa = _StringBetween($sBody, 'class="TitrePage">Définitions de ', '<')
		If @error = 0 Then $aReturn[$i][0] = StringReplace($sa[0], '&nbsp;', ' ')
		; Catégorie
		$sa = _StringBetween($sBody, 'class="CatgramDefinition">', '</')
		If @error = 0 Then $aReturn[$i][1] = StringStripWS($sa[0], 7)
		; Les N Définitions
		; Mise en forme des sous-définitions
		$saDef = _StringBetween($sBody, '<ol class="SousDivision">', '</ol>')
		If @error = 0 Then
			For $j = 0 To UBound($saDef) -1
				$s = '<ol class="SousDivision">' & $saDef[$j] & '</ol>'
				StringReplace($saDef[$j], "<li>", "")
				$n = @extended
				For $k = 1 to $n
					$saDef[$j] = StringReplace($saDef[$j], "<li>", $k & ". ", 1)
				Next
				$saDef[$j] = StringMid($saDef[$j], StringInStr($saDef[$j], "1. "))
				$saDef[$j] = StringReplace($saDef[$j], "</li>", "") & "</li>"
				$sBody = StringReplace($sBody, $s, $saDef[$j])
			Next
		EndIf
		; Déinition
		$saDef = _StringBetween($sBody, 'class="DivisionDefinition">', '</li>')
		If @error = 0 Then
			For $j = 0 To UBound($saDef) -1
				$saDef[$j] = StringReplace($saDef[$j], '<br />', '<br /> ')
				$saDef[$j] = _RemplaceEntre($saDef[$j] , "<", ">", "")
				$sa = _StringBetween($saDef[$j], '<a class="lienarticle" href="/dictionnaires/francais/', '">')
				If @error = 0 Then
					For $k = 0 To UBound($sa) -1
						$saDef[$j] = StringReplace($saDef[$j], '<a class="lienarticle" href="/dictionnaires/francais/' & $sa[$k] & '">', '')
					Next
				EndIf
				If $j > 0 Then $aReturn[$i][2] &= @CRLF
				$aReturn[$i][2] &= $saDef[$j]
			Next
		EndIf
	Next
	_DicoDefinitionModeDebug(1, $sMot, "L", $aReturn, $bDebug)
	Return $aReturn
EndFunc


;--------------------------------------------------------------------------------------------------
; Fonction de debug
;
; IN  $iMode    : 0=Init, 1=Valeur, -1=Erreur (WinHttp.WinHttpRequest)
;     $sMot		: Mot recherché
;	  $sDico	: "L"="Larousse.fr", "D"="Diconnaire.net", "T"="dictionnaire.Tv5.org" ou "X"="dictionnaire.eXionnaire.com"
;	  $aTableau	: Tableau 2D du mot
;	  $bDebug	: Mode debug ou pas
; OUT /
;--------------------------------------------------------------------------------------------------
Func _DicoDefinitionModeDebug($iMode, $sMot, $sDico, $aTableau, $bDebug)
	If Not $bDebug Then Return
	Local $hFile
	If $iMode = -1 Then
		$hFile = FileOpen(@ScriptDir & "\Debug\Trace-Erreur.txt", 9)
	Else
		$hFile = FileOpen(@ScriptDir & "\Debug\" & StringLeft($sMot, 1) & "\" & StringReplace($sMot, "/", "_") & ".txt", 9)
	EndIf
	If $hFile = -1 Then Return
	Switch $iMode
		Case 0
			FileWriteLine($hFile, "Début :" & @MDAY & "-" & @MON & "-" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC & " Dico : " & $sDico & " Mot : " & $sMot)
			FileClose($hFile)
		Case 1
			FileWriteLine($hFile, 'Nb de définition de ' & $sMot & ' = ' & $aTableau[0][0])
			For $i = 1 To $aTableau[0][0]
				FileWriteLine($hFile, $aTableau[$i][0] & @TAB & $aTableau[$i][1])
				FileWriteLine($hFile, $aTableau[$i][2])
			Next
			FileClose($hFile)
		Case -1
			FileWriteLine($hFile, "Erreur à " & @MDAY & "-" & @MON & "-" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC & " Dico:" & $sDico & " Mot:" & $sMot & " URL:" & $aTableau)
			FileClose($hFile)
	EndSwitch
EndFunc


;--------------------------------------------------------------------------------------------------
; Fonction retournant le corps de la page HTML du mot recherché
;
; IN  $sDicoRubrique : Code du dicotionnaire (et éventuellement la rubrique) - Voir Switch $sDicoRubrique ...
;     $sMot			 : Mot recherché
;	  $hForm		 : Handle de la fenêtre qui appel cette fonction
;	  $bStopPossible : Pour tester l'appui de la touche Echap pour arrêter le traitement
;	  $bDebug		 : Mode debug ou pas
; OUT Body de la page HTML ou un libelle d'erreur de moins de 200 caractères
;--------------------------------------------------------------------------------------------------
Func _DicoDefinitionBody($sDicoRubrique, $sMot, $hForm, $bStopPossible, $bDebug)
	Local $oHTTP, $sBody, $sFile, $hFile, $sUrl, $iNumDef = 0, $iBinaryToStringFlag = 4
	Switch $sDicoRubrique
		Case "DMot"
			$sUrl = "http://www.dictionnaire.net/definition/" & $sMot & ".html"
		Case "DVerbe"
			$sUrl = "http://www.conjugaison.net/fr/" & $sMot & ".html"
		Case "L"
			$sUrl = "http://www.larousse.fr/dictionnaires/francais/" & $sMot
		Case "T"
			$sUrl = "http://dictionnaire.tv5.org/dictionnaires.asp?Action=1&mot=" & $sMot
			$iBinaryToStringFlag = 1
		Case "X"
			$sUrl = "http://www.dictionnaire.exionnaire.com/que-signifie.php?mot=" & $sMot
			$iBinaryToStringFlag = 1
		Case Else
	EndSwitch
	If (Ping("www.google.com", 5000) = 0) And (Ping("www.facebook.com", 5000) = 0) And (Ping("www.youtube.com", 5000) = 0) Then Return "Vous n'êtes pas connecté à internet !"
	While 1
		If $bStopPossible And WinActive($hForm) And _IsPressed("1B") Then
			If MsgBox(8484, "Stop", "Arrêter la recherche ?") = 6 Then
				_NiToucheNiEsc()
				Return "Stop"
			Else
				_NiToucheNiEsc()
			EndIf
		EndIf
		$oHTTP = 0
		$bErreur = 0
		If $iNbErreur > 0 Then
			If $iNbErreur > 20 Then Return "Problème grave de WinHttp.WinHttpRequest !!!!"
			_DicoDefinitionModeDebug(-1, $sMot, $sDicoRubrique, $sUrl, $bDebug)
			Sleep(1000 + ($iNbErreur * 100))
		EndIf
		$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
		If @error Then Return "Création de l'objet HTTP impossible"
		$oHTTP.Open("GET", $sUrl)
		If $bErreur Then ContinueLoop
		$oHTTP.SetTimeOuts(0, 60000, 30000, 30000)
		If $bErreur Then ContinueLoop
		$oHTTP.Send()
		If $bErreur Then ContinueLoop
		If $oHttp.Status <> 200 Then Return "Utilisation de l'objet HTTP impossible"
		If $bErreur Then ContinueLoop
		$oHTTP.WaitForResponse
		If $bErreur Then ContinueLoop
		$sBody = BinaryToString($oHTTP.ResponseBody, $iBinaryToStringFlag)
		If Not $bErreur Then ExitLoop
	WEnd
	; Mode debug
	If $bDebug Then
		Do
			$iNumDef += 1
			$sFile = @ScriptDir & "\Debug\" & StringLeft($sMot, 1) & "\" & StringReplace($sMot, "/", "_") & "_" & $iNumDef & ".html"
		Until Not FileExists($sFile)
		$hFile = FileOpen($sFile, 10)
		FileWrite($hFile, $sBody)
		FileClose($hFile)
	EndIf
	Return $sBody
EndFunc


;--------------------------------------------------------------------------------------------------
; Fonction de gestion des erreurs mis en place pour les erreurs COM $oHTTP.Send()
;
; IN  /
; OUT Si l'erreur est liée à WinHttp.WinHttpRequest :
;			$iNbErreur est incrémenté
;			$bErreur passe à True
;    Sinon
;			Affichage de l'erreur et arrêt du programme
;--------------------------------------------------------------------------------------------------
Func FuncErreur()
    Local $HexNumber = Hex($oErreur.Number, 8)
	If $oErreur.source = "WinHttp.WinHttpRequest" Then
		$iNbErreur += 1
		$bErreur = True
	Else
		MsgBox(8240, "Erreur", "L'application a rencontré une erreur" & @CRLF & @CRLF & _
				"Description : " & @TAB & $oErreur.description & @CRLF & _
				"              " & @TAB & $oErreur.windescription & @CRLF & _
				"N° Erreur   : " & @TAB & $HexNumber & @CRLF & _
				"Ligne       : " & @TAB & $oErreur.scriptline & @CRLF & _
				"La source   : " & @TAB & $oErreur.source)
		Exit
	EndIf
EndFunc


;--------------------------------------------------------------------------------------------------
; Fonction remplaçant dans un $sTexte entre 2 bornes $sDebut et $sFin par $sRemplace
; en différenciant Minuscule et Majuscule ou pas
; IN  $sTexte		 : Texte à travailler
;	  $sDebut		 : début recherché
;	  $sFin			 : Fin recherché
;	  $sRemplace	 : Le texte qui viendra remplacer entre début et fin inclus
;	  $bDiffMinusMaj : Différencier les minuscules/majuscules ou pas
; OUT Texte trasnformer
;--------------------------------------------------------------------------------------------------
Func _RemplaceEntre($sTexte, $sDebut, $sFin, $sRemplace, $bDiffMinusMaj = False)
	Local $i, $sa = _StringBetween($sTexte, $sDebut, $sFin, Number($bDiffMinusMaj) - 1)
	If @error = 0 Then
		For $i = 0 To UBound($sa) -1
			$sTexte = StringReplace($sTexte, $sDebut & $sa[$i] & $sFin, $sRemplace, 0, $bDiffMinusMaj)
		Next
	EndIf
	Return $sTexte
EndFunc


;--------------------------------------------------------------------------------------------------
; Fonction d'attente du non appui de la touche Esc et de bouton
; IN  $iWait : Temps t'attente après l'attente
; OUT /
;--------------------------------------------------------------------------------------------------
Func _NiToucheNiEsc($iWait = 500)
	While (GUIGetMsg() <> 0) Or _IsPressed("1B")
		Sleep(20)
	WEnd
	Sleep($iWait)
EndFunc