[R] Calcul d'action par minute

[cortx]

Bonjour:

Je suis en train de réaliser un script qui me permettrai de calculer le nombre d'action par minute exécuté lors que je joue/tappe un texte/surf

Je suis parti sur le raisonnement suivant:

Code : Tout sélectionner

x=heure_de_début
while 1
action = action +1
endwhile
y=heure_de_fin
APM= action / heure_de_fin - heure_de_debut

Pour le moment c'est le raisonnement logique que j'ai sans code.
J'ai commencé à mettre en forme mais je bute sur la détermination d'une 'action'
Il faut que ce soit n'importe quel frappe clavier et n'importe quel clic souris.
Ca va de a->z / A->Z / 1->! ainsi que toutes les variantes possible et immaginable avec Shift/Ctrl/Alt
Et pour la Souris c'est le clic: droit/gauche/milieu/scroll/btn4/btn5 et plus si possible (par exemple ma molette de souris à des clic horizontaux en plus des scroll et du clic milieu).

Est ce qu'il existe un moyen simple et efficace pour qu'auto-it détecte cela ?
Je connais le IsPressed mais je me vois mal faire autant de fonction qu'il y à de combinaison possible et imaginable.

Merci d'avance.
CortX

Voici le code final:

► Afficher le texte

Code : Tout sélectionner

#include <Misc.au3>
#include <Date.au3>
HotKeySet("!{PAUSE}", "_Exit")

global $TIME = @YEAR &"/"& @MON &"/"& @MDAY & " "& @HOUR &":"& @MIN &":"& @SEC


GuiCreate("test", 50, 30, 10, 10)
$label = GuiCtrlCreateLabel("0", 20, 10, 20, 20)
GuiSetState()

Local $action
While GuiGetMsg()<>-3
For $i = 1 to 221

    If _IsPressed(Hex($i)) Then
        If  $i <> 16 Then ;shift
            If  $i <> 160 Then ; shift
                ;ToolTip("$i=" & $i & " - Hex($i)=" & Hex($i) ,0,0)
                Do;on en fait rien tant que la touche n'est pas relaché.
                Until not _IsPressed(Hex($i))
            $action += 1
            EndIf
        EndIf

;~      If  $i = 16  Then ;shift
;~          ToolTip("$i=" & $i & " - Hex($i)=" & Hex($i) ,0,0)
;~              Do
;~                  Sleep(10)
;~              Until not _IsPressed(Hex($i))
;~          $action += 1
;~      EndIf

        GuiCtrlSetData($label, $action)
    EndIf


;Code à rajouter dans la boucle "If _IsPressed(Hex($i)) Then" pour chaque touche que l'on veux ignorer
;ctrl droite 17 & 163
;ctrl gauche 17 & 162
;shift droite 16 & 161
;shift gauche 16 & 160
;alt gauche 18 & 164
;alt droite 17 & 162
;touche menu déroulant 93
;windows 91


Next
Sleep(10)
Wend
_Exit()

Func _Exit()
    calcul_apm()
    Exit
EndFunc

func calcul_apm()
    Local $iDateCalc = _DateDiff('s', $TIME, _NowCalc())
    $apm = ($action/$iDateCalc)*60
    MsgBox(4096, "", "Number of seconds  : " & $iDateCalc)
    MsgBox(4096, "", "Number of action  : " & $action)
    MsgBox(4096, "", "Number of apm  : " & $apm)
EndFunc

 

[mikell]

Oui on peut, voilà le moteur (la partie minutage je te la laisse)
Sans la roulette :

► Afficher le texte

Code : Tout sélectionner

#include <Misc.au3>
HotKeySet("{ESC}", "_Exit")

GuiCreate("test", 50, 30, 10, 10)
$label = GuiCtrlCreateLabel("0", 20, 10, 20, 20)
GuiSetState()

Local $action
While GuiGetMsg()<>-3
For $i = 1 to 221
  If  _IsPressed(Hex($i)) Then 
    Do
     Sleep(10)
    Until not _IsPressed(Hex($i))
    $action += 1
    GuiCtrlSetData($label, $action)
  EndIf
Next
Sleep(10)
Wend
_Exit()

Func _Exit()
    Exit Msgbox(0, "", $action)
EndFunc

Avec la roulette (clics horizontaux et scroll) c'est plus compliqué, faut télécharger l'udf WinAPIEx.au3

► Afficher le texte

Code : Tout sélectionner

#Include <APIConstants.au3>
#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>
#include <Misc.au3>
HotKeySet("{ESC}", "_Exit")

Global $hForm, $tRID, $pRID, $label, $action

$hForm = GUICreate('MyGUI', 120, 60, 20, 20,  -1, $WS_EX_TOPMOST)
$label = GUICtrlCreateLabel("test", 30, 20, 50, 20)

$tRID = DllStructCreate($tagRAWINPUTDEVICE)
DllStructSetData($tRID, 'UsagePage', 0x01) ; Generic Desktop Controls
DllStructSetData($tRID, 'Usage', 0x02) ; Mouse
DllStructSetData($tRID, 'Flags', $RIDEV_INPUTSINK)
DllStructSetData($tRID, 'hTarget', $hForm)
$pRID = DllStructGetPtr($tRID)

_WinAPI_RegisterRawInputDevices($pRID)
GUIRegisterMsg($WM_INPUT, 'WM_INPUT')

GUISetState()

While GuiGetMsg()<>$GUI_EVENT_CLOSE
For $i = 8 to 221
  If  _IsPressed(Hex($i)) Then 
    Do
     Sleep(10)
    Until not _IsPressed(Hex($i))
    $action += 1
    GuiCtrlSetData($label, $action)
  EndIf
Next
Sleep(10)
Wend
_Exit()


;==================================================
Func _Exit()
    Exit Msgbox(0, "", $action)
EndFunc 

Func WM_INPUT($hWnd, $iMsg, $wParam, $lParam)
    Switch $hWnd
        Case $hForm
            Local $tRIM = DllStructCreate($tagRAWINPUTMOUSE)
            If _WinAPI_GetRawInputData($lParam, DllStructGetPtr($tRIM), DllStructGetSize($tRIM), $RID_INPUT) Then
                Local $Flags = DllStructGetData($tRIM, 'ButtonFlags')
                If not BitAND($Flags, BitOR($RI_MOUSE_MIDDLE_BUTTON_UP, _ 
                    $RI_MOUSE_LEFT_BUTTON_UP, _ 
                    $RI_MOUSE_RIGHT_BUTTON_UP, _ 
                    $RI_MOUSE_BUTTON_4_UP, _ 
                    $RI_MOUSE_BUTTON_5_UP)) Then
                    If DllStructGetData($tRIM, 'LastX')=0 AND DllStructGetData($tRIM, 'LastY')=0 Then
                        $action += 1
                        GuiCtrlSetData($label, $action)
                    EndIf
                EndIf
            EndIf
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_INPUT
 

[cortx]

Bonjour;

Merci pour ces script je vais étudier et ajouter la partie minutage que j'ai déjà faites pendant la nuit.
Par contre pour ceux qui viendront ici pour récupérer l'info j'ai trouvé un petit bug.
Prenons l'exemple d'un texte en cours de rédaction, j'écris tout en minuscule.
Or parfois si j'ai besoin d'écrire un mot en majuscule je n'appuie pas sur Caps Lock mais je reste appuyer sur Shift et j'écris mon mot.
Dans l'état actuel le comptage ne sera actif que lorsque j'aurais relaché la touche shift et ne comptera que 1
Je vais voir si il est possible de jouer sur le Until not _IsPressed(Hex($i)), car si je retire cette ligne, le fait de rester appuyer augmente le compteur.
Je vais chercher si il est possible d'avoir une option non pas de pression de touche mais de relachement

A plus tard.

@Mikell:
Peux tu m'expliquer: GuiGetMsg()<>-3
J'ai compris que la fin du script intervenais quant j'appuyai sur Echap ou fermais la fenetre de compteur mais je ne comprends pas le "<>-3"

**********

Edit:
Je viens d'avoir une idée, mais je ne sais pas si elle est valable.
Faire une boucle For en excluant les touches Shift, Ctrl, Alt pour compter toutes les touches sauf celles ci avec des $i = 1 to x or $i= y to z
Faire ensuite des simple if pour chacune des touches Shift, Ctrl, Alt pour les comptabiliser aussi mais juste une fois.

...Bon je suis une quiche en codage
J'ai voulu faire For $i = 1 to 10 or $i = 11 to 221
Heu ouai mais non, c'est pas ca qui détecte la touche appuyé, (non ne me tapez pas)

**********

Voila à quoi je suis arrivé pour le moment en ignorant la touche shift de droite.
J'ai retiré la convertion en Hexadécimal pour m'éviter toute erreur.
J'ai fais une tooltip d'aide qui affiche le code du caractère appuyé pour aider.
Reste maintenant à savoir comment compter les touches spéciale tel que Shift et Alt une seule et unique fois qu'elle soit relaché ou non et à continuer à compter les autres même si elles sont encore enfoncée.

Code : Tout sélectionner

#include <Misc.au3>
HotKeySet("{ESC}", "_Exit")

;ctrl droite = 17 163
;ctrl gauche = 17 162
;shift droite = 16 161
;shift gauche = 16 160
;alt gauche = 18 164
;alt droite = 17 162
;Fn 93
;windows 91

GuiCreate("test", 50, 30, 10, 10)
$label = GuiCtrlCreateLabel("0", 20, 10, 20, 20)
GuiSetState()

Local $action
While GuiGetMsg()<>-3
For $i = 1 to 221

    If _IsPressed(Hex($i)) Then
        If  $i <> 16 Then ;shift
            If  $i <> 160 Then ; shift
                ToolTip("$i=" & $i & " - Hex($i)=" & Hex($i) ,0,0)
                Do
                    Sleep(10)
                Until not _IsPressed(Hex($i))
            $action += 1
            EndIf
        EndIf

;~      If  $i = 16  Then ;shift
;~          ToolTip("$i=" & $i & " - Hex($i)=" & Hex($i) ,0,0)
;~              Do
;~                  Sleep(10)
;~              Until not _IsPressed(Hex($i))
;~          $action += 1
;~      EndIf
;~      If  $i = 160  Then ;shift
;~          ToolTip("$i=" & $i & " - Hex($i)=" & Hex($i) ,0,0)
;~              Do
;~                  Sleep(10)
;~              Until not _IsPressed(Hex($i))
;~          $action += 1
;~      EndIf

        GuiCtrlSetData($label, $action)
    EndIf
Next
Sleep(10)
Wend
_Exit()

Func _Exit()
    Exit Msgbox(0, "", $action)
EndFunc

[mikell]

Dans l'état actuel le comptage ne sera actif que lorsque j'aurais relaché la touche shift et ne comptera que 1

Yes, faut trouver un petit additif ^^

Je vais voir si il est possible de jouer sur le Until not _IsPressed(Hex($i)), car si je retire cette ligne, le fait de rester appuyer augmente le compteur.

Oh que oui, si tu retires cette ligne chaque appui de touche fera : $action += 583 (environ)

Je vais chercher si il est possible d'avoir une option non pas de pression de touche mais de relachement

C'est effectivement la solution et ça s'appelle "Until not _IsPressed(Hex($i)"

Peux tu m'expliquer: GuiGetMsg()<>-3

$GUI_EVENT_CLOSE = -3

For $i = 1 to 10 or $i = 11 to 221

Niet, tu peux pas faire ça, il faut faire 2 boucles For distinctes et successives

[cortx]

Bonsoir;

En testant ma fonction de calcul de temps je me suis aperçu qu'il existait un autre problème auquel je n'avais pas pensé.
J'ai pianoter rapidement sur mon clavier pour faire monter le compteur d'action, et bien, comme on gère le 'not _IsPressed' tant qu'une touche n'est pas relaché il arrête de compter les autres.
Si je tape le mot 'bonjour' je peux appuyer sur la lettre 'n' sans avoir relaché la lettre 'o'
Windows gère cela très bien et reproduit la frappe des lettre (j'ai regardé il est capable de détecter la lettre appuyer même si 5 sont déjà enfoncé)

Ca n'a l'air de rien comme ca, mais c'est une contrainte.
Je ne vais pas en tenir compte car je ne cherche pas quelque chose d'aussi poussée mais si on veux vraiment etre précis faudra y penser.

[GhostLine]

Je pense qu'il serait peut être temps pour toi d'apprendre à taper correctement (lorsque j'ai appris la dactylo au collège, on le faisait sur des machines à écrire classiques : deux touches en même temps, c'était la salade de barres de lettre assurée ).

[mikell]

Rah ça y est je le tiens
Petite prise de tête du moment ...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#Include <WindowsConstants.au3>
HotKeySet('{ESC}', '_Exit')

Global Const $RID_INPUT = 0x10000003
Global Const $RIDEV_INPUTSINK = 0x00000100
Global Const $RI_MOUSE_LEFT_BUTTON_UP = 0x0002
Global Const $RI_MOUSE_RIGHT_BUTTON_UP = 0x0008
Global Const $RI_MOUSE_MIDDLE_BUTTON_UP = 0x0020
Global Const $RI_MOUSE_BUTTON_4_UP = 0x0080
Global Const $RI_MOUSE_BUTTON_5_UP = 0x0200
Global Const $RIM_TYPEMOUSE = 0
Global Const $RIM_TYPEKEYBOARD = 0x01
If Not IsDeclared('WM_INPUT') Then Global Const $WM_INPUT = 0x00FF

Global Const $tagRAWINPUTDEVICE = 'ushort usUsagePage;ushort usUsage;dword dwFlags;hwnd hwndTarget;'
Global Const $tagRAWINPUTHEADER = 'dword dwType;dword dwSize;hwnd hDevice;uint_ptr wParam;'
Global Const $tagRAWMOUSE = 'ushort usFlags;ushort usAlignment;ushort usButtonFlags;' & _
    'ushort usButtonData;ulong ulRawButtons;long lLastX;long lLastY;ulong ulExtraInformation'
Global Const $tagRAWINPUT_MOUSE = $tagRAWINPUTHEADER & $tagRAWMOUSE
Global Const $tagRAWKEYBOARD = 'ushort MakeCode;ushort Flags;ushort Reserved;ushort VKey;uint Message;' & _
        'ulong ExtraInformation;'
Global Const $tagRAWINPUT_KEYBOARD = $tagRAWINPUTHEADER & $tagRAWKEYBOARD & 'dword;ushort;' 

;======================================
Global $tRIH, $iRIH
Global $hGUI, $label, $action

$hGUI = GUICreate('MyGUI', 120, 60, 20, 20,  -1, $WS_EX_TOPMOST)
$label = GUICtrlCreateLabel("test", 30, 20, 50, 20)
GUIRegisterMsg($WM_INPUT, 'WM_INPUT')

$tRID_KD = DllStructCreate($tagRAWINPUTDEVICE)
$pRID_KD = DllStructGetPtr($tRID_KD)
$iRID_KD = DllStructGetSize($tRID_KD)

$tRID_M = DllStructCreate($tagRAWINPUTDEVICE)
$pRID_M = DllStructGetPtr($tRID_M)
$iRID_M = DllStructGetSize($tRID_M)

$tRIH = DllStructCreate($tagRAWINPUTHEADER)
$iRIH = DllStructGetSize($tRIH)

DllStructSetData($tRID_KD, 'usUsagePage', 0x01)
DllStructSetData($tRID_KD, 'usUsage', 0x06)
DllStructSetData($tRID_KD, 'dwFlags', $RIDEV_INPUTSINK) 
DllStructSetData($tRID_KD, 'hwndTarget', $hGUI)

DllStructSetData($tRID_M, 'usUsagePage', 0x01)
DllStructSetData($tRID_M, 'usUsage', 0x02)
DllStructSetData($tRID_M, 'dwFlags', $RIDEV_INPUTSINK) 
DllStructSetData($tRID_M, 'hwndTarget', $hGUI)

_RegisterRawInputDevices($pRID_M, 1, $iRID_M)
_RegisterRawInputDevices($pRID_KD, 1, $iRID_KD)
GUISetState()


While GuiGetMsg()<>$GUI_EVENT_CLOSE
    Sleep(10)
WEnd

 _Exit()

;=========================================

Func WM_INPUT($hwnd, $iMsg, $iwParam, $ilParam)

Local $tRI_M, $pRI_M, $iRI_M, $tRI_KD, $pRI_KD, $iRI_KD, $iSize
$tRI_M = DllStructCreate($tagRAWINPUT_MOUSE)
$pRI_M = DllStructGetPtr($tRI_M)
$iRI_M = DllStructGetSize($tRI_M)

_GetRawInputData($ilParam, $RID_INPUT, $pRI_M, $iRI_M, $iRIH)

Switch DllStructGetData($tRI_M, 'dwType')
    Case $RIM_TYPEMOUSE
        Local $Flags = DllStructGetData($tRI_M, 'usButtonFlags')
        If not BitAND($Flags, BitOR($RI_MOUSE_MIDDLE_BUTTON_UP, _ 
            $RI_MOUSE_LEFT_BUTTON_UP, _ 
            $RI_MOUSE_RIGHT_BUTTON_UP, _ 
            $RI_MOUSE_BUTTON_4_UP, _ 
            $RI_MOUSE_BUTTON_5_UP)) Then
            If DllStructGetData($tRI_M, 'lLastX')=0 AND DllStructGetData($tRI_M, 'lLastY')=0 Then
                $action += 1
                GuiCtrlSetData($label, $action)
            EndIf
        EndIf
    Case $RIM_TYPEKEYBOARD
        $tRI_KD = DllStructCreate($tagRAWINPUT_KEYBOARD)
        $pRI_KD = DllStructGetPtr($tRI_KD)
        $iRI_KB = DllStructGetSize($tRI_KD)
        _GetRawInputData($ilParam, $RID_INPUT, $pRI_KD, $iRI_KB, $iRIH)

        If DllStructGetData($tRI_KD, 'Message') = $WM_KEYUP Then   ; clavier
            $action += 1
            GuiCtrlSetData($label, $action)  ; DllStructGetData($tRI_KD, 'VKey')
        EndIf
EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc


Func _Exit()
    Exit Msgbox(0, "", $action)
EndFunc


Func _GetRawInputData($hRawInput, $iCommand, $pData, ByRef $iSize, $iSizeHeader, $hDll = 'user32.dll')
    Local $aRet 
    $aRet = DllCall($hDll, 'uint', 'GetRawInputData', 'hwnd', $hRawInput, 'uint', $iCommand, 'ptr', $pData, 'uint*', $iSize, 'uint', $iSizeHeader)  
    If @error Or $aRet[0] = 4294967295 Then Return SetError(1, 0, $aRet[0])
    $iSize = $aRet[4]
    Return $aRet[0]
EndFunc


Func _RegisterRawInputDevices($pRawInputDevices, $iNumDevices, $iSize, $hDll = 'user32.dll')
    Local $aRet 
    $aRet = DllCall($hDll, 'int', 'RegisterRawInputDevices', 'ptr', $pRawInputDevices, 'uint', $iNumDevices, 'uint', $iSize)    
    If @error Or $aRet[0] = 0 Then SetError(1, 0, 0)
    Return $aRet[0]
EndFunc

 

... le genre de truc qu'on ne fait qu'en vacances

[cortx]

SAlut;

Désolé Mikell, je n'avais pas vu ton message quant j'ai édite le mien en premier post.
Merci pour ce que tu as fourni, je vais me pencher dessus.
C'est un peu plus chiader que ce que j'ai l'habitude de sortir