[R] Fonction de recherche dans un PDF

[aulus]

Bonjour,

Pourriez-vous me renseigner sur les fonctions d'autoit concernant le traitement des fichiers PDF ?
Je serais surtout intéressé par une fonction de recherche dans ce type de fichier avec affichage de la page contenant l'objet de la recherche. Existe-t-elle ?

Je vous remercie.

[mikell]

A ma connaissance il n'existe pas de fonctions Autoit dédiées, du moins les udf existantes sur le sujet ne sont pas franchement convaincantes
Le plus simple est d'utiliser un soft externe libre en ligne de commande depuis Autoit pour convertir le pdf en txt - on fait ensuite la recherche dans le txt
Personnellement j'utilise pdftotext, dans celui-là les options permettent de traiter une page après l'autre (ce qui permet de mettre un n° de page sur un résultat de recherche), de respecter la mise en forme initiale (donc avoir un index de ligne)... autre option possible (pas testé) la sortie du texte en stdout plutôt qu'en fichier txt

[jguinch]

Ca à l'air excellent XPDF, Mikell ! J'avais déjà vu passer 2-3 liens, mais je pensais que c'était que sous Linux.
Du coup, pour m'amuser, j'ai essayé de faire deux petites fonctions qui pourraient être sympa.

@aulus : si ça te convient, il te restera à gérer l'ouverture du PDF à la page souhaité. Perso, j'utiliserais Sumatra PDF qui te permettra de faire ça super-facilement.

► Afficher le texteLe petit exemple

Code : Tout sélectionner

#Include "XPDF.au3"

$sMyPDF = @ScriptDir & "\reader_overview.pdf"
$sTextToSearch = "closeReason"


If _XPDF_ToText($sMyPDF, @TempDir & "\PDFContent.txt") Then
    Local $sContent = FileRead(@TempDir & "\PDFContent.txt")
    If $sContent = -1 Then Exit MsgBox(16, "", "Impossible de rechercher dans le fichier")
    
    Local $aPages = StringSplit($sContent, chr(12) )
    For $i = 1 To $aPages[0]
        If StringInStr($aPages[$i], $sTextToSearch) Then
            MsgBox(0, "", $sTextToSearch & " a été trouvé à la page " & $i)
        EndIf
    Next
EndIf

► Afficher le texteXPDF.au3

Code : Tout sélectionner

Global $sXPDFInfo = @ScriptDir & "\pdfinfo.exe"
Global $sXPDFToText = @ScriptDir & "\pdftotext.exe"


#CS
; #EXAMPLES =====================================================================================================================
Local $aRes = _XFDF_Info(@ScriptDir & "\reader_overview.pdf")
_ArrayDisplay($aRes)  ; necessite Array.au3

Local $sRes = _XFDF_Info(@ScriptDir & "\reader_overview.pdf", "Pages")
MsgBox(0, "Number of pages", $sRes)
#CE





; #FUNCTION# ====================================================================================================================
; Name...........: _XFDF_Info
; Description....: Retrives informations from a PDF file
; Syntax.........: _XFDF_Info ( "File" [, "Info"] )
; Parameters.....: file    - PDF File.
;                  Info    - The information to retrieve
; Return values..: Success - If the Info parameter is not empty, returns the desired information for the specified Info parameter
;                          - If the Info parameter is empty, returns an array with all available informations
;                  Failure - 0, and sets @error to :
;                   1 - PDF File not found
;                   2 - Unable to find the external programm
; Remarks........: The array returned is two-dimensional and is made up as follows:
;                   $array[1][0] = Label of the first information (title, author, pages...)
;                   $array[1][1] = value of the first information 
;                   ...
;
;                  
; ===============================================================================================================================
Func _XFDF_Info($sPDFFile, $sInfo = "")
    If NOT FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    If NOT FileExists($sXPDFInfo) Then Return SetError(2, 0, 0)
    
    Local $iPid = Run(@ComSpec & ' /c "' &  $sXPDFInfo & ' "' & $sPDFFile & '"', @ScriptDir, @SW_HIDE, 6)

    Local $sResult
    While 1
        $sResult &= StdoutRead($iPid)
        If @error Then ExitLoop
    WEnd
    
    Local $aInfos = StringRegExp($sResult, "(?m)^(.*?): +(.*)$", 3)
    If Mod( UBound($aInfos, 1), 2) = 1 Then Return SetError(3, 0, 0)
    
    Local $aResult [ UBound($aInfos, 1) / 2][2]
    
    For $i = 0 To UBound($aInfos) - 1 Step 2
        If $sInfo <> "" AND $aInfos[$i] = $sInfo Then Return $aInfos[$i + 1]
        $aResult[$i / 2][0] = $aInfos[$i]
        $aResult[$i / 2][1] = $aInfos[$i + 1]
    Next
    
    If $sInfo <> "" Then Return ""

    Return $aResult
EndFunc


; #FUNCTION# ====================================================================================================================
; Name...........: _XPDF_ToText
; Description....: Converts a PDF file to plain  text.
; Syntax.........: _XPDF_ToText ( "PDFFile" , "TxtFile" [ , FirstPage [, LastPage [, Layout ]]] )
; Parameters.....: PDFFile    - PDF Input File.
;                  TxtFile    - Plain text file to convert to
;                  FirstPage  - First page to convert
;                  LastPage   - Last page to convert
;                  Layout     - If true, maintains (as  best as possible) the original physical layout of the text
;                               If false, the behavior is to 'undo'  physical  layout  (columns, hyphenation, etc.)
;                                 and output the text in reading order.
;                               Default is True
; Return values..: Success - 1
;                  Failure - 0, and sets @error to :
;                   1 - PDF File not found
;                   2 - Unable to find the external programm
; Remarks........: The array returned is two-dimensional and is made up as follows:
; ===============================================================================================================================
Func _XPDF_ToText($sPDFFile, $sTXTFile, $iFirstPage = 0, $iLastPage = 0, $bLayout = True)
    Local $sOptions 
    
    If NOT FileExists($sPDFFile) Then Return SetError(1, 0, 0)
    If NOT FileExists($sXPDFToText) Then Return SetError(2, 0, 0)
    
    If $iFirstPage <> 0 Then $sOptions &= " -f " & $iFirstPage
    If $iLastPage <> 0 Then $sOptions &= " -l " & $iLastPage
    If $bLayout = True Then $sOptions &= " -layout"
    
    Local $iReturn = ShellExecuteWait ( $sXPDFToText , '"' & $sPDFFile & '" "' & $sTXTFile & '"', @ScriptDir, "", @SW_HIDE)
    If $iReturn = 0 Then Return 1
    
    Return 0
    
EndFunc

[aulus]

Bonjour et merci à tous deux pour vos pistes et vos codes. Je vais tester tout ça ce week-end.

[mikell]

@jguinch

Code : Tout sélectionner

; Name...........: _XFDF_Info
; Description....: Disables the specified network adapter.
; Remark.........: Doesn't make the coffee

Cela dit ces outils sont super, le seul truc dommage c'est que le viewer ne fonctionne pas sous Windows ...

Sans création de fichier txt :

► Afficher le texte

Code : Tout sélectionner

#include <Constants.au3>

$run = Run( "pdftotext32.exe -layout test.pdf -", "", @SW_HIDE, $STDOUT_CHILD)

Local $txt
While 1
    $txt &= StdoutRead($run)
    If @error Then ExitLoop
WEnd
$txt = StringRegExpReplace($txt, '(\s*$)', "")

Local $aPages = StringSplit($txt, chr(12) )
For $i = 1 to $aPages[0]
    MsgBox(0, "page " & $i, $aPages[$i])
Next
 

[aulus]

J'ai testé les 2 codes, après avoir installé pdftotext.exe , pdfinfo.exe et xpdf.au3. Je n'obtiens rien à l'exécution.

Cette ligne est-elle correcte (code de jguinch) :

Code : Tout sélectionner

$sMyPDF = @ScriptDir & "\mon_fichier.pdf"

$sTextToSearch = "mot_a_trouver"

Et (code de mikell) :

Code : Tout sélectionner

$run = Run( "pdftotext.exe mon_fichier.pdf", "", @SW_HIDE, $STDOUT_CHILD)

[mikell]

Il faut indiquer comment sortir le texte
syntaxe : "pdftotext.exe -options entrée.pdf sortie.txt"
Pour mon code :

Code : Tout sélectionner

$run = Run( "pdftotext.exe [color=#FF0000]-layout[/color] mon_fichier.pdf [color=#FF0000][size=150][b]-[/b][/size][/color]", "", @SW_HIDE, $STDOUT_CHILD)

-layout : option pour respecter la mise en forme
- : impose une sortie en stdout
A tester en mettant tout dans le même dossier
Voilà mon test (XP 32 bits)

pdftotxt.zip

(396.37 Kio) Téléchargé 293 fois

[aulus]

Effectivement, mon code n'était pas bon. Le test a réussi. Toutefois, la recherche s'effectue uniquement sur la page 1.

[mikell]

Si le test dans mon zip t'affiche 2 msgbox c'est que dans le principe ça fonctionne
Ensuite tu peux y remplacer mon pdf par le tien, pour voir
Si ça fonctionne encore c'est probablement dans ton code que ça se passe mais difficile de dire quoi que ce soit sans le voir...

[aulus]

J'utilise votre code tel quel, ne modifiant que le nom du fichier pdf à ouvrir et ajoutant le nom du fichier txt à créer. Avec votre fichier pdf, j'obtiens bien 2 msgbox. Mais avec mon propre fichier pdf, ne s'ouvre qu'une seule msgbox nommée page 1, alors que mon pdf en compte pas mal.
Je me demande si tous les fichiers pdf sont structurés de la même manière.

[mikell]

Aucune idée... faut faire des tests
Ce code est censé retourner l'intégralité du pdf dans le txt

Code : Tout sélectionner

Run("pdftotext.exe mon_fichier.pdf sortie.txt")

Si ça ne retourne que la page 1, faut essayer de forcer la lecture de la page 2

Code : Tout sélectionner

Run("pdftotext.exe -f 2 -l 2  page_2.txt")

Pas moyen de voir le pdf en question ?

[aulus]

Le fichier txt contient bien tout le contenu du pdf. Mais une seule msgbox s'affiche, et non une par page.
Fichier pdf : ftp://ftp.bnf.fr/582/N5821613_PDF_1_-1DM.pdf

[jguinch]

@mikell : oui, j'ai fais un copié-collé depuis une des mes fonctions... un peu trop vite, je vais corriger

aulus, j'ai testé avec mon code et ton PDF, ça marche plutôt bien...

► Afficher le texte

Code : Tout sélectionner

#Include "XPDF.au3"

$sMyPDF = @ScriptDir & "\N5821613_PDF_1_-1DM.pdf"
$sTextToSearch = "réuni"


If _XPDF_ToText($sMyPDF, @TempDir & "\PDFContent.txt") Then
    Local $sContent = FileRead(@TempDir & "\PDFContent.txt")
    If $sContent = -1 Then Exit MsgBox(16, "", "Impossible de rechercher dans le fichier")
    
    Local $aPages = StringSplit($sContent, chr(12) )
    For $i = 1 To $aPages[0]
        If StringInStr($aPages[$i], $sTextToSearch) Then
            MsgBox(0, "", $sTextToSearch & " a été trouvé à la page " & $i)
        EndIf
    Next
EndIf

[mikell]

@jguinch
j'avais compris - it was a joque

Sinon je sais pas trop quoi dire...
Je viens de tester ce script (en renommant le pdf en '3.pdf')

Code : Tout sélectionner

#include <Constants.au3>
$run = Run( "pdftotext.exe -layout 3.pdf -", "", @SW_HIDE, $STDOUT_CHILD)

Local $txt
While 1
    $txt &= StdoutRead($run)
    If @error Then ExitLoop
WEnd
$txt = StringRegExpReplace($txt, '(\s*$)', "")

Local $aPages = StringSplit($txt, chr(12) )
For $i = 1 to $aPages[0]
   ; MsgBox(0, "page " & $i, $aPages[$i])
    FileWrite(StringFormat("%02i", $i) & ".txt", $aPages[$i])
Next

qui m'a bien retourné 85 fichiers txt
Et aussi 85 msgbox (donc une recherche par page sans création de fichier est possible)

[aulus]

Bonjour,

Ca fonctionne aussi chez moi. Merci encore pour tout ce travail. Je pense que les dysfonctionnements provenaient du nom de fichier long du pdf qui me servait de test.
Afin que la page contenant le ou les mots cherchés s'ouvre dans le lecteur pdf, j'ai codé comme ceci :

Code : Tout sélectionner

#include <Constants.au3>

$run = Run("pdftotext32.exe -layout 3.pdf -", "", @SW_HIDE, $STDOUT_CHILD)

Local $txt
Local $sTextToSearch = "desinat in piscem"

While 1
    $txt &= StdoutRead($run)
    If @error Then ExitLoop
WEnd
$txt = StringRegExpReplace($txt, '(\s*$)', "")

Local $aPages = StringSplit($txt, chr(12) )
For $i = 1 to $aPages[0]
    If StringInStr($aPages[$i], $sTextToSearch) Then
            Local $pdf = ' "' & @ScriptDir & '\3.pdf' & '"'
            Run("C:\Program Files (x86)\Adobe\Reader 11.0\Reader\AcroRd32.exe /A page=" & $i & $pdf)
    EndIf

Next
 

Grand merci pour votre temps de réflexion, de codage et de tests.

[mikell]

Cette recherche ça ferait une belle fonction à rajouter au XPDF.au3 de jguinch

[jguinch]

C'est vrai mikell, on pourrait l'intégrer et proposer ça dans la section UDF, ça peut être utile.
Mais comment tu vois ça, toi ?
La fonction de recherche va faire la conversion en txt (directement dans stdout), ça c'est OK. Mais qu'est-ce qu'elle va retourner ?
- 1 si le mot a été trouvé et 0 si pas trouvé ?
- le nombre d’occurrences trouvées ?
- un tableau à 2 dimensions avec le numéro de page et le nombre d'occurrences dans la page ?
- ... ?

On peut faire ça :

► Afficher le texte

; Name...........: _XFDF_Search
; Description....: Makes the coffee, and incidentally search for an text string in a PDF File
; Syntax.........: _XFDF_Search ( "file", "search" [, flag = 0 [, start = 1 ]] )
; Parameters.....: file - PDF file.
; search - What to search for in the PDF file
; flag - Desired return mode. See remarks.
; start - Page number to start searching at (default is 1)
; Return values..:
; Flag = 0 - Returns 1 if the search string was found, or 0 if not (default)
; Flag = 1 - Returns the number of occcurrences found
; Flag = 2 - Returns an array containing the number of occurrences found for each page
; $result[0] : number of pages of the PDF file
; $result[1] : number of occurrences found in the first page
; $result[2] : number of occurrences found in the second page
; $result[3] : ...
; Flag = 3 - Returns the page number of the first occurrence
; @error is set the 1 if the search can not be performed

T'en penses quoi ?

[mikell]

Hem ça me rappelle quelque chose ce flag...

Code : Tout sélectionner

Flag - Values 
0 - Returns 1 (matched) or 0 (no match) 
1 - Return array of matches.

Le flag 3 est-il vraiment utile ?
Par contre peut-être une array 2D avec [0] n° de page - [1] nb d'occurences dedans ? et
$result[0][0] = number of matching pages
$result[0][1] = global number of occurrences found in ze whole pdf (un peu comme dans les FileList*) faut voir
Peut-être aussi (puisque les options de pdftotxt le permettent)

Code : Tout sélectionner

; start - Page number to start searching at (default is 1)
; end - Page number to stop searching (default is 0 = eof)

Et préciser que la recherche est case insensitive par défaut

Mais c'est que des idées comme ça, globally en fait je te fais la plus entière confiance