[..] Ecriture illisible GUI .png

[Utilisateur 3643 supprimé]

Bonjour, j'ai fais un petit programme avec un GUI .png (GDIPlus) et quand j'ajoute un label/checkbox/radio etc il est écrit en vert/noir (image liée)
Donc je voudrait savoir comment faire pour choisir la couleur .
Merci d'avance !!

[mikell]

Est-ce que ton script est construit à partir de ce modèle ?
http://www.autoitscript.fr/forum/viewto ... 478#p62478

[Utilisateur 3643 supprimé]

oui

[mikell]

Bon bin t'aurais pu dire merci quand même...
Pour tes controles essaie GuiCtrlSetColor

[Utilisateur 3643 supprimé]

ça ne marche pas :/

[mikell]

Si tu montrais le script ça serait plus facile...

[Utilisateur 3643 supprimé]

Le script n'est autre que celui que tu m'a offert sur ce sujet: http://www.autoitscript.fr/forum/viewto ... 478#p62478

[mikell]

Ben je vois pas où est le problème

► Afficher le texte

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
 
Global $hGUI2, $hImage

; gui principale
$hGUI2 = GUICreate("Test", 400, 400, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
$exit = GuiCtrlCreateLabel("", 290, 80, 30, 30)
GUICtrlSetState(-1, $GUI_ONTOP)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUISetState()

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\GUI.png")
SetBitMap($hGUI2, $hImage, 255)

; gui pour placer des controles
$gui_bis = GUICreate("", 400, 400, 0, 0, $WS_POPUP, $WS_EX_LAYERED  + $WS_EX_COMPOSITED + $WS_EX_MDICHILD, $hGUI2)

GuiCtrlCreateLabel("Label", 100, 120, 800, 30)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0xccffaa)
GUICtrlSetFont(-1, 16, 600, 0) 

GuiCtrlCreateCheckBox("Checkbox", 100, 160, 120, 25)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0xf0f0ff)
GUICtrlSetFont(-1, 14)

$btn = GuiCtrlCreateButton("bouton", 200, 200, 60, 30)  ; exemple ^^
GUICtrlSetBkColor(-1, 0xf0f0ff)
GUISetBkColor(0x00FF00)
_WinAPI_SetLayeredWindowAttributes($gui_bis, 0x00FF00)
GUISetState(@SW_SHOWNOACTIVATE)  ; pour éviter le focus moche sur le controle

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")


While 1
$msg = GuiGetMsg()
If $msg = $exit Then ExitLoop
If $msg = $btn Then Msgbox(0,"", "bouton pressé")
Wend

_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()

;=====================================================

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
  if ($hWnd = $hGUI2) and ($iMsg = $WM_NCHITTEST) then Return $HTCAPTION
EndFunc


Func SetBitmap($hGUI, $hImage, $iOpacity)
  Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
  $hScrDC  = _WinAPI_GetDC(0)
  $hMemDC  = _WinAPI_CreateCompatibleDC($hScrDC)
  $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
  $hOld    = _WinAPI_SelectObject($hMemDC, $hBitmap)
  $tSize   = DllStructCreate($tagSIZE)
  $pSize   = DllStructGetPtr($tSize  )
  DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth ($hImage))
  DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
  $tSource = DllStructCreate($tagPOINT)
  $pSource = DllStructGetPtr($tSource)
  $tBlend  = DllStructCreate($tagBLENDFUNCTION)
  $pBlend  = DllStructGetPtr($tBlend)
  DllStructSetData($tBlend, "Alpha" , $iOpacity    )
  DllStructSetData($tBlend, "Format", 1)
  _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
  _WinAPI_ReleaseDC   (0, $hScrDC)
  _WinAPI_SelectObject($hMemDC, $hOld)
  _WinAPI_DeleteObject($hBitmap)
  _WinAPI_DeleteDC    ($hMemDC)
EndFunc

[Utilisateur 3643 supprimé]

label c'est bon,mais c'est les checkbox qui me posent problème ...