[R] Rendre un fichier XML lisible au format TXT

[franco]

Bonjour.

Je ne sais pas si vous le savez, mais maintenant, malwarebyte's antimalware fournit les rapports au format XML...

J'ai donc fait un script qui m'enregistre le dernier rapport sur le bureau, avec l'extension TXT...

Et j'ai fait des "manipulations" pour que le fichier soit lisible de tous...

En fait, je voulais supprimer tous les </ ... >, ne sachant pas ce que contient ses balises </>... en fait, j'en connais, mais pas tous...

J'ai fait ceci :

► Afficher le textecode

Code : Tout sélectionner

#include <_FileListToArrayNT.au3>
#include <file.au3>

$mbamlog_dir = @AppDataCommonDir & "\Malwarebytes\Malwarebytes Anti-Malware\Logs"
$linelog = _FileListToArrayNT($mbamlog_dir, "*mbam-log*", 1, 2, False, "", 1)

$FichierXML = @TempDir & "\fichiersXML.txt"
$FileXML = FileOpen($FichierXML, 2)


$Result = UBound($linelog) - 1
For $i = 1 To $Result
    If Not @error Then
        FileWriteLine($FileXML, $linelog[$i])
    EndIf
Next
FileClose($FileXML)
$mbamlogXML = FileReadLine($FichierXML)
Local $sDrive ,$sDir, $sFilename , $sExtension
Local $aPathSplit = _PathSplit($mbamlogXML, $sDrive, $sDir, $sFilename, $sExtension)
$mbamlogTXT = @DesktopDir&"\" &$sFilename& ".txt"
FileCopy($mbamlogXML,$mbamlogTXT,1)


;~ for $i = 1 to _FileCountLines($mbamlogTXT)

_ReplaceStringInFile($mbamlogTXT,"<file><path>","File : ")
_ReplaceStringInFile($mbamlogTXT,"</path><vendor>"," || vendor : ")
_ReplaceStringInFile($mbamlogTXT,"</vendor><action>"," || action : ")
_ReplaceStringInFile($mbamlogTXT,"</action><hash>"," || hash : ")
_ReplaceStringInFile($mbamlogTXT,"</action><baddata>"," || baddata : ")
_ReplaceStringInFile($mbamlogTXT,"</baddata><gooddata>"," || gooddata : ")
_ReplaceStringInFile($mbamlogTXT,"</gooddata><hash>"," || hash : ")
_ReplaceStringInFile($mbamlogTXT,"</hash></file>","")

$_rapport = @TempDir & "\test.txt"
$_rapport2 = FileOpen($_rapport,2)
    For $i = 1 To _FileCountLines($mbamlogTXT)
        FileWriteLine($_rapport2, StringRegExpReplace(FileReadLine($mbamlogTXT, $i), "\</.*", "") & "")
    Next
    FileClose($_rapport2)
    ShellExecute($_rapport)


;~ ShellExecute($mbamlogTXT)

En fait :

Code : Tout sélectionner

    For $i = 1 To _FileCountLines($mbamlogTXT)
        FileWriteLine($_rapport2, StringRegExpReplace(FileReadLine($mbamlogTXT, $i), "\</.*", "") & "")
    Next

Ce bout de code me supprime ce qu'il y a après </, et il supprime parfois des éléments qui ne faut pas.
Je veux supprimer que les balises </> et ce qu'elles contiennent...

Pouvez-vous m'aider ?

Merci
@ bientôt !

[jguinch]

Perso, je ne comprends pas trop ta demande.
Tu pourrais poster un fichier XML et nous montrer le résultat que tu attends ?

[franco]

Salut.

je vais mettre le fichier XML en pièce jointe...

Je vais citer un passage :

<engine>
<version>2.00.0.1000</version>
<rules-database>v2014.03.27.02</rules-database>
<swissarmy-database>v2014.03.25.01</swissarmy-database>
<license>premium</license>
<file-protection>enabled</file-protection>
<web-protection>enabled</web-protection>
<self-protection>disabled</self-protection>
</engine>
etc...

En gros, je veux supprimer que les balises fermantes.
C'est à dire, en comparant avec le texte cité ci-dessus :
</version>
</rules-database>
</swissarmy-database>
</license>

Mais je ne sais pas toujours ce que contient les balises, et donc les balises fermantes non plus.

Si je vais quelle expression régulière il faut utiliser, je l'aurais fait... Mais celle que j'ai utilisé n'est pas la bonne.


Voilà.

Merci de ta réponse et de ton aide.
@+

[jguinch]

Mais ça va ressembler à rien
Un truc comme ça ?

Code : Tout sélectionner

$sUserContent = StringRegExpReplace( FileRead("mbam-log-2014-03-27 (10-51-54).xml"), "</[^>]+>", "")
ConsoleWrite($sUserContent)

[franco]

Salut.

« Mais ça va ressembler à rien »

Si, car les balises ouvrantes, je les "transforme" moi même. ^^


En fait, avant la version 2 de malwarebyte, les rapports étaient sous format TXT.
Lisible aussi bien par les helpeurs que les helpés...

Maintenant, c'est devenue illisible. Car ce type de rapport, on le regarde via le bloc note, afin de voir ce qu'il en est.

Un exemple d'un rapport au format TXT : http://cjoint.com/14av/DDnu1lWnTFS_rapp ... rebyte.txt

Je le cite, vu que ce type de lien s'efface dans le temps :

► Afficher le texterapport mbam - TXT

Malwarebytes Anti-Malware
http://www.malwarebytes.org

Date de l'examen: 13/04/2014
Heure de l'examen: 10:50:29
Fichier journal: Rapport malwarebyte.txt
Administrateur: Oui

Version: 2.00.1.1004
Base de données Malveillants: v2014.04.13.02
Base de données Rootkits: v2014.03.27.01
Licence: Gratuite
Protection contre les malveillants: Désactivé(e)
Protection contre les sites Web malveillants: Désactivé(e)
Chameleon: Désactivé(e)

Système d'exploitation: Windows 7 Service Pack 1
Processeur: x64
Système de fichiers: NTFS
Utilisateur: pimiento

Type d'examen: Examen "Menaces"
Résultat: Terminé
Objets analysés: 271198
Temps écoulé: 5 min, 8 sec

Mémoire: Activé(e)
Démarrage: Activé(e)
Système de fichiers: Activé(e)
Archives: Activé(e)
Rootkits: Activé(e)
Shuriken: Activé(e)
PUP: Activé(e)
PUM: Activé(e)

Processus: 0
(No malicious items detected)

Modules: 0
(No malicious items detected)

Clés du Registre: 0
(No malicious items detected)

Valeurs du Registre: 0
(No malicious items detected)

Données du Registre: 0
(No malicious items detected)

Dossiers: 0
(No malicious items detected)

Fichiers: 1
PUP.Optional.Babylon.A, C:\Users\pimiento\AppData\Local\Google\Chrome\User Data\Default\Preferences, Bon: (), Mauvais: ( "startup_urls": [ "http://www.google.com", "http://search.babylon.com/?AF=110398&ba ... 16ec417afb", "", "http://www.google.com/", "http://www2.delta-search.com/?affID=120 ... 16EC417AFB", "http://feed.snap.do/?publisher=Tuguu&dp ... 10/05/2013", "http://start.mysearchdial.com/?f=1&a=ai ... 882020&ir=", "http://www.holasearch.com/?affID=121962 ... 16EC417AFB", "http://start.mysearchdial.com/?f=1&a=ir ... 535106&ir=", "http://start.iminent.com/?appId=1E03A9E ... 6B2E97FBF7" ],), Remplacé,[2fd1718fcc34ba46f471db70c63e46ba]

Secteurs physiques: 0
(No malicious items detected)


(end)

Rien à voir avec le rapport au format XML que j'ai mis en pièce jointe ici.

==============================

Maintenant, merci pour ton code, il a résolu mon souci

Voici le code final (je peux encore l'améliorer, mais il est opérationnel)

► Afficher le textecode

Code : Tout sélectionner

#include <_FileListToArrayNT.au3>
#include <file.au3>
Local $sDrive, $sDir, $sFilename, $sExtension

$mbamlog_dir = @AppDataCommonDir & "\Malwarebytes\Malwarebytes Anti-Malware\Logs"
$linelog = _FileListToArrayNT($mbamlog_dir, "*mbam-log*", 1, 2, False, "", 1)

$Lrecent_mbamlogXML = UBound($linelog) - 1
$recent_mbamlogXML = $linelog[$Lrecent_mbamlogXML]
$sUserContent = StringRegExpReplace(FileRead($recent_mbamlogXML), "</[^>]+>", "")

$recent_mbamlogTXT = @DesktopDir & "\rapport_mbam.txt"
$_recent_mbamlogTXT = FileOpen($recent_mbamlogTXT, 2)
FileWrite($_recent_mbamlogTXT, $sUserContent)
FileClose($_recent_mbamlogTXT)

_FileWriteToLine($recent_mbamlogTXT, 1, "", 1)
_FileWriteToLine($recent_mbamlogTXT, 2, "", 1)
_ReplaceStringInFile($recent_mbamlogTXT, "<mbam-log>", "[mbam-log]")
_ReplaceStringInFile($recent_mbamlogTXT, "<engine>", "[engine]")
_ReplaceStringInFile($recent_mbamlogTXT, "<system>", "[system]")
_ReplaceStringInFile($recent_mbamlogTXT, "<summary>", "[summary]")
_ReplaceStringInFile($recent_mbamlogTXT, "<options>", "[options]")
_ReplaceStringInFile($recent_mbamlogTXT, "<items>", "[items]")
_ReplaceStringInFile($recent_mbamlogTXT, "<items>", "[items]")
_ReplaceStringInFile($recent_mbamlogTXT, "<file><path>", " - File/patch: ")
_ReplaceStringInFile($recent_mbamlogTXT, "<", " - ")
_ReplaceStringInFile($recent_mbamlogTXT, ">", ": ")

If Not IsDeclared("iMsgBoxAnswer") Then Local $iMsgBoxAnswer
$iMsgBoxAnswer = MsgBox(4, "Rapport mbam créé au format TXT", "Le dernier rapport de Malwarebyte's Antimalware vient d'être enregistré sous le bureau :" & @CRLF & $recent_mbamlogTXT & @CRLF & @CRLF & "Souhaitez-vous l'ouvrir ?")
Select
    Case $iMsgBoxAnswer = 6 ;Yes
        ShellExecute($recent_mbamlogTXT)
EndSelect

Voilà
Merci à toi

Bonne journée / soirée.

[jguinch]

Juste deux remarques :
- dans ton code, tu déclares des variables que tu n'utilise pas (et à l'inverse tu utilise des variables non déclarées). C'est pas grave, mais c'est juste plus propre de supprimer les déclaration inutiles - et éventuellement de déclarer les autres)
- tu as deux fois _ReplaceStringInFile($recent_mbamlogTXT, "<items>", "[items]")

Un code un peu différent, qui ne nécessite pas d'include (ça n'enlève rien au travail que tu as fait, qui est tout aussi fonctionnel) :

► Afficher le texte

Code : Tout sélectionner

Local $sLastFile, $sFile
Local $sDir =  @AppDataCommonDir & "\Malwarebytes\Malwarebytes Anti-Malware\Logs"

Local $hSearch = FileFindFirstFile($sDir & "\*mbam-log*")
If $hSearch = -1 Then Exit MsgBox(0, "", "Aucun fichier trouvé")

While 1
    $sFile = FileFindNextFile($hSearch)
    If @error Then ExitLoop
    $sLastFile = $sFile
WEnd


$recent_mbamlogXML = $sDir & "\" & $sLastFile
Local $sUserContent = FileRead($recent_mbamlogXML)
$sUserContent = StringRegExpReplace( $sUserContent, "</[^>]+>", "") ; Supprime les balise fermantes
$sUserContent = StringRegExpReplace( $sUserContent, "<(mbam-log|engine|system|summary|options|items)>", "[$1]") ; Remplace <mbam-log> par [mbam-log] , (ou engine ou system ...)
$sUserContent = StringReplace( $sUserContent, "><", "/") ; Remplace >< par  (<file><path> devient <file/path>)
$sUserContent = StringRegExpReplace( $sUserContent, "<([^>]+)>", " - $1 : ") ; Pour toutes les balises, remplace tous les "<NomBalise>" par "- NomBalise :"
$sUserContent = StringRegExpReplace( $sUserContent, "^[^\[]+", "") ; Supprime tout le début, jusqu'au premier "["


$recent_mbamlogTXT = @DesktopDir & "\rapport_mbam.txt"
$_recent_mbamlogTXT = FileOpen($recent_mbamlogTXT, 2)
FileWrite($_recent_mbamlogTXT, $sUserContent)
FileClose($_recent_mbamlogTXT)


IF MsgBox(4, "Rapport mbam créé au format TXT", _ 
             "Le dernier rapport de Malwarebyte's Antimalware vient d'être enregistré sous le bureau :" & _ 
             @CRLF & $recent_mbamlogTXT & @CRLF & @CRLF & "Souhaitez-vous l'ouvrir ?") = 6 Then _ 
             ShellExecute($recent_mbamlogTXT)