[R] Générer des fonctions

[pumilio]

Bonjour,

Est-il possible de créer des fonctions dans une boucle ? J'ai essayé divers solutions mais rien à faire. Autoit n'accepte pas de variable comme nom de fonction et je ne vois pas comment contourner ça.

Voici mon code dans lequel je souhaiterais générer les fonctions "_linkInX()" et "_linkOutX()" puisque leur nombre peut changer en fonction des besoins:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "includes\GUICtrlOnHover.au3"
Opt("GuiOnEventMode", 1)

Global $a[7][2]

$GUI = GUICreate("GUI",500, 200, -1, -1)
$label = GUICtrlCreateLabel("A", 216, 5, 68, 70)
GUICtrlSetbkColor(-1, 0xBDC6CF)
$image = GUICtrlCreatePic(@ScriptDir&"\image.jpg",221, 10, 58, 60)
$ok = GUICtrlCreateButton("ok", 210, 160, 80, 30)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUICtrlSetOnEvent($ok, "_ok")
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func SpecialEvents()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
            Exit
    EndSelect
EndFunc

Func _ok()
    For $i = 0 To 6
        $a[$i][0] = GUICtrlCreateLabel($i, $i*72, 80, 68, 70)
       GUICtrlSetbkColor(-1, 0xBDC6CF)
        $a[$i][1] = GUICtrlCreatePic("",$i*72+5, 85, 58, 60)
        GuiCtrlSetImage($a[$i][1], @ScriptDir&"\image.jpg")
    _GUICtrlSetOnHover($a[$i][0], "_linkIn"&$i, "_linkOut"&$i, "_linkClic"&$i, "_ClicRelache"&$i)
   Next
EndFunc

Func _linkIn0($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[0][0], 0x000000)
    GUICtrlSetColor($a[0][0], 0xFFFFFF)
EndFunc
Func _linkOut0($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[0][0], 0xBDC6CF)
    GUICtrlSetColor($a[0][0], 0x000000)
EndFunc

Func _linkIn1($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[1][0], 0x000000)
    GUICtrlSetColor($a[1][0], 0xFFFFFF)
EndFunc
Func _linkOut1($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[1][0], 0xBDC6CF)
    GUICtrlSetColor($a[1][0], 0x000000)
EndFunc

Func _linkIn2($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[2][0], 0x000000)
    GUICtrlSetColor($a[2][0], 0xFFFFFF)
EndFunc
Func _linkOut2($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[2][0], 0xBDC6CF)
    GUICtrlSetColor($a[2][0], 0x000000)
EndFunc

Func _linkIn3($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[3][0], 0x000000)
    GUICtrlSetColor($a[3][0], 0xFFFFFF)
EndFunc
Func _linkOut3($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[3][0], 0xBDC6CF)
    GUICtrlSetColor($a[3][0], 0x000000)
EndFunc

Func _linkIn4($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[4][0], 0x000000)
    GUICtrlSetColor($a[4][0], 0xFFFFFF)
EndFunc
Func _linkOut4($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[4][0], 0xBDC6CF)
    GUICtrlSetColor($a[4][0], 0x000000)
EndFunc

Func _linkIn5($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[5][0], 0x000000)
    GUICtrlSetColor($a[5][0], 0xFFFFFF)
EndFunc
Func _linkOut5($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[5][0], 0xBDC6CF)
    GUICtrlSetColor($a[5][0], 0x000000)
EndFunc

Func _linkIn6($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($a[6][0], 0x000000)
    GUICtrlSetColor($a[6][0], 0xFFFFFF)
EndFunc
Func _linkOut6($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($a[6][0], 0xBDC6CF)
    GUICtrlSetColor($a[6][0], 0x000000)
EndFunc

J'ai essayé des choses de ce genre sans succès :

Code : Tout sélectionner

For $j = 0 to 6
    $funcNameIn = "_linkIn"&$j
    $funcNameOut = "_linkOut"&$j
    Func $funcNameIn($CtrlID, $Param, $Param2)
        GUICtrlSetBkColor($a[$j][0], 0x000000)
        GUICtrlSetColor($a[$j][0], 0xFFFFFF)
    EndFunc
    Func $funcNameOut($CtrlID, $Param, $Param2)
        GUICtrlSetbkColor($a[$j][0], 0xBDC6CF)
        GUICtrlSetColor($a[$j][0], 0x000000)
    EndFunc
Next

Merci pour votre aide.

[mikell]

Décidément tu aimes te compliquer la vie

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; #include "includes\GUICtrlOnHover.au3"
#include "GUICtrlOnHover.au3"
Opt("GuiOnEventMode", 1)

Global $a[7][2]

$GUI = GUICreate("GUI",500, 200, -1, -1)
$label = GUICtrlCreateLabel("A", 216, 5, 68, 70)
GUICtrlSetbkColor(-1, 0xBDC6CF)
$image = GUICtrlCreatePic("",221, 10, 58, 60)
$ok = GUICtrlCreateButton("ok", 210, 160, 80, 30)
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")
GUICtrlSetOnEvent($ok, "_ok")
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func SpecialEvents()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE
            Exit
    EndSelect
EndFunc

Func _ok()
    For $i = 0 To 6
        $a[$i][0] = GUICtrlCreateLabel($i, $i*72, 80, 68, 70)
       GUICtrlSetbkColor(-1, 0xBDC6CF)
        $a[$i][1] = GUICtrlCreatePic("",$i*72+5, 85, 58, 60)
       ; GuiCtrlSetImage($a[$i][1], @ScriptDir&"\image.jpg")
    _GUICtrlSetOnHover($a[$i][0], "_linkIn", "_linkOut", "_linkClic", "_ClicRelache")
   Next
EndFunc

Func _linkIn($CtrlID, $Param, $Param2)
    GUICtrlSetBkColor($CtrlID, 0x000000)
    GUICtrlSetColor($CtrlID, 0xFFFFFF)
EndFunc

Func _linkOut($CtrlID, $Param, $Param2)
    GUICtrlSetbkColor($CtrlID, 0xBDC6CF)
    GUICtrlSetColor($CtrlID, 0x000000)
EndFunc

Func _linkClic($CtrlID, $Param)
    GUICtrlSetBkColor($CtrlID, 0x00ff00)
    GUICtrlSetColor($CtrlID, 0xFFFF00)
EndFunc

Func _ClicRelache($CtrlID, $Param)
    GUICtrlSetbkColor($CtrlID, 0xBD0000)
    GUICtrlSetColor($CtrlID, 0x333333)
EndFunc

 

[pumilio]

En effet
Je pique des petits bouts de code sur les forums et vu mon niveau je ne les maitrises pas...
Mais après ton intervention tout est simple et clair en effet.

Merci